【zt】delphi线程类

Delphi中有一个线程类TThread是用来实现多线程编程的,这个绝大多数Delphi书藉都有说到,但基本上都是对TThread类的几个成员作一简单介绍,再说明一下Execute的实现和Synchronize的用法就完了.然而这并不是多线 ...     Delphi中有一个线程类TThread是用来实现多线程编程的,这个绝大多数Delphi书藉都有说到,但基本上都是对TThread类的几个成员作 一简单介绍,再说明一下Execute的实现和Synchronize的用法就完了.然而这并不是多线程编程的全部,我写此文的目的在于对此作一个补充.
    线程本质上是进程中一段并发运行的代码.一个进程至少有一个线程,即所谓的主线程.同时还可以有多个子线程.当一个进程中用到超过一个线程时,就是所谓的"多线程".
    那么这个所谓的"一段代码"是如何定义的呢?其实就是一个函数或过程(对Delphi而言).
    如果用Windows API来创建线程的话,是通过一个叫做CreateThread的API函数来实现的,它的定义为:
    HANDLE CreateThread(
    LPSECURITY_ATTRIBUTES lpThreadAttributes, //线程属性(用于在NT下进行线程的安全属性设置,在9X下无效),
    DWORD dwStackSize,    //堆栈大小
    LPTHREAD_START_ROUTINE lpStartAddress, //起始地址
    LPVOID lpParameter, //参数
    DWORD dwCreationFlags, //创建标志(用于设置线程创建时的状态)
    LPDWORD lpThreadId 线程ID
    );
    最后返回线程Handle.其中的起始地址就是线程函数的入口,直至线程函数结束,线程也就结束了.
    因为CreateThread参数很多,而且是Windows的API,所以在C Runtime Library里提供了一个通用的线程函数(理论上可以在任何支持线程的OS中使用):
    unsigned long _beginthread(void (_USERENTRY *__start)(void *), unsigned __stksize, void *__arg);
    Delphi也提供了一个相同功能的类似函数:
    function BeginThread(
    SecurityAttributes: Pointer;
    StackSize: LongWord;
    ThreadFunc: TThreadFunc;
    Parameter: Pointer;
    CreationFlags: LongWord;
    var ThreadId: LongWord
    ): Integer;

    这三个函数的功能是基本相同的,它们都是将线程函数中的代码放到一个独立的线程中执行.线程函数与一般函数的最大不同在于,线程函数一启动,这三个线程启 动函数就返回了,主线程继续向下执行,而线程函数在一个独立的线程中执行,它要执行多久,什么时候返回,主线程是不管也不知道的.

   正常情况下,线程函数返回后,线程就终止了.但也有其它方式:
    Windows API:
    VOID ExitThread( DWORD dwExitCode );
    C Runtime Library:
    void _endthread(void);
    Delphi Runtime Library:
    procedure EndThread(ExitCode: Integer);
    为了记录一些必要的线程数据(状态/属性等),OS会为线程创建一个内部Object,如在Windows中那个Handle便是这个内部Object的Handle,所以在线程结束的时候还应该释放这个Object.
    虽然说用API或RTL(Runtime Library)已经可以很方便地进行多线程编程了,但是还是需要进行较多的细节处理,为此Delphi在Classes单元中对线程作了一个较好的封装,这就是VCL的线程类:TThread
    使用这个类也很简单,大多数的Delphi书籍都有说,基本用法是:先从TThread派生一个自己的线程类(因为TThread是一个抽象类,不能生成 实例),然后是Override抽象方法:Execute(这就是线程函数,也就是在线程中执行的代码部分),如果需要用到可视VCL对象,还需要通过 Synchronize过程进行.关于之方面的具体细节,这里不再赘述,请参考相关书籍.
    本文接下来要讨论的是TThread类是如何对线程进行封装的,也就是深入研究一下TThread类的实现.因为只是真正地了解了它,才更好地使用它.

    下面是DELPHI7中TThread类的声明(本文只讨论在Windows平台下的实现,所以去掉了所有有关Linux平台部分的代码):

 1     TThread = class
 2     private
 3     FHandle: THandle;
 4     FThreadID: THandle;
 5     FCreateSuspended: Boolean;
 6     FTerminated: Boolean;
 7     FSuspended: Boolean;
 8     FFreeOnTerminate: Boolean;
 9     FFinished: Boolean;
     FReturnValue: Integer;
     FOnTerminate: TNotifyEvent;
     FSynchronize: TSynchronizeRecord;
     FFatalException: TObject;
     procedure CallOnTerminate;
     class procedure Synchronize(ASyncRec: PSynchronizeRecord); overload;
     function GetPriority: TThreadPriority;
     procedure SetPriority(Value: TThreadPriority);
     procedure SetSuspended(Value: Boolean);
     protected
     procedure CheckThreadError(ErrCode: Integer); overload;
     procedure CheckThreadError(Success: Boolean); overload;
     procedure DoTerminate; virtual;
     procedure Execute; virtual; abstract;
     procedure Synchronize(Method: TThreadMethod); overload;
     property ReturnValue: Integer read FReturnValue write FReturnValue;
     property Terminated: Boolean read FTerminated;
     public
     constructor Create(CreateSuspended: Boolean);
     destructor Destroy; override;
     procedure AfterConstruction; override;
     procedure Resume;
     procedure Suspend;
     procedure Terminate;
     function WaitFor: LongWord;
     class procedure Synchronize(AThread: TThread; AMethod: TThreadMethod); overload;
     class procedure StaticSynchronize(AThread: TThread; AMethod: TThreadMethod);
     property FatalException: TObject read FFatalException;
     property FreeOnTerminate: Boolean read FFreeOnTerminate write FFreeOnTerminate;
     property Handle: THandle read FHandle;
     property Priority: TThreadPriority read GetPriority write SetPriority;
     property Suspended: Boolean read FSuspended write SetSuspended;
     property ThreadID: THandle read FThreadID;
     property OnTerminate: TNotifyEvent read FOnTerminate write FOnTerminate;
     end;

    TThread类在Delphi的RTL里算是比较简单的类,类成员也不多,类属性都很简单明白,本文将只对几个比较重要的类成员方法和唯一的事件:OnTerminate作详细分析.

    首先就是构造函数:

 1     constructor TThread.Create(CreateSuspended: Boolean);
 2     begin
 3     inherited Create;
 4     AddThread;
 5     FSuspended := CreateSuspended;
 6     FCreateSuspended := CreateSuspended;
 7     FHandle := BeginThread(nil, 0, @ThreadProc, Pointer(Self), Create_SUSPENDED, FThreadID);
 8     if FHandle = 0 then
 9     raise EThread.CreateResFmt(@SThreadCreateError, [SysErrorMessage(GetLastError)]);
