纪中OJ 2019.02.15【NOIP提高组】模拟 B 组 梦回三国 比赛题解

声明

---

　　旁边的同学小 H（胡）对我说： “哟，比赛拿了 140，强！要知道，如果哥第三题 AC 了，哥就 230 了，你个废柴！！！（比赛实际分数 130 额呵）”

　　顿时，千万草泥马从我心中奔腾而过：你不要每次都把“如果”说得这么理直气壮好吧...... （心态大崩*1）

---

　　　　嗯咳，不和他瞎扯了，骚话一大堆，进入正题。

　　　　

　　　　第一次心情大好 （因为小 H 太搞笑了啊哈），准备写比赛的题解！~

　　小 H：“明明你是因为以前的比赛题解太长了才懒得写，说得这么好听......”

　　“额呵，闭嘴！”（心态大崩*2）

　　　　嗯，似乎又扯远了。

　　　　比赛分数：100+10+30=140  （竟然还有 3 个大佬们高我 160 AK 比赛（心态大崩*3）？太强了，膜拜！！！）

　　　　排名：12 （额，比平常平均排名要前）

　　　　这次比赛有个特别好听的题目： “梦回三国”

　　　　不想排版，就这样了吧哎~

　　　　“梦回三国”系列题解如下：

---

  

　　　　　T1：魏传之长坂逆袭

 3906. 魏传之长坂逆袭 （standard IO） 

Time Limits: 1000 ms  Memory Limits: 131072 KB 

Description

 

【题目背景】
众所周知，刘备在长坂坡上与他的一众将领各种开挂，硬生生从曹操手中逃了出去，随后与孙权一起火烧赤壁、占有荆益、成就霸业。而曹操则在赤壁一败后再起不能，终生无力南下。
建安二十五年(220年)，曹操已到风烛残年，但仍难忘当年长坂的失误，霸业的破灭。他想如果在刘备逃亡的路中事先布下一些陷阱，便能拖延刘备的逃脱时间了。你作为曹操身边的太傅，有幸穿越到了208年的长坂坡，为大魏帝国贡献力量，布置一些陷阱。但时空守卫者告诉你你不能改变历史，不能拖增大刘备的最大逃脱时间，但你身为魏武之仕，忠心报国，希望能添加一些陷阱使得刘备不论怎么逃跑所用的时间都一样。
 
【问题描述】
已知共有n个据点，n-1条栈道，保证据点联通。1号据点为刘备军逃跑的起点，当刘备军跑到某个据点后不能再前进时视为刘备军逃跑结束。在任意一个栈道上放置1个陷阱会使通过它的时间+1，且你可以在任意一个栈道上放置任意数量的陷阱。
现在问你在不改变刘备军当前最大逃跑时间的前提下，需要添加最少陷阱，使得刘备军的所有逃脱时间都尽量的大。

 

Input

第一行一个数n，表示据点个数。
    接下来n-1行每行三个数，ai、bi、ti，表示从据点ai通过第i个栈道到bi耗时ti

Output

仅包含一个数，为需要添加的最少陷阱数。
 

 

Sample Input

3
1  2  1
1  3  3

Sample Output

2

 

Data Constraint

对于 5% 的数据，1<=n<=100000，1<=ti<=200000
对于 100% 的数据，1<=n<=500000，0<ti<=1000000

　　　5% 的数据是什么鬼啊啊？？？（心态大崩*4）

　　　额然而仔细想想发现，这道题不是挺简单的吗？比赛时用时 45 min 就 A 掉了（耶 100 到手，5% 与我无关！！！）~

　　　就是一棵树，画画图，发现贪心可行性显然，于是两次 dfs 搞定！！！

　　　直接附比赛出题人的题解：

　　　　题目大意是给你一棵树，要你调整一些边的权值，使根结点 到结点的路径等长。

　　　　首先要求该根到各叶子节点的距离相同，实际上也就是要求它 的子树到各个叶子节点相同，而当保证了某棵子树的根到叶子节 点的距离相同的时候，实际上可以把这个看做一条链了，所以这就可以看做一个树形 DP 了。递归处理子树的然后再处理父亲，这种贪心的证明显然，不妨假设某一个边的修改值变小，那么它显 然就需要下传那个差额给其他子树，而子树的个数>=1，所以肯定不会比这个方法优。

