bzoj2436

不难发现两边的活动是交替进行的，我们可以dp

先对时间离散化，设f[i,j]到时间i一个会场选j个活动，另一个会场最多有多少活动，那么f[i,j]=max(f[k,j]+s[k,i],f[k,j-s[k,i]])

然后第一问的答案就是max(min(f[n*2,i],i))

第二问是要求必选一个，那这一定形如中间一段必须选，向左向右分别dp

假设中间那段是(i,j)时最优值是g[i,j]

肯定要预处理时间i前一个会场选j个活动，另一个会场最多有多少活动和时间i到结束一个会场选j个活动，另一个会场最多有多少活动

我们记为fl[i,j],fr[i,j]，不难得到g[i,j]=max{min(x+y+s[i,j],fl[i,x]+fr[j,y])} （注意到f[]数组的两个会场取值是对称的）

处理g[i,j]是O(n4）的，拍几组数据可以发现当i,j固定时，随着x的增大，对应最优的y减小

其实主观上也很好理解，肯定是两个会场活动尽量平衡，证明吗……不会……

var fl,fr,f,g:array[0..410,0..410] of longint;
    a,s,e:array[0..410] of longint;
    i,n,m,k,j,x,y,ans,t:longint;

procedure max(var a:longint; b:longint);
  begin
    if a<b then a:=b;
  end;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure swap(var a,b:longint);
  var c:longint;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure sort(l,r:longint);
  var i,j,x:longint;
  begin
    i:=l;
    j:=r;
    x:=a[(l+r) shr 1];
    repeat
      while a[i]<x do inc(i);
      while x<a[j] do dec(j);
      if not(i>j) then
      begin
        swap(a[i],a[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

function find(l,r,x:longint):longint;
  var m:longint;
  begin
    while l<=r do
    begin
      m:=(l+r) shr 1;
      if a[m]=x then exit(m);
      if a[m]>x then r:=m-1 else l:=m+1;
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
  begin
    readln(s[i],e[i]);
    e[i]:=s[i]+e[i];
    inc(t);
    a[t]:=s[i];
    inc(t);
    a[t]:=e[i];
  end;
  sort(1,t);
  m:=1;
  for i:=2 to t do
    if a[i]<>a[m] then
    begin
      inc(m);
      a[m]:=a[i];
    end;
  for i:=1 to n do
  begin
    s[i]:=find(1,m,s[i]);
    e[i]:=find(1,m,e[i]);
    inc(g[s[i],e[i]]);
  end;
  for i:=1 to m do
    for j:=i+1 to m do
      inc(g[i,j],g[i,j-1]);
  for j:=1 to m do
    for i:=j-1 downto 1 do
      inc(g[i,j],g[i+1,j]);
  for i:=0 to m+1 do
    for j:=0 to n do
    begin
      fl[i,j]:=-n;
      fr[i,j]:=-n;
    end;
  fl[0,0]:=0; fr[m+1,0]:=0;
  for i:=1 to m do
    for j:=0 to i-1 do
      for k:=0 to n do
      begin
        max(fl[i,k],fl[j,k]+g[j,i]);
        if k>=g[j,i] then max(fl[i,k],fl[j,k-g[j,i]]);
      end;
  for i:=m downto 1 do
    for j:=i+1 to m+1 do
      for k:=0 to n do
      begin
        max(fr[i,k],fr[j,k]+g[i,j]);
        if k>=g[i,j] then max(fr[i,k],fr[j,k-g[i,j]]);
      end;
  ans:=0;
  for i:=0 to n do
    max(ans,min(fl[m,i],i));
  writeln(ans);
  for i:=1 to m do
    for j:=i to m do
    begin
      y:=g[j,m];
      for x:=0 to g[1,i] do
      begin
        while (y>0) and (min(x+y-1+g[i,j],fl[i,x]+fr[j,y-1])>=min(x+y+g[i,j],fl[i,x]+fr[j,y])) do dec(y);
        max(f[i,j],min(x+y+g[i,j],fl[i,x]+fr[j,y]));
      end;
    end;

  for i:=1 to n do
  begin
    ans:=0;
    for x:=1 to s[i] do
      for y:=e[i] to m do
        max(ans,f[x,y]);
    writeln(ans);
  end;
end.