10     end;

     虽然这个构造函数没有多少代码,但却可以算是最重要的一个成员,因为线程就是在这里被创建的.

    在通过Inherited调用TObject.Create后,第一句就是调用一个过程:AddThread,其源码如下:

    procedure AddThread;
    begin
    InterlockedIncrement(ThreadCount);
    end;

 同样有一个对应的RemoveThread:

    procedure RemoveThread;
    begin
    InterlockedDecrement(ThreadCount);
    end;

     它们的功能很简单,就是通过增减一个全局变量来统计进程中的线程数.只是这里用于增减变量的并不是常用的Inc/Dec过程,而是用了 InterlockedIncrement/InterlockedDecrement这一对过程,它们实现的功能完全一样,都是对变量加一或减一.但它 们有一个最大的区别,那就是interlockedIncrement/InterlockedDecrement是线程安全的.即它们在多线程下能保证 执行结果正确,而Inc/Dec不能.或者按操作系统理论中的术语来说,这是一对"原语"操作. 以加一为例来说明二者实现细节上的不同:
    一般来说,对内存数据加一的操作分解以后有三个步骤:
    1、 从内存中读出数据
    2、 数据加一
    3、 存入内存
    现在假设在一个两个线程的应用中用Inc进行加一操作可能出现的一种情况:
    1、 线程A从内存中读出数据(假设为3)
    2、 线程B从内存中读出数据(也是3)
    3、 线程A对数据加一(现在是4)
    4、 线程B对数据加一(现在也是4)
    5、 线程A将数据存入内存(现在内存中的数据是4)
    6、 线程B也将数据存入内存(现在内存中的数据还是4,但两个线程都对它加了一,应该是5才对,所以这里出现了错误的结果)
    而用InterlockIncrement过程则没有这个问题,因为所谓"原语"是一种不可中断的操作,即操作系统能保证在一个"原语"执行完毕前不会进 行线程切换.所以在上面那个例子中,只有当线程A执行完将数据存入内存后,线程B才可以开始从中取数并进行加一操作,这样就保证了即使是在多线程情况下, 结果也一定会是正确的.前面那个例子也说明一种"线程访问冲突"的情况,这也就是为什么线程之间需要"同步"Synchronize),关于这个,在后面 说到同步时还会再详细讨论.
    说到同步,有一个题外话:加拿大滑铁卢大学的教授李明曾就Synchronize一词在"线程同步"中被译作"同步"提出过异议,个人认为他说的其实很有 道理.在中文中"同步"的意思是"同时发生",而"线程同步"目的就是避免这种"同时发生"的事情.而在英文中,Synchronize的意思有两个:一 个是传统意义上的同步(To occur at the same time),另一个是"协调一致"(To operate in unison).在"线程同步"中的Synchronize一词应该是指后面一种意思,即"保证多个线程在访问同一数据时,保持协调一致,避免出错".不 过像这样译得不准的词在IT业还有很多,既然已经是约定俗成了,本文也将继续沿用,只是在这里说明一下,因为软件开发是一项细致的工作,该弄清楚的,绝不 能含糊.
    扯远了,回到TThread的构造函数上,接下来最重要就是这句了:
    FHandle := BeginThread(nil, 0, @ThreadProc, Pointer(Self), Create_SUSPENDED, FThreadID);
    这里就用到了前面说到的Delphi RTL函数BeginThread,它有很参数,关键的是第三、四两个参数.第三个参数就是前面说到的线程函数,即在线程中执行的代码部分.第四个参数则是传递给线程函数的参数,在这里就是创建的 线程对象(即Self).其它的参数中,第五个是用于设置线程在创建后即挂起,不立即执行(启动线程的工作是在AfterConstruction中根据 CreateSuspended标志来决定的),第六个是返回线程ID.
    现在来看TThread的核心:线程函数ThreadProc.有意思的是这个线程类的核心却不是线程的成员,而是一个全局函数

    (因为BeginThread过程的参数约定只能用全局函数).下面是它的代码:

 1    function ThreadProc(Thread: TThread): Integer;
 2    var
 3    FreeThread: Boolean;
 4    begin
 5    try
 6    if not Thread.Terminated then
 7    try
 8    Thread.Execute;
 9    except
