bzoj3955

首先，最短路不同的两辆车一定不会发生堵塞

对于最短路相同的点，我们把属于最短路径上的边拎出来建图跑最大流即可

然后我TLE了……

因为很明显建出来图很大，而真正流的流量很小

普通的初始标号都是0的sap在增广的时候编号会非常慢

运用fanhq博客里的做法，先用dfs计算图的标号O(m+n)，然后再跑sap就跑得飞起了

const inf=1000000007;
type node=record
       po,next,flow:longint;
     end;
     point=record
       loc,num:longint;
     end;
     way=record
       po,next,num:longint;
     end;

var w:array[0..100010] of way;
    e:array[0..400010] of node;
    h:array[0..25010] of point;
    v:array[0..25010] of boolean;
    wh,d,a,cur,hi,pre,p,q,numh:array[0..25010] of longint;
    ans,j,i,len,n,m,t,c,x,y,z:longint;

procedure swap(var a,b:point);
  var c:point;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure sift(i:longint);
  var j,x,y:longint;
  begin
    j:=i shl 1;
    while j<=t do
    begin
      if (j<t) and (h[j].num>h[j+1].num) then inc(j);
      if h[i].num>h[j].num then
      begin
        x:=h[i].loc;
        y:=h[j].loc;
        wh[x]:=j;
        wh[y]:=i;
        swap(h[i],h[j]);
        i:=j;
        j:=j shl 1;
      end
      else break;
    end;
  end;

procedure up(i:longint);
  var j,x,y:longint;
  begin
    j:=i shr 1;
    while j>0 do
    begin
      if h[i].num<h[j].num then
      begin
        x:=h[i].loc;
        y:=h[j].loc;
        wh[x]:=j;
        wh[y]:=i;
        swap(h[i],h[j]);
        i:=j;
        j:=j shr 1;
      end
      else break;
    end;
  end;

procedure dij;
  var i,k,x,y:longint;
  begin
    t:=n;
    for i:=1 to n do
    begin
      if i=1 then d[i]:=0 else d[i]:=inf;
      wh[i]:=i;
      h[i].num:=d[i];
      h[i].loc:=i;
    end;
    for k:=1 to n-1 do
    begin
      x:=h[1].loc;
      wh[h[t].loc]:=1;
      swap(h[1],h[t]);
      dec(t);
      sift(1);
      i:=q[x];
      while i<>0 do
      begin
        y:=w[i].po;
        if d[x]+w[i].num<d[y] then
        begin
          d[y]:=d[x]+w[i].num;
          h[wh[y]].num:=d[y];
          up(wh[y]);
        end;
        i:=w[i].next;
      end;
    end;
  end;

function cmp(i,j:longint):boolean;
  begin
    if d[i]=d[j] then exit(i<j);
    exit(d[i]<d[j]);
  end;

procedure sort(l,r:longint);
  var i,j,x,y:longint;
  begin
    i:=l;
    j:=r;
    x:=a[(l+r) shr 1];
    repeat
      while cmp(a[i],x) do inc(i);
      while cmp(x,a[j]) do dec(j);
      if not(i>j) then
      begin
        y:=a[i]; a[i]:=a[j]; a[j]:=y;
        inc(i);
        dec(j);
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r)
  end;

procedure add(x,y,f:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].flow:=f;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure build(x,y,f:longint);
  begin
    add(x,y,f);
    add(y,x,0);
  end;

procedure ins(x,y,z:longint);
  begin
    inc(len);
    w[len].po:=y;
    w[len].num:=z;
    w[len].next:=q[x];
    q[x]:=len;
  end;

function sap(lim:longint):longint;
  var i,j,u,tmp,q:longint;
  begin
    u:=0; sap:=0;
    while hi[0]<n+1 do
    begin
      i:=cur[u];
      while i<>-1 do
      begin
        j:=e[i].po;
        if (e[i].flow>0) and (hi[u]=hi[j]+1) then
        begin
          pre[j]:=u;
          cur[u]:=i;
          u:=j;
          if u=1 then
          begin
            inc(sap);
            if sap=lim then exit;
            while u<>0 do
            begin
              u:=pre[u];
              j:=cur[u];
              dec(e[j].flow);
              inc(e[j xor 1].flow);
            end;
          end;
          break;
        end;
        i:=e[i].next;
      end;
      if i=-1 then
      begin
        dec(numh[hi[u]]);
        if numh[hi[u]]=0 then break;
        tmp:=n;
        q:=-1;
        i:=p[u];
        while i<>-1 do
        begin
          j:=e[i].po;
          if e[i].flow>0 then
            if hi[j]<tmp then
            begin
              q:=i;
              tmp:=hi[j];
            end;
          i:=e[i].next;
        end;
        cur[u]:=q;
        hi[u]:=tmp+1;
        inc(numh[hi[u]]);
        if u<>0 then u:=pre[u];
      end;
    end;
  end;

procedure dfs(x:longint);
  var tmp,i,y,q:longint;
  begin
    if x=1 then
    begin
      hi[1]:=0;
      inc(numh[0]);
      exit;
    end;
    v[x]:=true;
    tmp:=n;
    q:=-1;
    i:=p[x];
    while i<>-1 do
    begin
      y:=e[i].po;
      if e[i].flow>0 then
      begin
        if not v[y] then dfs(y);
        if hi[y]<tmp then
        begin
          tmp:=hi[y];
          q:=i;
        end;
      end;
      i:=e[i].next;
    end;
    cur[x]:=q;
    hi[x]:=tmp+1;
    inc(numh[hi[x]]);
  end;

procedure work(l,r:longint);
  var i,j:longint;
  begin
    len:=-1;
    fillchar(p,sizeof(p),255);
    for i:=1 to n do
    begin
      j:=q[i];
      while j<>0 do
      begin
        y:=w[j].po;
        if d[i]+w[j].num=d[y] then build(y,i,1);
        j:=w[j].next;
      end;
    end;
    i:=l;
    while i<=r do
    begin
      j:=i+1;
      while (j<=r) and (a[j]=a[i]) do inc(j);
      build(0,a[i],j-i);
      i:=j;
    end;
    fillchar(numh,sizeof(numh),0);
    fillchar(v,sizeof(v),false);
    dfs(0);
    if hi[0]<n+1 then
      ans:=ans+sap(r-l+1);
  end;

begin
  readln(n,m,c);
  for i:=1 to m do
  begin
    readln(x,y,z);
    ins(x,y,z);
    ins(y,x,z);
  end;
  dij;
  for i:=1 to c do
    read(a[i]);
  sort(1,c);
  i:=1;
  while i<=c do
  begin
    j:=i+1;
    while (d[a[i]]=d[a[j]]) and (j<=c) do inc(j);
    if j=i+1 then inc(ans)
    else if a[i]=1 then inc(ans,j-i)
    else work(i,j-1);
    i:=j;
  end;
  writeln(ans);
end.