ORACLE中LOB字段的使用和维护

摘要：本文通过实例介绍了在ORACLE数据库中通过DBMS_LOB包使用和维护LOB数据类型的基本方法。

关键词：ORACLE DBMS_LOB LOB 维护

中图分类号：TP31

1、引言
    随着社会的发展，在现代信息系统的开发中，需要存储的已不仅仅是简单的文字信息，同时还包括一些图片和音像资料或者是超长的文本。比如开发一套旅游信息系统，每一个景点都有丰富的图片、音像资料和大量的文字介绍。这就要求后台数据库要有存储这些数据的能力。ORACLE公司在其Oracle8i中通过提供LOB字段实现了该功能。

为了便于读者的理解，我们先介绍一些基本的概念：

    在ORACLE数据库中，LOB（Large Objects—大对象）是用来存储大量的二进制和文本数据的一种数据类型（一个LOB字段可存储可多达4GB的数据）。目前，它又分为两种类型：内部LOB和外部LOB。内部LOB将数据以字节流的形式存储在数据库的内部。因而，内部LOB的许多操作都可以参与事务，也可以像处理普通数据一样对其进行备份和恢复操作。Oracle8i支持三种类型的内部LOB：BLOB（二进制数据）、CLOB（单字节字符数据）、NCLOB（多字节国家字符数据）。其中CLOB和NCLOB类型适用于存储超长的文本数据，BLOB字段适用于存储大量的二进制数据，如图像、视频、音频等。目前，Oracle8i只支持一种外部LOB类型，即BFILE类型。在数据库内，该类型仅存储数据在操作系统中的位置信息，而数据的实体以外部文件的形式存在于操作系统的文件系统中。因而，该类型所表示的数据是只读的，不参与事务。该类型可帮助用户管理大量的由外部程序访问的文件。

    为了方便下文的叙述，我们假定使用如下语句在数据库中创建了一张表。

CREATE TABLE view_sites_info
(
site_id NUMBER(3),
audio BLOB DEFAULT empty_blob(),
document CLOB DEFAULT empty_clob(),
video_file BFILE DEFAULT NULL,
constraint PK_TAB_view_sites_info primary key (site_id)
);

2、LOB的使用和维护 
    ORACL提供了多种使用和维护LOB的方式，如使用PL/SQL DBMS_LOB包、调用OCI（Oracle Call Interface）、使用Proc * C/C++、使用JDBC等。
其中最为方便有效的是使用PL/SQL调用DBMS_LOB包，本文就将介绍该方法。在Oracle中，存储在LOB中数据称为LOB的值，
如使用Select 对某一LOB字段进行选择，则返回的不是LOB的值，而是该LOB字段的定位器（可以理解为指向LOB值的指针）。如执行如下的SQL语句：

DECLARE      
	AUDIO_INFO BLOB; 
BEGIN     
	SELECT audio INTO AUDIO_INFO FROM view_sites_info WHERE site_id = 100;     
END;
/

  2.1内部LOB 
DBMS_LOB包中主要提供了以下几个过程供用户对内部LOB字段进行维护。

APPEND（） 将源LOB中的内容加到目的LOB中
COPY（） 从源LOB中复制数据到目的LOB
ERASE（） 删除LOB中全部或部分内容
TRIM（） 将LOB值减少到指定的长度
WRITE（） 向LOB 中写入数据
COMPARE（） 比较两个同种数据类型的LOB的部分或全部值是否相同
GETLENGTH（） 获取LOB的长度
READ（） 从LOB中读出数据

下面我们以最为常用的读和写为例详细介绍这些过程的用法。

    首先介绍一下写过程。该过程的语法为：
/* Formatted on 2006/10/12 19:09 (Formatter Plus v4.8.6) */
DECLARE   
	lobloc   CLOB;   
	buffer   VARCHAR2 (2000);   
	amount   NUMBER          := 20;   
	offset   NUMBER          := 1;
BEGIN
	----初始化要写入的数据
	buffer := 'This is a writing example';   
	amount := LENGTH (buffer);   
 
	SELECT     document         INTO lobloc      -- 获取定位器并锁定行	
	FROM view_sites_info        
	WHERE site_id = 100   
	FOR UPDATE;   
	
	DBMS_LOB.WRITE (lobloc, amount, 1, buffer);   
	COMMIT;
END;
/

 
需要特别指出的是：

I. 在调用写过程前一定要使用SELECT语句检索到定位器且用 FOR UPDATE 子句锁定行，否则不能更新LOB；
II. 写过程从offset指定的位置开始，向LOB中写入长度为amount的数据，原LOB中在这个范围内的任何数据都将被覆盖。
III. 缓冲区的最大容量为32767字节，因此在写入大量数据时需多次调用该过程。

下面再来介绍一下读过程：
/* Formatted on 2006/10/12 19:19 (Formatter Plus v4.8.6) */
DECLARE   
	lobloc   CLOB;   
	buffer   VARCHAR2 (2000);   
	amount   NUMBER          := 2;   
	offset   NUMBER          := 6;
BEGIN   
	SELECT document     
	INTO lobloc		 				--获取定位器
	FROM view_sites_info
	WHERE site_id = 100;   
 
	DBMS_LOB.READ (lobloc, amount, offset, buffer);          --读取数据到缓冲区
	DBMS_OUTPUT.put_line (buffer);                           --显示缓冲区中的数据   
 
	COMMIT;
