bzoj2482

还是像以前那样维护下次出现位置，计算影响

其实不难，思维盲点，受到做最大子段和的影响

其实这里可以直接维护当前每个位置的子段和，再记录一个历史最大和

当然tag也需要记录当前tag和历史（距离上次push）最大累加

type node=record
       x,y,id:longint;
     end;

var lazy,tree:array[0..100010*4,0..1] of longint;
    ans,next,a:array[0..100010] of longint;
    last:array[-100010..100010] of longint;
    q:array[0..100010] of node;
    i,j,n,m:longint;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure swap(var a,b:node);
  var c:node;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure sort(l,r:longint);
  var i,j,x:longint;
  begin
    i:=l;
    j:=r;
    x:=q[(l+r) shr 1].x;
    repeat
      while q[i].x>x do inc(i);
      while x>q[j].x do dec(j);
      if i<=j then
      begin
        swap(q[i],q[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

procedure get(i,x0,x1:longint);
  begin
    tree[i,0]:=max(tree[i,0],tree[i,1]+max(x0,x1));
    lazy[i,0]:=max(lazy[i,0],lazy[i,1]+max(x0,x1));
    inc(lazy[i,1],x1);
    inc(tree[i,1],x1);
  end;

procedure update(i:longint);
  begin
    tree[i,0]:=max(tree[i*2,0],tree[i*2+1,0]);
    tree[i,1]:=max(tree[i*2,1],tree[i*2+1,1]);
  end;

procedure push(i:longint);
  begin
    if (lazy[i,1]=0) and (lazy[i,0]=0) then exit;
    get(i*2,lazy[i,0],lazy[i,1]);
    get(i*2+1,lazy[i,0],lazy[i,1]);
    lazy[i,0]:=0;
    lazy[i,1]:=0;
  end;

procedure add(i,l,r,x,y,z:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then get(i,0,z)
    else begin
      m:=(l+r) shr 1;
      push(i);
      if x<=m then add(i*2,l,m,x,y,z);
      if y>m then add(i*2+1,m+1,r,x,y,z);
      update(i);
    end;
  end;

function ask(i,l,r,x:longint):longint;
  var m:longint;
  begin
    if l=r then exit(tree[i,0])
    else begin
      m:=(l+r) shr 1;
      push(i);
      if x<=m then exit(ask(i*2,l,m,x))
      else exit(max(tree[i*2,0],ask(i*2+1,m+1,r,x)));
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
    read(a[i]);
  for i:=n downto 1 do
  begin
    next[i]:=last[a[i]];
    last[a[i]]:=i;
  end;
  readln(m);
  for i:=1 to m do
  begin
    readln(q[i].x,q[i].y);
    q[i].id:=i;
  end;
  sort(1,m); 
  j:=1;
  for i:=n downto 1 do
  begin
    if next[i]=0 then next[i]:=n+1;
    add(1,1,n,i,next[i]-1,a[i]);
    while (j<=m) and (q[j].x=i) do
    begin
      ans[q[j].id]:=ask(1,1,n,q[j].y);
      inc(j);
    end;
    if j=m+1 then break;
  end;
  for i:=1 to m do
    writeln(ans[i]);
end.