10    Thread.FFatalException := AcquireExceptionObject;
11    end;
12    finally
13    FreeThread := Thread.FFreeOnTerminate;
14    Result := Thread.FReturnValue;
15    Thread.DoTerminate;
16    Thread.FFinished := True;
17    SignalSyncEvent;
18    if FreeThread then Thread.Free;
19    EndThread(Result);
20    end;
21    end;

     虽然也没有多少代码,但却是整个TThread中最重要的部分,因为这段代码是真正在线程中执行的代码.下面对代码作逐行说明:
    首先判断线程类的Terminated标志,如果未被标志为终止,则调用线程类的Execute方法执行线程代码,因为TThread是抽象类,Execute方法是抽象方法,所以本质上是执行派生类中的Execute代码.
    所以说,Execute就是线程类中的线程函数,所有在Execute中的代码都需要当作线程代码来考虑,如防止访问冲突等.如果Execute发生异 常,则通过AcquireExceptionObject取得异常对象,并存入线程类的FFatalException成员中.
    最后是线程结束前做的一些收尾工作.局部变量FreeThread记录了线程类的FreeOnTerminated属性的设置,然后将线程返回值设置为线程类的返回值属性的值.然后执行线程类的DoTerminate方法.

    DoTerminate方法的代码如下:

    procedure TThread.DoTerminate;
    begin
    if Assigned(FOnTerminate) then Synchronize(CallOnTerminate);
    end;

     很简单,就是通过Synchronize来调用CallOnTerminate方法,而CallOnTerminate方法的代码如下,就是简单地调用OnTerminate事件:

    procedure TThread.CallOnTerminate;
    begin
    if Assigned(FOnTerminate) then FOnTerminate(Self);
    end;

     因为OnTerminate事件是在Synchronize中执行的,所以本质上它并不是线程代码,而是主线程代码(具体见后面对Synchronize的分析).

    执行完OnTerminate后,将线程类的FFinished标志设置为True.接下来执行SignalSyncEvent过程,其代码如下:

    procedure SignalSyncEvent;
    begin
    SetEvent(SyncEvent);
    end;

     也很简单,就是设置一下一个全局Event:SyncEvent,关于Event的使用,本文将在后文详述,而SyncEvent的用途将在WaitFor过程中说明.
    然后根据FreeThread中保存的FreeOnTerminate设置决定是否释放线程类,在线程类释放时,还有一些些操作,详见接下来的析构函数实现.
    最后调用EndThread结束线程,返回线程返回值.至此,线程完全结束.

    说完构造函数,再来看析构函数:

 1     destructor TThread.Destroy;
 2     begin
 3     if (FThreadID <> 0) and not FFinished then begin
 4     Terminate;
 5     if FCreateSuspended then
 6     Resume;
 7     WaitFor;
 8     end;
 9     if FHandle <> 0 then CloseHandle(FHandle);