　　　　说白了，每次对于深度越低的点能放多少陷阱就放多少陷阱，两次深搜解决。

　　　　

　　　　　

var
        d,delta:array[0..500001] of int64;
        first,next,en,len,a:array[0..1000001] of longint;
        i,k,m,n,s,t,flag:longint;
        v,ans:int64;
procedure add(x,y,w:longint);    //前向星
begin
        inc(m);
        next[m]:=first[x];
        first[x]:=m;
        en[m]:=y;
        len[m]:=w;
end;
procedure dfs1(x,data:longint);
var
        now,e,bool:longint;
begin
        now:=first[x];
        bool:=0;
        while now<>0 do
        begin
                e:=en[now];
                bool:=1;
                dfs1(e,data+len[now]);
                now:=next[now];
        end;
        if bool=0 then
        begin
                inc(k);
                a[k]:=x;
                d[k]:=data;
                if data>v then v:=data;
        end;
end;
procedure dfs2(x:longint);
var
        now,e:longint;
begin
        now:=first[x];
        if now=0 then exit;
        while now<>0 do
        begin
                e:=en[now];
                dfs2(e);
                if delta[e]<delta[x] then delta[x]:=delta[e];
                now:=next[now];
        end;
        now:=first[x];
        while now<>0 do
        begin
                inc(ans,delta[en[now]]-delta[x]);
                now:=next[now];
        end;
end;
begin
        readln(n);
        for i:=1 to n-1 do
        begin
                readln(s,t,v);
                add(s,t,v);
        end;
        v:=-maxlongint;
        dfs1(1,0);
        fillchar(delta,sizeof(delta),126);
        for i:=1 to k do
                delta[a[i]]:=v-d[i];
        dfs2(1);
        writeln(ans);
end.

---

　　　　　T2： 蜀传之单刀赴会

 3907. 蜀传之单刀赴会 (Standard IO)

Time Limits: 1000 ms  Memory Limits: 131072 KB 

 

Description

【题目背景】
公元215年，刘备取益州，孙权令诸葛瑾找刘备索要荆州。刘备不答应，孙权极为恼恨，便派吕蒙率军取长沙、零陵、桂阳三郡。长沙、桂阳蜀将当即投降。刘备得知后，亲自从成都赶到公安(今湖北公安)，派大将关羽争夺三郡。孙权也随即进驻陆口，派鲁肃屯兵益阳，抵挡关羽。双方剑拔弩张，孙刘联盟面临破裂，在这紧要关头，鲁肃为了维护孙刘联盟，不给曹操可乘之机，决定当面和关羽商谈。“肃邀羽相见，各驻兵马百步上，但诸将军单刀俱会”。双方经过会谈，缓和了紧张局势。随后，孙权与刘备商定平分荆州，“割湘水为界，于是罢军”，孙刘联盟因此能继续维持。
 
【问题描述】
关羽受鲁肃邀请，为了大局，他决定冒险赴会。他带着侍从周仓，义子关平，骑着赤兔马，手持青龙偃月刀，从军营出发了，这就是历史上赫赫有名的“单刀赴会”。关羽平时因为军务繁重，决定在这次出行中拜访几个多日不见的好朋友。然而局势紧张，这次出行要在限定时间内完成，关公希望你能够帮助他安排一下行程，安排一种出行方式，使得从军营出发，到达鲁肃处赴会再回来，同时拜访到尽可能多的朋友，在满足这些条件下行程最短。注意拜访朋友可以在赴会之前，也可以在赴会之后。现在给出地图，请你完成接下来的任务。

 

Input

第一行n,m,k,t,代表有n个地点，m条道路,有k个朋友(不包括鲁肃)，以及限定时间t(行走1单位长度的路程用时1单位时间)。
    接下来m行，每行有x,y,w三个整数，代表x和y之间有长度为w的道路相连。
    接下来一行有k个整数，代表朋友所在的都城编号(保证两两不同，且不在1和n)
   （我们约定1是关羽的营地，n是鲁肃的营地）

Output

