bzoj3747

经典题，记录每个位置对应数下次出现的位置next[i]

每个位置维护当前左端点下到这个位置的和

随着左端点的右移一位到i+1，对[i+1,next[i]-1] 的影响是-a[i], [next[i],next[next[i]]-1]的影响是a[i]

线段树维护，pascal过不去系列

UPD:现在时限开大能过去了

var lazy,tree:array[0..1000010*4] of int64;
    s:array[0..1000010] of int64;
    next,last,w,a:array[0..1000010] of longint;
    i,n,m:longint;
    ans:int64;

function max(a,b:int64):int64;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure ins(i:longint;z:int64);
  begin
    tree[i]:=tree[i]+z;
    lazy[i]:=lazy[i]+z;
  end;

procedure push(i:longint);
  begin
    ins(i*2,lazy[i]);
    ins(i*2+1,lazy[i]);
    lazy[i]:=0;
  end;

procedure add(i,l,r,x,y,z:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then ins(i,z)
    else begin
      m:=(l+r) shr 1;
      if lazy[i]<>0 then push(i);
      if x<=m then add(i*2,l,m,x,y,z);
      if y>m then add(i*2+1,m+1,r,x,y,z);
      tree[i]:=max(tree[i*2],tree[i*2+1]);
    end;
  end;

begin
 
  readln(n,m);
  for i:=1 to n do
    read(a[i]);
  for i:=1 to m do
  begin
    read(w[i]);
    last[i]:=n+1;
  end;
  for i:=n downto 1 do
  begin
    if last[a[i]]=n+1 then s[i]:=s[i+1]+w[a[i]]
    else s[i]:=s[i+1];
    next[i]:=last[a[i]];
    last[a[i]]:=i;
  end;
  for i:=1 to m do
    if last[i]>0 then add(1,1,n,last[i],next[last[i]]-1,w[i]);

  for i:=1 to n do
  begin
    if s[i]<=ans then break;
    ans:=max(ans,tree[1]);
    add(1,1,n,i,next[i]-1,-w[a[i]]);
    if next[i]<=n then add(1,1,n,next[i],next[next[i]]-1,w[a[i]]);
  end;
  writeln(ans);
end.