10     inherited Destroy;
11     FFatalException.Free;
12     RemoveThread;
13     end;

     在线程对象被释放前,首先要检查线程是否还在执行中,如果线程还在执行中(线程ID不为0,并且线程结束标志未设置),则调用Terminate过程结束线程.Terminate过程只是简单地设置线程类的Terminated标志,如下面的代码:

    procedure TThread.Terminate;
    begin
    FTerminated := True;
    end;

     所以线程仍然必须继续执行到正常结束后才行,而不是立即终止线程,这一点要注意.
    在这里说一点题外话:很多人都问过我,如何才能"立即"终止线程(当然是指用TThread创建的线程).结果当然是不行!终止线程的唯一办法就是让 Execute方法执行完毕,所以一般来说,要让你的线程能够尽快终止,必须在Execute方法中在较短的时间内不断地检查Terminated标志, 以便能及时地退出.这是设计线程代码的一个很重要的原则!
    当然如果你一定要能"立即"退出线程,那么TThread类不是一个好的选择,因为如果用API强制终止线程的话,最终会导致TThread线程对象不能 被正确释放,在对象析构时出现Access Violation.这种情况你只能用API或RTL函数来创建线程.
    如果线程处于启动挂起状态,则将线程转入运行状态,然后调用WaitFor进行等待,其功能就是等待到线程结束后才继续向下执行.关于WaitFor的实现,将放到后面说明.
    线程结束后,关闭线程Handle(正常线程创建的情况下Handle都是存在的),释放操作系统创建的线程对象.
    然后调用TObject.Destroy释放本对象,并释放已经捕获的异常对象,最后调用RemoveThread减小进程的线程数.
    其它关于Suspend/Resume及线程优先级设置等方面,不是本文的重点,不再赘述.下面要讨论的是本文的另两个重点
    :Synchronize和WaitFor.
    但是在介绍这两个函数之前,需要先介绍另外两个线程同步技术:事件和临界区.
    事件(Event)与Delphi中的事件有所不同.从本质上说,Event其实相当于一个全局的布尔变量.它有两个赋值操作:Set和Reset,相当 于把它设置为True或False.而检查它的值是通过WaitFor操作进行.对应在Windows平台上,是三个API函数:SetEvent、 ResetEvent、WaitForSingleObject(实现WaitFor功能的API还有几个,这是最简单的一个).
    这三个都是原语,所以Event可以实现一般布尔变量不能实现的在多线程中的应用.Set和Reset的功能前面已经说过了,现在来说一下WaitFor的功能:
    WaitFor的功能是检查Event的状态是否是Set状态(相当于True),如果是则立即返回,如果不是,则等待它变为Set状态,在等待期间,调 用WaitFor的线程处于挂起状态.另外WaitFor有一个参数用于超时设置,如果此参数为0,则不等待,立即返回Event的状态,如果是 INFINITE则无限等待,直到Set状态发生,若是一个有限的数值,则等待相应的毫秒数后返回Event的状态.
    当Event从Reset状态向Set状态转换时,唤醒其它由于WaitFor这个Event而挂起的线程,这就是它为什么叫Event的原因.所谓"事件"就是指"状态的转换".通过Event可以在线程间传递这种"状态转换"信息.
    当然用一个受保护(见下面的临界区介绍)的布尔变量也能实现类似的功能,只要用一个循环检查此布尔值的代码来代替WaitFor即可.从功能上说完全没有 问题,但实际使用中就会发现,这样的等待会占用大量的CPU资源,降低系统性能,影响到别的线程的执行速度,所以是不经济的,有的时候甚至可能会有问题. 所以不建议这样用.
    临界区(CriticalSection)则是一项共享数据访问保护的技术.它其实也是相当于一个全局的布尔变量.但对它的操作有所不同,它只有两个操 作:Enter和Leave,同样可以把它的两个状态当作True和False,分别表示现在是否处于临界区中.这两个操作也是原语,所以它可以用于在多 线程应用中保护共享数据,防止访问冲突.
    用临界区保护共享数据的方法很简单:在每次要访问共享数据之前调用Enter设置进入临界区标志,然后再操作数据,最后调用Leave离开临界区.它的保 护原理是这样的:当一个线程进入临界区后,如果此时另一个线程也要访问这个数据,则它会在调用Enter时,发现已经有线程进入临界区,然后此线程就会被 挂起,等待当前在临界区的线程调用Leave离开临界区,当另一个线程完成操作,调用Leave离开后,此线程就会被唤醒,并设置临界区标志,开始操作数 据,这样就防止了访问冲突.

    以前面那个InterlockedIncrement为例,我们用CriticalSection(Windows API)来实现它:

    Var
    InterlockedCrit : TRTLCriticalSection;
    Procedure InterlockedIncrement( var aValue : Integer );
    Begin
    EnterCriticalSection( InterlockedCrit );
    Inc( aValue );
    LeaveCriticalSection( InterlockedCrit );
    End;

     现在再来看前面那个例子:
    1. 线程A进入临界区(假设数据为3)
    2. 线程B进入临界区,因为A已经在临界区中,所以B被挂起
    3. 线程A对数据加一(现在是4)
    4. 线程A离开临界区,唤醒线程B(现在内存中的数据是4)
    5. 线程B被唤醒,对数据加一(现在就是5了)
    6. 线程B离开临界区,现在的数据就是正确的了.
    临界区就是这样保护共享数据的访问.

    关于临界区的使用,有一点要注意:即数据访问时的异常情况处理.因为如果在数据操作时发生异常,将导致Leave操作没有被执行,结果将使本应被唤醒的线程未被唤醒,可能造成程序的没有响应.所以一般来说,如下面这样使用临界区才是正确的做法:

    EnterCriticalSection
    Try
    // 操作临界区数据
    Finally
    LeaveCriticalSection
    End;

     最后要说明的是,Event和CriticalSection都是操作系统资源,使用前都需要创建,使用完后也同样需要释放.如
    TThread类用到的一个全局Event:SyncEvent和全局CriticalSection:TheadLock,都是在 InitThreadSynchronization和DoneThreadSynchronization中进行创建和释放的,而它们则是在 Classes单元的Initialization和Finalization中被调用的.
    由于在TThread中都是用API来操作Event和CriticalSection的,所以前面都是以API为例,其实Delphi已经提供了对它们 的封装,在SyncObjs单元中,分别是TEvent类和TCriticalSection类.用法也与前面用API的方法相差无几.因为TEvent 的构造函数参数过多,为了简单起见,Delphi还提供了一个用默认参数初始化的Event类:TSimpleEvent.
    顺便再介绍一下另一个用于线程同步的类:TMultiReadExclusiveWriteSynchronizer,它是在SysUtils单元中定义的.据我所知,这是Delphi RTL中定义的最长的一个类名,还好它有一个短的别名:TMREWSync.至于它的用处,我想光看名字就可以知道了,我也就不多说了.
    有了前面对Event和CriticalSection的准备知识,可以正式开始讨论Synchronize和WaitFor了.

    我们知道,Synchronize是通过将部分代码放到主线程中执行来实现线程同步的,因为在一个进程中,只有一个主线程.先来看看Synchronize的实现:

 1    class procedure TThread.Synchronize(ASyncRec: PSynchronizeRecord);
 2    var
 3    SyncProc: TSyncProc;
 4    begin
 5    if GetCurrentThreadID = MainThreadID then
 6    ASyncRec.FMethod
 7    //首先是判断当前线程是否是主线程,如果是,则简单地执行同步方法后返回.
 8    else begin
 9    SyncProc.Signal := CreateEvent(nil, True, False, nil);