输出两个整数，分别是最多可以拜访的朋友数，以及在这种情况下最少需要耗费的时间，如果连到达鲁肃再回来都无法完成，输出一个-1就可以了。

 

Sample Input

5  7  2  15
1  2  5
1  3  3
2  3  1
2  4  1
3  4  4
2  5  2
4  5  3
2  4

Sample Output

2  14

 

Data Constraint

有10%数据，n<=10,m<=50,k<=5;
有10%数据,k=0;
有10%数据,k=1;
另30%数据，k<=5;
对于100%数据，n<=10000,m<=50000,k<=15,t<=2147483647,w<=10000

　　　　本人认为这题是此系列中最难的一道题。

　　

　　　　比赛时只用 spfa 跑纯最短路拿了 k=0 的 10 分的部分分（呜呜呜复制粘贴后还调了我快一个小时，才发现是无向边，前向星要建两次边）~  （心态大崩*5）

　　　小 H：“要不是我看那 10 分太少了，还要打最短路。于是哥给你一个面子，让你比我高，不然我 Ctrl C+Ctrl V 然后修改一下就和你一样分数了哈” （心态大崩*6）

　　　额这是比赛啊！！！（虽然我也是偷偷复制粘贴的，只是他没发现，实在不想打啊啊~）

　　　　咳咳，思路：先跑一遍 dijkstra（或大约 k 遍 spfa），然后状压 dp 。（太复杂啦！心态大崩*7）

　　　　具体思路：　　　　　

　　　　 我们观察到 k 很小，不难想到状压 dp 。

　　　　dp[sta,i] 表示状态为 sta，最后到达的点为 i 的最少时间。

　　　　转移方程不难想到，我们枚举当前状态最后到达的点 i，再枚举未来状态最后到达的点 j，判断一下当前状态里包不包含 j，如果不包含，则：

　　　　　　dp[sta or (1<<(j-1)),j]=min(dp[sta or (1<<(j-1)),j],dp[sta,i]+dist[i,j])；

　　　　不过这里有一个小疑问就是 dist[i,j] 之间有一个另外的朋友经过了怎么办，这样不是没有记录么，其实我刚开始也是这样想的，但是其实我们状态都会枚举，不会有错。

　　　　那么我们要怎么求 dist[i,j] 呢？

　　　　我们先把地点 1 加入到要访问的朋友里，再把地点 n 加入到朋友里。

　　　　最后我们加一个 n+1 点，作为最后回到 1 的点（注意我们的 k 已经加了 3 了）。

　　　　我们跑 k-2 遍最短路，把两两朋友之间的最小距离算出来。

　　　　最后枚举一下状态判断 dp[i,k] 是否小于等于 t 且 i and (1<<(k-2))（判断到达点 n）就可以啦~

  思路转自：http://www.itdaan.com/blog/2017/11/08/4bbf264861172e48d24cf044945e7e10.html

　　　　再附一段官方题解（最难的题题解最短？？？心态大崩*8）：

　　　　 题目大意是给定一张图，确定起点和一些关键点，其中至少有一个关键点要到达，要求在时限内安排一种方案使得尽可能经过多的关键点并且回到起点，要求在同等条件下路程最短。

　　　　 我们对于每一个关键点进行一次 SPFA 预处理，然后用状压枚举方案，最后和时限做比较求最优方案就可以了。

　　

　　　　　　　

uses math;
var
        n,m,k,t,s,w,i,j,sta,cnt,tt:longint;
        f:array[0..500001,1..18] of int64;
        dist:array[1..18,1..18] of longint;
        py,dui,en,len,c,first,next:array[0..100001] of longint;
        use:array[0..100001] of boolean;
procedure add(x,y,w:longint);   //前向星
begin
        inc(sta);
        next[sta]:=first[x];
        first[x]:=sta;
        en[sta]:=y;
        len[sta]:=w;
end;
procedure spfa(s,x:longint);
var
        i,j,t,h,r,head:longint;
