bzoj2085

首先看到k的范围就该知道这题不是倍增就是矩乘

首先肯定要求出任意一对串(a,b) a的后缀与b的前缀相同的最长长度是多少

考虑到kmp求出的失配指针是一个串最长后缀和前缀相等的长度

这里多个串我们只要用ac自动机即可

具体的，我们只要建立自动机，然后记录每个状态点是哪些串的子串

然后我们只要从每个串的结尾节点出发，顺着失配指针统计即可

然后我们把每个串看作一个点，点之间的边长度就是虽代表串的后缀前缀相同的最长长度

这个问题等价于求经过k条边的最短长度，倍增轻松搞定

const inf=2147483647*2147483647;
type node=record
       po,next:longint;
     end;
     mtx=array[0..201,0..201] of int64;

var lcp:array[0..201,0..201] of longint;
    d,p,w,fa,q:array[0..100010] of longint;
    loc:array[0..201] of longint;
    e:array[0..100010*200] of node;
    trie:array[0..100010,'a'..'z'] of longint;
    f,a:mtx;
    ss:ansistring;
    t,len,i,n,m,j,k:longint;
    ans:int64;

function min(a,b:int64):int64;
  begin
    if a>b then exit(b) else exit(a);
  end;

function max(a,b:longint):longint;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure add(x,y:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure ac;
  var h,r,x,y,j:longint;
      c:char;
  begin
    h:=1;
    r:=0;
    for c:='a' to 'z' do
      if trie[0,c]>0 then
      begin
        inc(r);
        q[r]:=trie[0,c];
      end;

    while h<=r do
    begin
      x:=q[h];
      for c:='a' to 'z' do
        if trie[x,c]>0 then
        begin
          y:=trie[x,c];
          inc(r);
          q[r]:=y;
          j:=fa[x];
          while (j>0) and (trie[j,c]=0) do j:=fa[j];
          fa[y]:=trie[j,c];
        end;
      inc(h);
    end;
  end;

procedure get(k,x:longint);
  var i,j:longint;
  begin
    while fa[x]<>0 do
    begin
      x:=fa[x];
      i:=p[x];
      while i<>0 do
      begin
        j:=e[i].po;
        lcp[k,j]:=max(lcp[k,j],d[x]);
        i:=e[i].next;
      end;
    end;
  end;

procedure mul(var c:mtx; a,b:mtx);
  var i,j,k:longint;
  begin
    for i:=1 to n do
      for j:=1 to n do
        c[i,j]:=inf;

    for k:=1 to n do
      for i:=1 to n do
        for j:=1 to n do
          c[i,j]:=min(c[i,j],a[i,k]+b[k,j]);
  end;

begin
  readln(n,m);
  for i:=1 to n do
  begin
    readln(ss);
    w[i]:=length(ss);
    j:=0;
    for k:=1 to w[i] do
    begin
      if trie[j,ss[k]]=0 then
      begin
        inc(t);
        trie[j,ss[k]]:=t;
      end;
      j:=trie[j,ss[k]];
      d[j]:=k;
      add(j,i);
    end;
    loc[i]:=j;
  end;
  ac;
  for i:=1 to n do
    get(i,loc[i]);
  for i:=1 to n do
    for j:=1 to n do
      a[i,j]:=w[j]-lcp[i,j];

  for i:=1 to n do
    for j:=1 to n do
      if i<>j then f[i,j]:=inf;
  dec(m);
  while m>0 do
  begin
    if m mod 2=1 then mul(f,f,a);
    m:=m shr 1;
    mul(a,a,a);
  end;
  ans:=inf;
  for i:=1 to n do
    for j:=1 to n do
      ans:=min(ans,f[i,j]+w[i]);
  writeln(ans);
end.