以前我们讨论的都是CPU对指令的执行。我们知道，CPU 在计算机系统中，除了能够执行指令，进行运算以外，还应该能够对外部设备进行控制，接收它们的输入，向它们进行输出。
也就是说，CPU 除了有运算能力外，还要有 I/O（ Input/Output ，输入/输出）能力。
15.1 接口芯片和端口
第 14 章我们讲过，在PC 系统的接口卡和主板上，装有各种接口芯片。这些外设接口芯片的内部有若干寄存器，CPU 将这些寄存器当作端口来访问。
外设的输入不直接送入内存和CPU ，而是送入相关的接口芯片的端口中；
CPU 向外设的输出也不是直接送入外设，而是先送入端口中，再由相关的芯片送到外设。
CPU 还可以向外设输出控制命令，而这些控制命令也是先送到相关芯片的端口中，然后再由相关的芯片根据命令对外设实施控制。
可见，CPU 通过端口和外部设备进行联系。
CPU 在执行完当前指令后，可以检测到发送过来的中断信息，引发中断过程，处理外设的输入。
15.2 外中断信息
在PC 系统中，外中断源一共有两类：
1、可屏蔽中断
2、不可屏蔽中断
可屏蔽中断是CPU 可以不响应的外中断。CPU 是否响应可屏蔽中断，要看标志寄存器的IF 位的设置。
当CPU 检测到可屏蔽中断信息时：
如果IF=1，则CPU 在执行完当前指令后响应中断，引发中断过程；
如果IF=0，则不响应可屏蔽中断。
我们回忆一下内中断所引发的中断过程：
我们回忆一下内中断所引发的中断过程：
（1）取中断类型码n；
（2）标志寄存器入栈，IF=0，TF=0；
（3）CS 、IP 入栈；
（4）(IP)=(n4)，(CS)=(n4+2)
由此转去执行中断处理程序。
可屏蔽中断所引发的中断过程 ，除在第一步的实现上有所不同外，基本上和内中断的中断过程相同。
因为可屏蔽中断信息来自于CPU外部，中断类型码是通过数据总线送入CPU 的；
而内中断的中断类型码是在CPU内部产生的。
现在，我们可以解释中断过程中将IF置为0的原因了。将IF置0的原因就是，在进入中断处理程序后，禁止其他的可屏蔽中断。
当然，如果在中断处理程序中需要处理可屏蔽中断，可以用指令将IF 置1 。
8086CPU 提供的设置IF的指令如下：
sti，用于设置IF=1；
cli，用于设置IF=0。
不可屏蔽中断是CPU 必须响应的外中断。当CPU 检测到不可屏蔽中断信息时，则在执行完当前指令后，立即响应，引发中断过程。
对于8086CPU 不可屏蔽中断的中断类型码固定为2。所以中断过程中，不需要取中断类型码。
不可屏蔽中断的中断过程：
1、标志寄存器入栈，IF=0，TF=0；
2、CS、IP入栈；
3、(IP)=(8)，(CS)=(0AH)。
几乎所有由外设引发的外中断，都是可屏蔽中断。当外设有需要处理的事件（比如说键盘输入）发生时，相关芯片向CPU 发出可屏蔽中断信息。
不可屏蔽中断是在系统中有必须处理的紧急情况发生时用来通知CPU 的中断信息。在我们的课程中，主要讨论可屏蔽中断。
15.3 PC机键盘的处理过程
下面我们看一下键盘输入的处理过程，并以此来体会一下PC 机处理外设输入的基本方法。
1、键盘输入
2、引发9号中断
3、执行int 9中断例程
键盘上的每一个键相当于一个开关，键盘中有一个芯片对键盘上的每一个键的开关状态进行扫描。
按下一个键时，开关接通，该芯片就产生一个扫描码，扫描码说明了按下的键在键盘上的位置。扫描码被送入主板上的相关接口芯片的寄存器中，该寄存器的端口地址为60H 。
松开按下的键时，也产生一个扫描码，扫描码说明了松开的键在键盘上的位置。松开按键时产生的扫描码也被送入60H 端口中。
一般将按下一个键时产生的扫描码称为通码，松开一个键产生的扫描码称为断码。
扫描码长度为一个字节，通码的第 7 位为 0 ，断码的第7位为1，即： 断码 = 通码＋80H(10000000 第7为为1）
比如：g键的通码为22H，断码为a2H。
BIOS 提供了int 9中断例程，用来进行基本的键盘输入处理，主要的工作如下：
（1）读出60H 端口中的扫描码；
（2）如果是字符键的扫描码，将该扫描码和它所对应的字符码（ 即 ASCII码）送入内存中的 BIOS 键盘缓冲区；
键盘的输入到达60H 端口时，相关的芯片就会向CPU 发出中断类型码为 9 的可屏蔽中断信息。
CPU检测到该中断信息后，如果IF=1，则响应中断，引发中断过程，转去执行int 9中断例程。
如果是控制键（比如 Ctrl ）和切换键（比如 CapsLock）的扫描码，则将其转变为状态字节（ 用二进制位记录控制键和切换键状态的字节 ）写入内存中存储状态字节的单元。
（3）对键盘系统进行相关的控制，比如说，向相关芯片发出应答信息。
BIOS键盘缓冲区是系统启动后，BIOS用于存放int 9 中断例程所接收的键盘输入的内存区。
该内存区可以存储 15 个键盘输入，因为 int 9 中断例程除了接收扫描码外，还要产生和扫描码对应的字符码，所以在BIOS键盘缓冲区中，一个键盘输入用一个字单元存放，
高位字节存放扫描码，低位字节存放字符码。
0040:17 单元存储键盘状态字节，该字节记录了控制键和切换键的状态。键盘状态字节各位记录的信息如下：
15.4 编写int 9中断例程
复习一下前边的内容中，我们可以总结出键盘输入的处理过程：
（1）键盘产生扫描码；
（2）扫描码送入60h 端口；
（3）一旦侦测到60h端口有动静，引发9 号中断；
（4）CPU执行int 9 中断例程处理键盘输入。
以上的过程，前三步都由硬件系统自动完成。我们能够改变的只有第四步，修改int 9 终端程序。
如果单纯要完成这点还是相对比较简单的，因为BIOS 提供的int 9中断例程已经对这些硬件细节进行了处理。
我们只要在自己编写的中断例程中调用BIOS 的int 9中断例程就可以了。
任务演示：在屏幕中间依次显示 “a”~“z” ，并可以让人看清。在显示的过程中，按下Esc键后，改变显示的颜色。
我们先来看一下如何依次显示“a”~“z”：
assume cs:code
code segment
start: mov ax,0b800h
mov es,ax
mov ah,'a'
s: mov es:[16012+402],ah
inc ah
cmp ah,'z'
jna s
mov ax,4c00h
int 21h
code ends
end start
我们发觉，因为一个字母刚显示到屏幕上，CPU执行几条指令后，就又变成了另一个字母，字母之间切换得太快，因此我们无法看清。
理想状况是：我们应该在每显示一个字母后，延时一段时间，让人看清后，再显示下一个字母。
那么如何延时呢？
不如……我们让CPU 执行一段时间的空循环。有时候让它做点无用功哈~
请看源代码并试图分析作者的做法：
;编程：在屏幕中间依次显示“a”~“z”，并可以让人看清。在显示的过程中，按下'Esc'键后，改变显示的颜色。
;部分功能代码：
assume cs:code
stack segment
db 128 dup (0)
stack ends
code segment
start:
mov ax,stack
mov ss,ax
mov sp,128
mov ax,0b800h
mov es,ax
mov ah,'a'
s: mov es:[16012+402],ah
call delay
inc ah
cmp ah,'z'
jna s
mov ax,4c00h
int 21h
delay:
push ax
push dx
mov dx,1000h ;循环10000000h次
mov ax,0
s1:
sub ax,1
sbb dx,0
cmp ax,0
jne s1
cmp dx,0
jne s1
pop dx
pop ax
ret
code ends
end start
现在显示“a”~“z”的任务我们基本完成了，并做到可以让人看清，虽然做法有些无耻……
那么接下来将进一步来实现：按下 Esc 键后，改变显示的颜色！怎么办呢？
键盘输入到达60h 端口后，就会引发 9号中断，CPU 则转去执行int 9中断例程。
我们可以编写int 9中断例程，功能如下：
（1）从60h 端口读出键盘的输入；
（2）调用BIOS 的int 9 中断例程，处理其他硬件细节；
（3）判断是否为Esc的扫描码，如果是，改 变显示的颜色后返回；如果不是则直接返回。
接下来，我们对这些功能的实现一一进行分析！
第一步：从端口60h读出键盘的输入
in al,60h
第二步：调用BIOS的int 9中断例程
注：有一点要注意的是，我们写的中断处理程序要成为新的int 9中断例程，主程序必须要将中断向量表中的int 9中断例程的入口地址改为我们写的中断处理程序的入口地址。
那么在新的中断处理程序中调用原来的int 9中断例程时，中断向量表中的int 9中断例程的入口地址却不是原来的int 9 中断例程的地址。所以我们不能使用int 指令直接调用。
对于我们现在的问题，假设我们将原来int 9中断例程的偏移地址和段地址保存在ds:[0]和ds:[2]单元中。
那么我们在需要调用原来的int 9中断例程时候，就可以在 ds:[0]、ds:[2] 单元中找到它的入口地址。
那么，有了入口地址后，我们如何进行调用呢？
当然不能使用指令int 9来调用。我们可以用别的指令来对int指令进行一些模拟，从而实现对中断例程的调用。
我们来看，int 指令在执行的时候，CPU 进行下面的工作：
（1）取中断类型码n；
（2）标志寄存器入栈；
（3） IF=0，TF=0；
（4） CS 、IP 入栈；
（5）(IP) = (n4)，(CS) = (n4+2)。
取中断类型码是为了定位中断例程的入口地址，在我们的问题中，中断例程的入口地址已经知道。
所以，我们用别的指令模拟int 指令时候，不需要做第（1）步。
在假设要调用的中断例程的入口地址在ds:0和ds:2单元中的前提下，我们将int 过程用下面几步模拟：
（1）标志寄存器入栈；
（2）IF=0，TF=0；
（3）CS、IP入栈；
（4）(IP)=((ds)16+0),(CS)=((ds)16+2)。
可以注意到第（3）、（4）步和call dword ptr ds:[0]的功能一样。
call dword ptr ds:[0] 的功能也是： （1）CS 、IP 入栈； （2）(IP)=((ds)16+0)，(CS)=((ds)16+2)。
所以经过我们总结后，int 过程的模拟最终变为：
（1）标志寄存器入栈；
（2）IF=0，TF=0；
（3）call dword ptr ds:[0]
对于（1），可用pushf实现。
对于（2），我们又得动点歪脑筋，没办法，资源条件极其卑劣的8086 要么使人放弃，要么逼出天才！我们可用以下程序间接实现：
实现IF=0，TF=0步骤：
pushf
pop ax
and ah,11111100b ; IF和OF为标志寄存器的
; 第9位和第8位
push ax
popf
这样，模拟int指令的调用功能，调用入口地址在ds:0、ds:2中的中断例程的程序如下：
pushf ;标志寄存器入栈
pushf
pop ax
and ah,11111100b ; IF和OF为标志寄存器的第9
; 位和第8位
push ax
popf ;IF=0、TF=0
call dword ptr ds:[0]
第三步：如果是Esc键的扫描码，改变显示的颜色后返回……
那么，下一个问题：如何改变显示的颜色？
显示的位置是屏幕的中间，即第12行40列，显存中的偏移地址为：16012+40 2。所以字符的ASCII码要送入b800:16012+402处。
而b800:16012+402+1 处是字符的属性，我们只要改变此处的数据就可以改变在b800:16012+402 处显示的字符的颜色了。
该程序的最后一个问题是，要在程序返回前，将中断向量表中的ini 9中断例程的入口地址恢复为原来的地址。否则程序返回后，别的程序将无法使用键盘。
;编程：在屏幕中间依次显示“a”~“z”，并可以让人看清。在显示的过程中，按下'Esc'键后，改变显示的颜色。
;完整功能代码：
assume cs:code
stack segment
db 128 dup (0)
stack ends
data segment
dw 0,0
data ends
code segment
start:
mov ax,stack
mov ss,ax
mov sp,128
mov ax,data
mov ds,ax
mov ax,0
mov es,ax
push es:[9*4]
pop ds:[0]
push es:[9*4+2]
pop ds:[2] ;将原来的int 9中断例程的入口地址保存在ds:0、ds:2单元中
mov word ptr es:[9*4],offset int9
mov es:[9*4+2],cs ;在中断向量表中设置新的int 9中断例程的入口地址
mov ax,0b800h
mov es,ax
mov ah,'a'
s:
mov es:[16012+402],ah
call delay
inc ah
cmp ah,'z'
jna s
mov ax,0
mov es,ax
push ds:[0]
pop es:[9*4]
push ds;[2]
pop es;[9*4+2] ;将中断向量表中int 9中断例程的入口恢复为原来的地址
mov ax,4c00h
int 21h
delay:
push ax
push dx
mov dx,2000h
mov ax,0
s1:
sub ax,1
sbb dx,0
cmp ax,0
jne s1
cmp dx,0
jne s1
pop dx
pop ax
ret
;------以下为新的int 9中断例程--------------------
int9:
push ax
push bx
push es
in al,60h
pushf
pushf
pop bx
and bh,11111100b
push bx
popf
call dword ptr ds:[0] ;对int指令进行模拟，调用原来的int 9中断例程
cmp al,1
jne int9ret
mov ax,0b800h
mov es,ax
inc byte ptr es:[160*12+40*2+1] ;属性增加1，改变颜色
int9ret:
pop es
pop bx
pop ax
iret
code ends
end start
注意，本章中所有关于键盘的程序，因要直接访问真实的硬件，则必须在DOS实模式下运行。
在Windows 2000 的DOS 方式下运行，会出现一些和硬件工作原理不符合的现象。
15.5 安装新的int 9中断例程
下面，我们将安装一个新的int 9中断例程，使得原int 9中断例程的功能得到扩展。
任务：安装一个新的int 9中断例程
功能：在DOS下，按F1键后改变当前屏幕的显示颜色，其他的键照常处理。
我们进行一下分析：
（1）改变屏幕的显示颜色
怎么改变屏幕的颜色呢? 学习win 32 的朋友立马百度：有相应的函数吗？
其实，我们认真考虑下原理应该不难：改变从B800 开始的4000 个字一节中的所有奇地址单元中的内容，当前屏幕的显示颜色即发生改变。
实现 - - - - > > >
改变屏幕的显示颜色程序
mov ax,0b800h
mov es,ax
mov bx,1
mov cx,2000
s: inc byte ptr es:[bx]
add bx,2
loop s
（2）对于其他键则照常处理，我们可以调用原int 9中断处理程序，来处理其他的键盘输入。
（3）原int 9 中断例程入口地址的保存
因为在编写的新int 9中断例程中要调用原int 9中断例程，所以，要保存原int 9中断例程的入口地址。
保存在哪里？
显然不能保存在安装程序中，因为安装程序返回后地址将丢失。我们因此又将目标锁定在0:200单元处。
（4）新int 9中断例程的安装
这个问题在前面己经详细讨论过。
我们可将新的int 9中断例程安装在0:204 处。
这一章中，我们通过对键盘输入的处理，讲解了CPU 对外设输入的通常处理方法。即：
（1）外设的输入送入端口；
（2）向CPU 发出外中断（可屏蔽中断）信息；
（3）CPU检测到可屏蔽中断信息，如果IF=1，CPU在执行完当前指令后响应中断，执行相应的中断例程；
（4）可在中断例程中实现对外设输入的处理。
注意：端口和中断机制，是CPU 进行I/O的基础。
安装一个新的 int 9 中断例程，功能：在DOS 下，按下“A”键后，除非不再松开，如果松开，就显示满屏幕的“A”；其他的键照常处理。