begin
        fillchar(c,sizeof(c),63);
        h:=1;
        r:=1;
        use[s]:=true;
        dui[1]:=s;
        c[s]:=0;
        while h<=r do
        begin
                head:=dui[h];
                t:=first[head];
                while t>0 do
                begin
                        if c[en[t]]>c[head]+len[t] then
                        begin
                                c[en[t]]:=c[head]+len[t];
                                if use[en[t]]=false then
                                begin
                                        use[en[t]]:=true;
                                        inc(r);
                                        dui[r]:=en[t];
                                end;
                        end;
                        t:=next[t];
                end;
                use[head]:=false;
                inc(h);
        end;
        for i:=1 to k-1 do
                dist[x,i]:=c[py[i]];
        dist[x,k]:=c[1];
end;
begin
        readln(n,m,k,t);
        for i:=1 to m do
        begin
                readln(s,tt,w);
                add(s,tt,w);
                add(tt,s,w);
        end;
        py[1]:=1;                         //把地点 1 加入关键点
        inc(k);
        for i:=2 to k do
                read(py[i]);
        readln;
        inc(k);                               //把地点 n 加入关键点
        py[k]:=n;
        inc(k);                               //把地点 n+1 加入关键点
        for i:=1 to k-1 do               //跑 spfa 记录关键点之间距离
                spfa(py[i],i);
        for i:=1 to k-1 do
                dist[k,i]:=dist[1,i];
        for sta:=0 to 1<<k-1 do
                for i:=1 to k do
                        f[sta,i]:=100000000000000007;
        f[1,1]:=0;
        for sta:=1 to 1<<k-1 do     //状压 dp
        for i:=1 to k do
        for j:=1 to k do
                if sta and (1<<(j-1))=0 then
                f[sta or (1<<(j-1)),j]:=min(f[sta or (1<<(j-1)),j],f[sta,i]+dist[i,j]);
        w:=-1;
        s:=maxlongint;
        for sta:=0 to 1<<k-1 do     //处理答案
                if (f[sta,k]<=t) and (sta and (1<<(k-2))<>0) then
                begin
                        j:=sta;
                        cnt:=0;
                        while j<>0 do
                        begin
                                inc(cnt);
                                j:=j-j and (-j);
                        end;
                        dec(cnt,3);
                        if cnt>w then
                        begin
                                w:=cnt;
                                s:=f[sta,k];
                        end;
                        if (cnt=w) and (f[sta,k]<s) then s:=f[sta,k];
                end;
        if w=-1 then writeln(-1) else writeln(w,' ',s);
end.

　　

　　　　然而代码比我想象中要短很多（理想 at least 150+，实际100额）~~~　　

---

　　　T3：吴传之火烧连营

3908. 吴传之火烧连营 (Standard IO)

Time Limits: 1000 ms  Memory Limits: 131072 KB 

 

 

Special Judge

 

Description

 

【题目背景】
蜀汉章武元年(221年)，刘备为报吴夺荆州、关羽被杀之仇，率大军攻吴。吴将陆逊为避其锋，坚守不战，双方成对峙之势。蜀军远征，补给困难，又不能速战速决，加上入夏以后天气炎热，以致锐气渐失，士气低落。刘备为舒缓军士酷热之苦，命蜀军在山林中安营扎寨以避暑热。陆逊看准时机，命士兵每人带一把茅草，到达蜀军营垒时边放火边猛攻。蜀军营寨的木栅和周围的林木为易燃之物，火势迅速在各营漫延。蜀军大乱，被吴军连破四十余营。陆逊火烧连营的成功，决定了夷陵之战蜀败吴胜的结果。
 
【问题描述】
刘备带兵深入吴境，陆逊却避而不出，蜀军只得在山林中安营扎寨。而刘备在扎营时却犯了兵家大忌，将兵营排列成一条直线，远远看去，就像是一条串着珠子的链，美其名曰：链寨。如果吴军将领是一般人，那么这也许不算什么，而陆逊何许人也，他可是江东才子，能力不低于周瑜的一代儒将。他看到刘备这样排阵，心生一计，决定用火攻破阵。然而，火计除了要有风，选定引火点也非常重要，对于刘备的布阵，最佳引火点一定是n个兵营中的一个。而因为风水轮流转，每天的最佳引火点都不一样。我们给每个兵营定下一个固定不变的火攻值Ai，每天定下一个风水值K，对于每天的最佳引火点，显然是所有兵营中火攻值与风水值异或的结果最大的那一个兵营。然而，陆逊是个谨慎的人，他要观察时机，在m天中选定一个最佳的进攻的日期，为此他演算出了这m天每天的风水值，然后他希望你能够告诉他这m天每天最佳引火点的兵营编号。

 