10    {通过局部变量SyncProc记录线程交换数据(参数)和一个Event Handle,其记录结构如下:
11    TSyncProc = record
12    SyncRec: PSynchronizeRecord;
13    Signal: THandle;
14    end; }
15    try
16    EnterCriticalSection(ThreadLock);
17    {
18    接着进入临界区(通过全局变量ThreadLock进行,因为同时只能有一个线程进入Synchronize状态,所以可以用全局变量记录)
19    }
20    try
21    {然后就是把这个记录数据存入SyncList这个列表中(如果这个列表不存在的话,则创建它).}
22    if SyncList = nil then SyncList := TList.Create;
23    //
24    SyncProc.SyncRec := ASyncRec;
25    SyncList.Add(@SyncProc);
26    { 再接下就是调用SignalSyncEvent,其代码在前面介绍TThread的构造函数时已经介绍过了,它的功能就是简单地将SyncEvent作一个Set的操作.关于这个SyncEvent的用途,将在后面介绍WaitFor时再详述.}
27    SignalSyncEvent;
28    {接下来就是最主要的部分了:调用WakeMainThread事件进行同步操作.WakeMainThread是一个TNotifyEvent类型的全局事件.这里之所以要用事件进行处理,是因为Synchronize方法本质上是通过消息,将需要同步的过程放到主线程中执行,如果在一些没有消息循环的应用中(如Console或DLL)是无法使用的,所以要使用这个事件进行处理.}
29    if Assigned(WakeMainThread) then WakeMainThread(SyncProc.SyncRec.FThread);
30    LeaveCriticalSection(ThreadLock);
31    //在执行完WakeMainThread事件后,就退出临界区
32    try
33    WaitForSingleObject(SyncProc.Signal, INFINITE);
34    {然后调用WaitForSingleObject开始等待在进入临界区前创建的那个Event.这个Event的功能是等待这个同步方法的执行结束,关于这点,在后面分析CheckSynchronize时会再说明.}
35    finally
36    EnterCriticalSection(ThreadLock);
37    end;
38    {注意在WaitForSingleObject之后又重新进入临界区,但没有做任何事就退出了,似乎没有意义,但这是必须的!
39    因为临界区的Enter和Leave必须严格的一一对应.那么是否可以改成这样呢:
40    if Assigned(WakeMainThread) then
41    WakeMainThread(SyncProc.SyncRec.FThread);
42    WaitForSingleObject(SyncProc.Signal, INFINITE);
43    f inally
44    LeaveCriticalSection(ThreadLock);
45    end;
46    上面的代码和原来的代码最大的区别在于把WaitForSingleObject也纳入临界区的限制中了.看上去没什么影响,还使代码大大简化了,但真的可以吗?事实上是不行!
47    因为我们知道,在Enter临界区后,如果别的线程要再进入,则会被挂起.而WaitFor方法则会挂起当前线程,直到等待别的线程SetEvent后才会被唤醒.如果改成上面那样的代码的话,如果那个SetEvent的线程也需要进入临界区的话,死锁(Deadlock)就发生了(关于死锁的理论,请自行参考操作系统原理方面的资料).死锁是线程同步中最需要注意的方面之一!
48    }
49    finally
50    LeaveCriticalSection(ThreadLock);
51    end;
52    finally
53    CloseHandle(SyncProc.Signal);
54    end;
55    //最后释放开始时创建的Event,如果被同步的方法返回异常的话,还会在这里再次抛出异常.
56    if Assigned(ASyncRec.FSynchronizeException) then
57    raise ASyncRec.FSynchronizeException;
58    end;
59    end;

     这段代码略多一些,不过也不算太复杂.
    可见ThreadLock这个临界区就是为了保护对SyncList的访问,这一点在后面介绍CheckSynchronize时会再次看到.

    而响应这个事件的是Application对象,下面两个方法分别用于设置和清空WakeMainThread事件的响应(来自Forms单元):

    procedure TApplication.HookSynchronizeWakeup;
    begin
    Classes.WakeMainThread := WakeMainThread;
    end;
    procedure TApplication.UnhookSynchronizeWakeup;
    begin
    Classes.WakeMainThread := nil;
    end;

     上面两个方法分别是在TApplication类的构造函数和析构函数中被调用.

    这就是在Application对象中WakeMainThread事件响应的代码,消息就是在这里被发出的,它利用了一个空消息来实现:

    procedure TApplication.WakeMainThread(Sender: TObject);
    begin
    PostMessage(Handle, WM_NULL, 0, 0);
    end;

    而这个消息的响应也是在Application对象中,见下面的代码(删除无关的部分):

    procedure TApplication.WndProc(var Message: TMessage);
    …
    begin
    try
    …
    with Message do
    case Msg of
    …
    WM_NULL:
    CheckSynchronize;
    …
    except
    HandleException(Self);
    end;
    end;

     其中的CheckSynchronize也是定义在Classes单元中的,由于它比较复杂,暂时不详细说明,只要知道它是具体处理Synchronize功能的部分就好.

    回到前面CheckSynchronize,见下面的代码:

 1    function CheckSynchronize(Timeout: Integer = 0): Boolean;
 2    var
 3    SyncProc: PSyncProc;
 4    LocalSyncList: TList;
 5    begin
 6    //首先,这个方法必须在主线程中被调用(如前面通过消息传递到主线程),否则就抛出异常.
 7    if GetCurrentThreadID <> MainThreadID then
 8    raise EThread.CreateResFmt(@SCheckSynchronizeError, [GetCurrentThreadID]);
 9    {接下来调用ResetSyncEvent(它与前面SetSyncEvent对应的,之所以不考虑WaitForSyncEvent的情况,是因为只有在Linux版下才会调用带参数的CheckSynchronize,Windows版下都是调用默认参数0的CheckSynchronize).}
