poj3481

平衡树的题，应该还有什么最大堆最小堆的解法

题目描述 http://poj.org/problem?id=3481

题目大意：给你一系列操作，0代表读入终止，1代表添加一个编号为k，权值为p的点，2代表输出权值最大点的编号并删除该点，3代表输出权值最小的点并删除该节点。

我用的treap，基本上还可以，会一种平衡树是必要的

详细解释在代码内部

skysun原创，http://www.cnblogs.com/skysun

program sky;
const
   maxn    = 1000000;
type
   aa = array[0..1000000] of record
      l,r,w,b,c    : longint;
   end;
var
   p,w,k     : longint;
   root,tp,tot : longint;
   a           : aa;

procedure left(var e :longint );{几乎每个过程都要var，因为改变了树的形态，需要传出去}
var j : longint;
begin
   j:=a[e].l;
   a[e].l:=a[j].r;
   a[j].r:=e;
   e:=j;
end; { left }
procedure right(var e :longint );
var j : longint;
begin
   j:=a[e].r;
   a[e].r:=a[j].l;
   a[j].l:=e;
   e:=j;
end; { right }

procedure ins(var e: longint );{这也要var，因为它也会改变树的形态，使根改变}
begin
   if e=0 then
   begin
      inc(tot);
      a[tot].w:=w; a[tot].b:=random(maxn); a[tot].c:=k;
      a[tot].l:=0; a[tot].r:=0;
      e:=tot;
      exit;
   end;
   if a[e].w>=w then
   begin
      ins(a[e].l);
      if a[e].b>a[a[e].l].b then left(e);
      exit;
   end;
   if a[e].w<w then
   begin
      ins(a[e].r);
      if a[e].b>a[a[e].r].b then right(e);
      exit;
   end;
end; { ins }

procedure delete(var e :longint);
begin
   if a[e].w=a[tp].w then
   begin
      if a[e].l*a[e].r=0 then begin e:=a[e].l+a[e].r; exit; end;
      if a[a[e].l].b<a[a[e].r].b then
      begin {左旋之后原结点会到新的根的右边}
     left(e); {所以左旋，向右递归}
     delete(a[e].r);
     exit;
      end else
      begin
     right(e); {同上}
     delete(a[e].l);
     exit;
      end;
   end;
   if a[tp].w>a[e].w then begin delete(a[e].r); exit; end;
   if a[tp].w<a[e].w then begin delete(a[e].l); exit; end;
end; { delete }

function getmax(e :longint ):longint;
begin
   while a[e].r<>0 do e:=a[e].r;
   exit(e); {返回在树里的编号，不要返回读入的编号，不然可以输出，但delete就没办法了}
end; { getmax }
function getmin(e :longint ):longint;
begin
   while a[e].l<>0 do e:=a[e].l;
   exit(e);
end; { getmin }

begin
   assign(input,'tiaoshi.in'); reset(input);
   read(p);
   randomize;
   root:=0;
   while p<>0 do
   begin
      case p of
    1 : begin readln(k,w); ins(root); end; {这里每一个过程都传root，因为平衡树跟在变}
    2 : begin tp:=getmax(root); writeln(a[tp].c); delete(root); end;
    3 : begin tp:=getmin(root); writeln(a[tp].c); delete(root); end;
      end; { case }
      read(p);
   end;
end.