①int指令
在第12章中，我们讲解了中断过程和两种内中断的处理。
这一章中，我们讲解另一种重要的内中断，由int指令引发的中断。
万众瞩目，是什么呢？那就是DOS时代大名鼎鼎的int中断。
int格式： int n，n为中断类型码。它的功能是引发中断过程。
CPU 执行int n指令，相当于引发一个 n号中断的中断过程，执行过程如下：
（1）取中断类型码n；
（2）标志寄存器入栈，IF = 0，TF = 0；
（3）CS、IP入栈；
（4）(IP) = (n4)，(CS) = (n4+2)。
从此处转去执行n号中断的中断处理程序。
可以在程序中使用int指令调用任何一个中断的中断处理程序。
比如我们看下这个程序段：
test1.asm
assume cs:code
code segment
start:
mov ax,0b800h
mov es,ax
mov byte ptr es:[12160+402],'!'
int 0
code ends
end start
程序是没有做除法，但是在结尾使用了int 0指令。
CPU执行int 0指令时，将引发中断过程，执行 0号中断处理程序，而系统设置的 0号中断处理程序的功能是显示“Divide overflow”，然后返回到系统。
可见，int 指令的最终功能和call指令相似，都是调用一段程序。
因此，一般情况下，系统将一些具有一定功能的子程序，以中断处理程序的方式提供给应用程序调用。
我们在编程的时候，可以用int指令调用这些子程序。当然，也可以自己编写一些中断处理程序供别人使用。
以后，我们可以将中断处理程序简称为中断例程。
②编写供应用程序调用的中断例程
前面，我们已经编写过中断0 的中断例程了，现在我们讨论可以供应用程序调用的中断例程的编写方法。
我们通过两个实例来讨论：
实例一 编写、安装中断7ch的中断例程，实现求一word型数据的平方。
实例二 编写、安装中断7ch的中断例程，实现将一个全是字母，以 0结尾的字符串，转化为大写。
示例一 编写、安装中断7ch的中断例程：
功能：求一word型数据的平方。
参数： (ax)=要计算的数据。
返回值：dx、ax中存放结果的高16位和低16位。
应用举例：求2*3456^2
assume cs:code
code segment
start:
mov ax,3456;(ax)=3456
int 7ch; 调用中断7ch的中断例程，计算ax 中的数据的平方
add ax,ax
adc dx,dx ；存放结果，讲结果乘以2
mov ax,4c00h
int 21h
code ends
end start
我们要做三部分工作：
（1）编程实现求平方功能的程序；
（2）安装程序，我们将其安装在0:200处；
（3）设置中断向量表，将程序的入口地址保存在7ch表项中，使其成为中断7ch的中断例程。
;编程：安装中断7ch的中断例程
;功能：求一word型数据的平方。
;参数：(ax) = 要计算的数据。
;返回值：dx、ax中存放结果的高16位和低16位。
assume cs:code
code segment
start:
mov ax,cs
mov ds,ax
mov si,offset sqr ;设置ds:si指向源地址
mov ax,0
mov es,ax
mov di,200h ;设置es:di指向目的地址
mov cx,offset sqrend - offset sqr ;设置cx为传输长度
cld ;设置传输方向为正
rep movsb
mov ax,0
mov es,ax
mov word ptr es:[7ch*4],200h
mov word ptr es:[7ch*4+2],0
mov ax,4c00h
int 21h
sqr:
mul ax
iret
sqrend: nop
code ends
end start
注意，在中断例程 sqr的最后，要使用iret指令。
用汇编语法描述，iret指令的功能为：
pop IP
pop CS
popf
CPU执行int 7ch指令进入中断例程之前，标志寄存器、当前的CS和IP被压入栈中，在执行完中断例程后，应该用iret指令恢复int 7ch 执行前的标志寄存器和CS、IP的值，从而接着执行应用程序。
int指令和 iret指令的配合使用与call指令和ret指令的配合使用具有相似的思路。
实例二 编写、安装中断7ch的中断例程：
功能：将一个全是字母，以 0结尾的字符串，转化为大写。
参数：ds:si指向字符串的首地址。
应用举例：
将data段中的字符转化为大写。
实例二 编写、安装中断7ch的中断例程：
功能：将一个全是字母，以 0结尾的字符串，转化为大写。
参数：ds:si指向字符串的首地址。
应用举例：
将data段中的字符转化为大写。
assume cs:code
data segment
db 'conversation',0
data ends
code segment
start: mov ax,data
mov ds,ax
mov si,0
int 7ch
mov ax,4c00h
int 21h
code ends
end start
安装程序：test3.asm
assume cs:code
code segment
start:
mov ax,cs
mov ds,ax
mov si,offset capital
mov ax,0
mov es,ax
mov di,200h
mov cx,offset capitalend - offset capital
cld
rep movsb
mov ax,0
mov es,ax
mov word ptr es:[7ch*4],200h
mov word ptr es:[7ch*4+2],0
mov ax,4c00h
int 21h
capital:
push cx
push si
change:
mov cl,[si]
mov ch,0
jcxz ok
and byte ptr [si],11011111b
inc si
jmp short change
ok:
pop si
pop cx
iret
capitalend:nop
code ends
end start
最后，在中断例程capital中用到了寄存器 si和cx，编写中断例程和编写子程序的时候具有同样的问题，就是要避免寄存器的冲突。
应该注意例程中用到的寄存器的值的保存和恢复。
③对int、iret和栈的深入理解
问题：用7ch中断例程完成 loop指令的功能。
loop s 的执行需要两个信息，循环次数和到s的位移，所以，7ch中断例程要完成loop指令的功能，也需要这两个信息作为参数。
我们用cx存放循环次数，用bx存放位移。
应用举例：在屏幕中间显示80个‘！’。
认识框架代码。
assume cs:code
code segment
start:
mov ax,0b800h
mov es,ax
mov di,160*12
mov bx,offset s - offset se ;设置从标号se到标号s的转移位移
mov cx,80
s: mov byte ptr es:[di],'!'
add di,2
int 7ch ;如果(cx)≠0，转移到标号s处
se: nop
mov ax,4c00h
int 21h
code ends
end start
在上面的程序中，用int 7ch调用7ch中断例程进行转移，用 bx 传递转移的位移。
分析，为了模拟loop指令，7ch中断例程应具备下面的功能：
（1）dec cx
（2）如果(cx)≠0，转到标号s 处执行，否则向下执行。
下面我们分析7ch中断例程如何实现到目的地址的转移：
（1）转到标号s显然应设(CS)=标号s的段地址，(IP)=标号s的偏移地址；
（2）那么，中断例程如何得到标号s的段地址和偏移地址呢？
（3）现在知道，可以从栈中直接和间接地得到标号s的段地址和偏移地址，那么如何用它们设置CS:IP呢？
int 7ch引发中断过程后，进入 7ch 中断例程，在中断过程中，当前的标志寄存器、CS和IP都要压栈。
此时压入的CS和IP中的内容，分别是调用程序的段地址（可以认为是标号 s 的段地址）和int 7ch后一条指令的偏移地址（即标号se的偏移地址）。
可见，在中断例程中，可以从栈里取得标号s 的段地址和标号 se的偏移地址，而用标号se的偏移地址加上bx中存放的转移位移就可以得到标号s的偏移地址。
可以利用iret指令，我们将栈中的se的偏移地址加上 bx 中的转移位移，则栈中的se的偏移地址就变为了s的偏移地址。
我们再使用iret指令，用栈中的内容设置CS、IP，从而实现转移到标号s处。
7ch中断例程如下：
lp: push bp
mov bp,sp
dec cx
jcxz lpret
add [bp+2],bx
lpret: pop bp
iret
④BIOS和DOS所提供的中断例程
前边的课程中，我们都是自己编写中断例程，将他们放在安装程序中，然后通过运行安装程序，将他们安装到指定的内存区中。此后，别的应用程序才可以调用。
BIOS和DOS提供的中断例程是如何安装到内存中的呢？
⑤BIOS和DOS中断例程的安装过程
我们下面讲解它们的安装过程。
（1） 开机后，CPU 一加电，初始化(CS)=0FFFFH，(IP)=0，自动从FFFF:0单元开始执行程序。FFFF:0处有一条转跳指令，CPU执行该指令后，转去执行BIOS中的硬件系统检测和初始化程序。
（2）初始化程序将建立BIOS 所支持的中断向量，即将BIOS提供的中断例程的入口地址登记在中断向量表中。
（3） 硬件系统检测和初始化完成后，调用int 19h进行操作系统的引导。从此将计算机交由操作系统控制。
（4）DOS 启动后，除完成其它工作外，还将它所提供的中断例程装入内存，并建立相应的中断向量。
⑥BIOS中断例程应用
下面我们举几个例子，来看一下BIOS中断例程的应用。
int 10h中断例程是BIOS提供的中断例程，其中包含了多个和屏幕输出相关的子程序。
一般来说，一个供程序员调用的中断例程中往往包括多个子程序，中断例程内部用传递进来的参数来决定执行哪个子程序。
BIOS 和DOS 提供的中断例程，都用ah来传递内部子程序的编号。
我们看一下int 10h中断例程的设置光标位置功能。
mov ah,2
mov bh,0
mov dh,5
mov dl,12
int 10h
(ah)=2表示调用第 10h号中断例程的 2号子程序，功能为设置光标位置，可以提供光标所在的行号（8025字符模式下：024）、列号（80*25字符模式下：079），和页号作为参数。
(bh)=0，(dh)=5,(dl)=12，设置光标到第0页，第5行，第12列。
bh中页号的含义：内存地址空间中，B8000h~BFFFFh共 32K的空间，为8025 彩色字符模式的显示缓冲区。
一屏的内容在显示缓冲区中共占4000个字节。
也就是说，通常情况下，B8000~B8F9F中的4000个字节的内容将出现在显示器上。
一般情况下，显示第 0 页的内容。
再看一下int 10h中断例程的在光标位置显示字符功能。
mov ah,9 ;置光标
mov al,‘a’ ;字符
mov bl,7 ;颜色属性
mov bh,0 ;第0页
mov cx,3 ;字符重复个数
int 10h
(ah)=9 表示调用第10h号中断例程的9号子程序；
功能为在光标位置显示字符，可以提供要显示的字符、颜色属性、页号、字符重复个数作为参数。
(bh)中的颜色属性格式如下：
编程：在屏幕的5行12列显示3个红底高亮闪烁绿色的‘a’。
程序源码！
;编程：在屏幕的5行12列显示3个红底高亮闪烁绿色的‘a’。
assume cs:code
code segment
mov ah,2 ;置光标
mov bh,0 ;第0页
mov dh,5 ;dh中放行号
mov dl,12 ;dl中放列号
int 10h
mov ah,9 ;置光标
mov al,'a' ;字符
mov bl,11001010b;颜色属性
mov bh,0 ;第0页
mov cx,3 ;字符重复个数
int 10h
mov ax,4c00h
int 21h
code ends
end
注意：闪烁的效果必须在全屏DOS 方式下才能看到。
⑦DOS中断例程应用
int 21h 中断例程是DOS提供的中断例程，其中包含了DOS提供给程序员在编程时调用的子程序。
我们从前一直使用的是 int 21中断例程的4ch号功能，即程序返回功能，如下：
mov ah,4ch ;程序返回
mov al,0 ;返回值
int 21h
(ah)=4ch表示调用第21h号中断例程的 4ch号子程序，功能为程序返回，可以提供返回值作为参数。
我们前面使用这个功能的时候经常写作：
mov ax,4c00h
int 21h
我们看一下int 21h中断例程的在光标位置显示字符串的功能：
ds:dx指向字符串 ;要显示的字符串需用“$”作为结束符
mov ah ,9 ;功能号9，表示在光标位置显示字符串
int 21h
(ah)=9表示调用第21h号中断例程的 9号子程序，功能为在光标位置显示字符串，可以提供要显示字符串的地址作为参数。
编程：在屏幕的5列12行显示字符串“I love Fishc.com！”。
;编程：在屏幕的5行20列显示字符串“I love Fishc.com!”。
assume cs:code
data segment
db 'I love Fishc.com!','$'
data ends
code segment
start:
mov ah,2 ;置光标
mov bh,0 ;第0页
mov dh,5 ;dh中放行号
mov dl,20 ;dl中放列号
int 10h
mov ax,data
mov ds,ax
mov dx,0 ;ds:dx指向字符串的首地址data:0
mov ah,9
int 21h
mov ax,4c00h
int 21h
code ends
end start
上述程序在屏幕的5列12行显示字符串“I love Fishc.com！”，直到遇见“$”（“$” 本身并不显示，只起到边界的作用）。
如果字符串比较长，遇到行尾，程序会自动转到下一行开头处继续显示；如果到了最后一行，还能自动上卷一行。
DOS为程序员提供了许多可以调用的子程序，都包含在 int 21h 中断例程中。
我们这里只对原理进行了讲解，对于DOS提供的所有可调用子程序的情况，读者可以参考相关的书籍。