10    if Timeout > 0 then
11    WaitForSyncEvent(Timeout)
12    else
13    ResetSyncEvent;
14    {现在可以看出SyncList的用途了:它是用于记录所有未被执行的同步方法的.因为主线程只有一个,而子线程可能有很多个,当多个子线程同时调用同步方法时,主线程可能一时无法处理,所以需要一个列表来记录它们.}
15    LocalSyncList := nil;
16    EnterCriticalSection(ThreadLock);
17    try
18    Integer(LocalSyncList) := InterlockedExchange(Integer(SyncList), Integer(LocalSyncList));
19    try
20    Result := (LocalSyncList <> nil) and (LocalSyncList.Count > 0);
21    if Result then begin
22    {在这里用一个局部变量LocalSyncList来交换SyncList,这里用的也是一个原语:InterlockedExchange.同样,这里也是用临界区将对SyncList的访问保护起来.只要LocalSyncList不为空,则通过一个循环来依次处理累积的所有同步方法调用.最后把处理完的LocalSyncList释放掉,退出临界区.}
23    while LocalSyncList.Count > 0 do begin
24    {再来看对同步方法的处理:首先是从列表中移出(取出并从列表中删除)第一个同步方法调用数据.然后退出临界区(原因当然也是为了防止死锁).接着就是真正的调用同步方法了.}
25    SyncProc := LocalSyncList[0];
26    LocalSyncList.Delete(0);
27    LeaveCriticalSection(ThreadLock);
28    try
29    try
30    SyncProc.SyncRec.FMethod;
31    except     //如果同步方法中出现异常,将被捕获后存入同步方法数据记录中.
32    SyncProc.SyncRec.FSynchronizeException := AcquireExceptionObject;
33    end;
34    finally
35    EnterCriticalSection(ThreadLock);
36    {重新进入界区后,调用SetEvent通知调用线程,同步方法执行完成了(详见前面Synchronize中的WaitForSingleObject调用).}
37    end;
38    SetEvent(SyncProc.signal);
39    end;
40    end;
41    finally
42    LocalSyncList.Free; //等list的序列全部执行完后,释放list的资源
43    end;
44    finally
45    LeaveCriticalSection(ThreadLock);
46    end;
47    end;

     至此,整个Synchronize的实现介绍完成.

    最后来说一下WaitFor,它的功能就是等待线程执行结束.其代码如下:

 1     function TThread.WaitFor: LongWord;
 2     var
 3     H: array[0..1] of THandle;
 4     WaitResult: Cardinal;
 5     Msg: TMsg;
 6     begin
 7     H[0] := FHandle;
 8     if GetCurrentThreadID = MainThreadID then begin
 9     WaitResult := 0;