Input

第一行n,m，代表有n个兵营，m天。
    接下来一行有n个非负整数，代表这n个兵营的火攻值。
    接下来一行有m个非负整数，代表这m天的风水值。

Output

输出共m行，每行输出一个整数，代表第m天最佳引火点的编号。
如果存在多个最佳引火点使得火攻值与风水值的异或值最大，请任意输出一组解即可。

 

Sample Input

3 2
1 2 3
4 5

Sample Output

3
2

【样例解释】
对于第1天，由于4 xor 1=5, 4 xor 2=6, 4 xor 3=7，选择第3个引火点是最佳的。
对于第2天，由于5 xor 1=4, 5 xor 2=7, 5 xor 3=6，选择第2个引火点是最佳的。

 

Data Constraint

对于30%数据，n<=1000，m<=1000
对于100%数据，n<=100000，m<=100000, 0<=k,ai<=2147483647

 

　　　　这不是一道常规的二进制 trie 树？

　　　　部分分超好拿，n² 的暴力只要不打挂，5 min 就能敲诈走30分！

　　　　然后回去打了 1 h 的第二题 10 分暴力分~

　　　　比赛后面的 1 h 一直看着这道题，然而什么也没发现！！！（心态大崩*9）

　　　　正解：把读入的数的二进制加入 trie 树中，那么询问时，我们要尽量的走与询问数的二进制相反的点，因为这样异或之后就可以让那一位变成 1，很简单不是吗？

　　　　（然而我比赛时没想到？？？心态大崩*10）

　　　　附官方正解：

　　　题目大意就是对于一个序列，多次询问求在 xor K 的情况下的最大值。

　　　我们将每一个数拆分成 2 进制，然后映射进一棵 trie 中，然后对于每个询问，根据异或的性质 (1 xor 1=0,1 xor 0=1,0 xor 1=1,0 xor 0=0) 尽可能的匹配，因为是 32 位整数，所以每次询问效率就是 O(32)。

　　　对于水平较高的同学可以思考一下如果改成区间询问该如何做。 （额这个算了吧！心态大崩*11）

　

　　　　　　　

var
        trie:array[0..10000001,0..1] of longint;
        ans:array[0..10000001] of longint;
        n,m,i,j,k,t,x,s:longint;
begin
        readln(n,m);
        k:=1;
        for i:=1 to n do         //建 trie 树
        begin
                read(x);
                s:=0;
                for j:=31 downto 1 do
                begin
                        t:=(x>>(j-1)) and 1;
                        if trie[s,t]=0 then
                        begin
                                inc(k);
                                trie[s,t]:=k;
                                s:=k;
                                ans[k]:=i;
                        end else s:=trie[s,t];
                end;
        end;
        readln;
        for i:=1 to m do         //输出答案
        begin
                read(x);
                s:=0;
                for j:=31 downto 1 do
                begin
                        t:=((x>>(j-1)) and 1+1) and 1; 
                        //取反，本来原位置上是 1 则 t=0，反之
                        if trie[s,t]=0 then s:=trie[s,(t+1) and 1]
                                else s:=trie[s,t];    
                        //尽可能取反匹配，匹配不了就算了~
                end;
                writeln(ans[s]);
        end;
        readln;
end.            

---

 　　　　

　　　　此系列的题码量总体很（chao）少（40、65、100），三题码量加起来才其他比赛最难那题相当，所以超好改的！！！

　　　　但是做完题后魏蜀吴三国我都搞不清了啊啊啊！！！

　　　　没什么好总结的，就是时间要控制好。

　　　　还有最短路的几种算法忘得差不多了，调 spfa 竟然调了一个小时？！

　　　　最后就是敲诈部分分（骗分）的能力还有待提高！！！

　　　　（额虽然几乎每次比赛所有的题都是骗分的，很少有比赛中 A 掉的题，但还是不够哎~）