END;
/
PS:
在oracle中，有4个大对象（lobs）类型可用，分别是blob,clob,bfile,nclob。 

　　下面是对lob数据类型的简单介绍。 

　　l blob:二进制lob，为二进制数据，最长可达4GB，存贮在数据库中。 
　　l clob:字符lob,字符数据,最长可以达到4GB,存贮在数据库中。 
　　l bfile:二进制文件;存贮在数据库之外的只读型二进制数据，最大长度由操作系统限制。 
　　l nclob：支持对字节字符集合(nultibyte characterset)的一个clob列。 

　　对于如何检索和操作这些lob数据一直是oracle数据库开发者经常碰到的问题。下面我将在oracle对lob数据处理的一些方法和技巧，介绍给读者，希望能够对读者以后的开发有所帮助。 
　　oracle中可以用多种方法来检索或操作lob数据。通常的处理方法是通过dbms_lob包。 
　　其他的方法包括使用api(application programming interfaces)应用程序接口和oci（oracle call interface）oracle调用接口程序。 

　　一、在oracle开发环境中我们可以用dbms_lob包来处理！dbms_lob包功能强大，简单应用。既可以用来读取内部的lob对象，也可以用来处理bfile对象。但处理两者之间，还有一点差别。处理内部lob对象（blob,clob）时，可以进行读和写，但处理外部lob对象bfile时，只能进行读操作，写的操作可以用pl/sql处理。另外用sql也可以处理lob，但要注意sql仅可以处理整个lob，不能操作lob的数据片。 
　　在dbms_lob包中内建了read(),append,write()，erase()，copy(),getlength()，substr()等函数，可以很方便地操作lob对象。这里不做深入讨论，读者可以参看相关的书籍。 
　　对于pl/sql，下面介绍一种技巧，用动态的pl/sql语句处理clob对象来传替表名！ 

　　example 1. 
　　动态PL/SQL,对CLOB字段操作可传递表名table_name，表的唯一标志字段名field_id，clob字段名field_name,记录号v_id，开始处理字符的位置v_pos，传入的字符串变量v_clob 
　　修改CLOB的PL/SQL过程：
/* Formatted on 2006/10/12 19:54 (Formatter Plus v4.8.6) */
CREATE OR REPLACE PROCEDURE updateclob (
   table_name   IN   VARCHAR2,
   field_id     IN   VARCHAR2,
   field_name   IN   VARCHAR2,
   v_id         IN   NUMBER,
   v_pos        IN   NUMBER,
   v_clob       IN   VARCHAR2
)
IS
   lobloc      CLOB;
   c_clob      VARCHAR2 (32767);
   amt         BINARY_INTEGER;
   pos         BINARY_INTEGER;
   query_str   VARCHAR2 (1000);
BEGIN
   pos := v_pos * 32766 + 1;
   amt := LENGTH (v_clob);
   c_clob := v_clob;
   query_str :=
         'select '
      || field_name
      || ' from '
      || table_name
      || ' where '
      || field_id
      || '= :id for update ';
   --initialize buffer with data to be inserted or updated
   EXECUTE IMMEDIATE query_str
                INTO lobloc
               USING v_id;
   --from pos position, write 32766 varchar2 into lobloc
   DBMS_LOB.WRITE (lobloc, amt, pos, c_clob);
   COMMIT;
EXCEPTION
   WHEN OTHERS
   THEN
      ROLLBACK;
END;
/
用法说明： 
　　在插入或修改以前，先把其它字段插入或修改，CLOB字段设置为空empty_clob()， 
　　然后调用以上的过程插入大于2048到32766个字符。 
　　如果需要插入大于32767个字符，编一个循环即可解决问题。 

　　查询CLOB的PL/SQL函数：getclob 
/* Formatted on 2006/10/12 19:50 (Formatter Plus v4.8.6) */
CREATE OR REPLACE FUNCTION getclob (
   table_name   IN   VARCHAR2,
   field_id     IN   VARCHAR2,
   field_name   IN   VARCHAR2,
   v_id         IN   NUMBER,
   v_pos        IN   NUMBER
)
   RETURN VARCHAR2
IS
   lobloc      CLOB;
   buffer      VARCHAR2 (32767);
   amount      NUMBER           := 2000;
   offset      NUMBER           := 1;
   query_str   VARCHAR2 (1000);
BEGIN
   query_str :=
         'select '
      || field_name
      || ' from '
      || table_name
      || ' where '
      || field_id
      || '= :id ';
   --initialize buffer with data to be found
   EXECUTE IMMEDIATE query_str
                INTO lobloc
               USING v_id;
   offset := offset + (v_pos - 1) * 2000;
   --read 2000 varchar2 from the buffer
   DBMS_LOB.READ (lobloc, amount, offset, buffer);
   RETURN buffer;
EXCEPTION
   WHEN NO_DATA_FOUND
   THEN
      RETURN buffer;
END;
/
　　l 用法说明： 
　　用select getclob(table_name,field_id,field_name,v_id,v_pos) as partstr from dual; 
　　可以从CLOB字段中取2000个字符到partstr中， 
　　编一个循环可以把partstr组合成dbms_lob.getlength(field_name)长度的目标字符串。