10     H[1] := SyncEvent;
11     repeat
12     { This prevents a potential deadlock if the background thread does a SendMessage to the foreground thread }
13     if WaitResult = WAIT_OBJECT_0 + 2 then
14     PeekMessage(Msg, 0, 0, 0, PM_NOREMOVE);
15     WaitResult := MsgWaitForMultipleObjects(2, H, False, 1000, QS_SENDMESSAGE);
16     CheckThreadError(WaitResult <> WAIT_FAILED);
17     if WaitResult = WAIT_OBJECT_0 + 1 then
18     CheckSynchronize;
19     until WaitResult = WAIT_OBJECT_0;
20     end else
21     WaitForSingleObject(H[0], INFINITE);
22     CheckThreadError(GetExitCodeThread(H[0], Result));
23     end;

     如果不是在主线程中执行WaitFor的话,很简单,只要调用WaitForSingleObject等待此线程的Handle为Signaled状态即可.
    如果是在主线程中执行WaitFor则比较麻烦.首先要在Handle数组中增加一个SyncEvent,然后循环等待,直到线程结束(即MsgWaitForMultipleObjects返回WAIT_OBJECT_0,详见MSDN中关于此API的说明).
    在循环等待中作如下处理:如果有消息发生,则通过PeekMessage取出此消息(但并不把它从消息循环中移除),然后调用 MsgWaitForMultipleObjects来等待线程Handle或SyncEvent出现Signaled状态,同时监听消息 (QS_SENDMESSAGE参数,详见MSDN中关于此API的说明).可以把此API当作一个可以同时等待多个Handle的 WaitForSingleObject.如果是SyncEvent被SetEvent(返回WAIT_OBJECT_0 + 1),则调用CheckSynchronize处理同步方法.
    为什么在主线程中调用WaitFor必须用MsgWaitForMultipleObjects,而不能用WaitForSingleObject等待线 程结束呢?因为防止死锁.由于在线程函数Execute中可能调用Synchronize处理同步方法,而同步方法是在主线程中执行的,如果用 WaitForSingleObject等待的话,则主线程在这里被挂起,同步方法无法执行,导致线程也被挂起,于是发生死锁.
    而改用WaitForMultipleObjects则没有这个问题.首先,它的第三个参数为False,表示只要线程Handle或SyncEvent 中只要有一个Signaled即可使主线程被唤醒,至于加上QS_SENDMESSAGE是因为ynchronize是通过消息传到主线程来的,所以还要 防止消息被阻塞.这样,当线程中调用Synchronize时,主线程就会被唤醒并处理同步调用,在调用完成后继续进入挂起等待状态,直到线程结束.
    至此,对线程类TThread的分析可以告一个段落了,对前面的分析作一个总结:
    1、 线程类的线程必须按正常的方式结束,即Execute执行结束,所以在其中的代码中必须在适当的地方加入足够多 的对Terminated标志的判断,并及时退出.如果必须要"立即"退出,则不能使用线程类,而要改用API或RTL函数.
    2、 对可视VCL的访问要放在Synchronize中,通过消息传递到主线程中,由主线程处理.
    3、 线程共享数据的访问应该用临界区进行保护(当然用Synchronize也行).
    4、 线程通信可以采用Event进行(当然也可以用Suspend/Resume).
    5、 当在多线程应用中使用多种线程同步