在SQL语句中使用参数

在SQL语句中使用":参数名"的方法传入参数,效果图:

****************************************************************************************************

新建空白工程，在窗体中放入一ADODataSet，三对ADODataSet，DataSource，DBGrid。

源代码如下：

****************************************************************************************************

unit Unit4;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants,
  System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Data.DB, Data.Win.ADODB, Vcl.Grids,
  Vcl.DBGrids;

type
  TForm4 = class(TForm)
    DBGrid1: TDBGrid;
    DBGrid2: TDBGrid;
    DBGrid3: TDBGrid;
    ADODataSet1: TADODataSet;
    DataSource1: TDataSource;
    ADODataSet2: TADODataSet;
    ADODataSet3: TADODataSet;
    DataSource2: TDataSource;
    DataSource3: TDataSource;
    ADOConnection1: TADOConnection;
    procedure FormCreate(Sender: TObject);
    procedure ADODataSet2AfterScroll(DataSet: TDataSet);
    procedure ADODataSet1AfterScroll(DataSet: TDataSet);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form4: TForm4;

implementation

{$R *.dfm}

procedure TForm4.ADODataSet1AfterScroll(DataSet: TDataSet);
begin
  ADODataSet2.Active := false;
  ADODataSet2.Parameters.ParamByName('订单ID1').Value :=
    DataSet.FieldByName('订单ID').Value;
  ADODataSet2.Active := true;
end;

procedure TForm4.ADODataSet2AfterScroll(DataSet: TDataSet);
begin
  ADODataSet3.Active := false;
  ADODataSet3.Parameters.ParamByName('产品ID1').Value :=
    DataSet.FieldByName('产品ID').Value;
  ADODataSet3.Active := true;
end;

procedure TForm4.FormCreate(Sender: TObject);
begin
  // 连接到同一个数据库，三个ADODataSet共用一个Connection;
  with ADOConnection1 do
  begin
    // 连结来源的资讯及使用何种连结特性等连结字串
    ConnectionString :=
      'Provider=Microsoft.Jet.OLEDB.4.0;Data Source=Demons.mdb;Persist Security Info=False';
    // 不弹出登录提示框
    LoginPrompt := false;
    Provider := 'Microsoft.Jet.OLEDB.4.0';
    // 防止其它人连接
    Mode := cmShareDenyNone;
  end;
  // 获取数据库中3订单表中的所有字段
  ADODataSet1.CommandText := 'select * from 3订单';
  ADODataSet1.CursorType := ctStatic;
  // 关联ADOConnection
  ADODataSet1.Connection := ADOConnection1;
  // 根据订单表中的订单ID获取订单明细，:变量名 表示是变量不是字段，:订单ID1可以为任意合法变量名
  ADODataSet2.CommandText := 'select * from 2订单明细 where 订单ID=:订单ID1';
  with ADODataSet2.Parameters.AddParameter do
  begin
    Name := '订单ID1';
    Value := NUll;
  end;
  ADODataSet2.CursorType := ctStatic;
  ADODataSet2.Connection := ADOConnection1;
  // 根据订单明细表中的产品ID获取产品明细
  ADODataSet3.CommandText := 'select * from 1产品 where 产品ID=:产品ID1';
  with ADODataSet3.Parameters.AddParameter do
  begin
    Name := '产品ID1';
    Value := NUll;
  end;
  ADODataSet3.CursorType := ctStatic;
  ADODataSet3.Connection := ADOConnection1;
  DataSource1.DataSet := ADODataSet1;
  DBGrid1.DataSource := DataSource1;
  DataSource2.DataSet := ADODataSet2;
  DBGrid2.DataSource := DataSource2;
  DataSource3.DataSet := ADODataSet3;
  DBGrid3.DataSource := DataSource3;

  // 连接到数据库
  ADODataSet1.Active := true;
  ADODataSet2.Active := true;
  ADODataSet3.Active := true;

end;

end.

 以上代码除了ADODataSet1AfterScroll和ADODataSet2AfterScroll这两个事件，其它完全可以在对象检视器中设置相应属性完成，在代码中完成相应设置会更灵活，可在运行时修改。