bzoj1001

平面图求最小割；

其实看bzoj1001一开始着实把我怔住了

AC的人暴多，可自己完全没思路

后来看了某大牛的ppt，才会做

一个月前做这题的吧，今天来简单回忆一下；

首先是欧拉公式

如果一个连通的平面图有n个点，m条边和f个面，那么f=m-n+2

我们把原图的每个面看成新图的一个点，对于原图中的每条边

如果边只属于一个面，那么给对应点连一个自环；

如果边两侧各有一个面，那么给对应点之间连一条无向边

这样，新图与原图的边一一对应；

可以发现，新图的一条路径对应原图的一个割

于是我们原图起点终点连一条边，增加一个附加面（也可以理解为把外面言直线st分为两个面）；

按上述方法建新图，于是最小割问题转化为对新图求最短路；

最短路可以用堆优化dij；

这题我的dij+heap写的有进步

const inf=2147483647;
type link=^node;
     node=record
       po,len:longint;
       next:link;
     end;
     point=record
       num,loc:longint;
     end;

var w:array[0..2020010] of link;
    heap:array[0..2020010] of point;
    where,d:array[0..2020010] of longint;
    xie,hen,shu:array[0..1010,0..1010] of longint;
    t,s,i,j,n,m,x,y:longint;
    p:link;

procedure swap(var a,b:point);
  var c:point;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure add(x,y,z:longint);
  var p:link;
  begin
    new(p);
    p^.po:=y;
    p^.len:=z;
    p^.next:=w[x];
    w[x]:=p;
  end;

procedure up(i:longint);
  var j,x,y:longint;
  begin
    j:=i shr 1;
    while j>0 do
    begin
      if heap[i].num<heap[j].num then
      begin
        x:=heap[i].loc;
        y:=heap[j].loc;
        where[x]:=j;
        where[y]:=i;
        swap(heap[i],heap[j]);
        i:=j;
        j:=i shr 1;
      end
      else break;
    end;
  end;

procedure sift(i:longint);
  var j,x,y:longint;
  begin
    j:=i shl 1;
    while j<=s do
    begin
      if (j+1<=s) and (heap[j].num>heap[j+1].num) then inc(j);
      if heap[i].num>heap[j].num then
      begin
        x:=heap[i].loc;
        y:=heap[j].loc;
        where[x]:=j;
        where[y]:=i;
        swap(heap[i],heap[j]);
        i:=j;
        j:=i shl 1;
      end
      else break;
    end;
  end;

procedure build;    //复杂的建图，这种东西一定要谨慎，错误才会少；
  var i:longint;
  begin
    for i:=1 to m-1 do
    begin
      add(1,i+1,hen[1,i]);
      add(i+1,1,hen[1,i]);
    end;
    for i:=1 to n-1 do
    begin
      x:=(m-1)*(2*i-1)+1;
      add(1,x,shu[i,m]);
      add(x,1,shu[i,m]);
    end;

    for i:=1 to m-1 do
    begin
      x:=t-m+i;
      add(t,x,hen[n,i]);
      add(x,t,hen[n,i]);
    end;
    for i:=1 to n-1 do
    begin
      x:=(m-1)*(2*i-1)+2;
      add(t,x,shu[i,1]);
      add(x,t,shu[i,1]);
    end;

    for i:=2 to n-1 do
      for j:=1 to m-1 do
      begin
        x:=(2*i-3)*(m-1)+j+1;
        y:=x+m-1;
        add(x,y,hen[i,j]);
        add(y,x,hen[i,j]);
      end;

    for i:=1 to n-1 do
      for j:=2 to m-1 do
      begin
        x:=(2*i-2)*(m-1)+j;
        y:=x+m;
        add(x,y,shu[i,j]);
        add(y,x,shu[i,j]);
      end;

    for i:=1 to n-1 do
      for j:=1 to m-1 do
      begin
        x:=(2*i-2)*(m-1)+j+1;
        y:=x+m-1;
        add(x,y,xie[i,j]);
        add(y,x,xie[i,j]);
      end;
  end;

procedure dij;       //最短路
  var p:link;
      mid,k,y:longint;
  begin
    p:=w[1];
    for i:=2 to t do
      d[i]:=inf;
    d[1]:=0;
    while p<>nil do
    begin
      x:=p^.po;
      d[x]:=min(d[x],p^.len);
      p:=p^.next;
    end;
    s:=0;
    for i:=2 to t do
    begin
      inc(s);
      heap[s].num:=d[i];
      heap[s].loc:=i;        //表示堆的这个位置是哪个点
      where[i]:=s;           //where表示这个点在堆的哪个位置
      up(s);
    end;

    for k:=1 to t do
    begin
      mid:=heap[1].num;
      if s=0 then break;      
      if mid=inf then break;   
      x:=heap[1].loc;
      y:=heap[s].loc;
      where[y]:=1;

      swap(heap[1],heap[s]);   //退堆
      dec(s);

      sift(1);
      p:=w[x];
      while p<>nil do
      begin
        y:=p^.po;
        if d[y]>p^.len+mid then     //更新，入堆
        begin
          d[y]:=p^.len+mid; 
          heap[where[y]].num:=d[y];
          up(where[y]);
        end;
        p:=p^.next;
      end;
    end;
  end;

begin
  readln(n,m);
  for i:=1 to n do
  begin
    for j:=1 to m-1 do
      read(hen[i,j]);
  end;
  for i:=1 to n-1 do
  begin
    for j:=1 to m do
      read(shu[i,j]);
  end;
  for i:=1 to n-1 do
  begin
    for j:=1 to m-1 do
      read(xie[i,j]);
  end;

  if n=1 then       //注意这种情况要特判
  begin
    t:=inf;
    for i:=1 to m-1 do
      t:=min(hen[1,i],t);
    writeln(t);
    halt;
  end
  else if m=1 then
  begin
    t:=inf;
    for i:=1 to n-1 do
      t:=min(t,shu[i,1]);
    writeln(t);
    halt;
  end;
  t:=(n-1)*(m-1)*2+2;    //计算新图总点数
  build;
  dij;
  writeln(d[t]);
end.