bzoj1305

让我们继续来练网络流；

很明显是一个最大流的问题；

二分枚举最多次数m，然后最大流判定；

具体就是男生女生都拆成两个点i1，i2，之间连一条流量为k的边（男生i1-->i2,女生i2-->i1);

i2连不喜欢的人，i1连喜欢的人

最后，男生i1连源点流量为m，女生i1连汇点流量为m

最后判断最大流是否等于n*m即可

但做着做着，我发现好像好像二分+最大流不是很优，因为进行了很多重复操作

但我也没管，先A了再说；

后来看status发现很多人代码很短，用时0ms（我的最大流180ms）

肯定有更简单的方法：

贪心！……其实是错的……

code(using maxflow)：
type node=record
       next,point,flow:longint;
     end;

var edge:array[0..200010] of node;
    a:array[0..60,0..60] of boolean;
    cur,pre,p,numh,h:array[0..400] of longint;
    j,m,n,k,i,len,t,ans,l,r:longint;
    c:string;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,f:longint);
  begin
    inc(len);
    edge[len].flow:=f;
    edge[len].point:=y;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

function sap(m:longint):boolean;
  var s,u,tmp,i,j,q:longint;
  begin
    len:=-1;
    fillchar(p,sizeof(p),255);
    for i:=1 to n do
    begin
      add(0,i,m);
      add(i,0,m);
      add(i+2*n,t,m);
      add(t,i+2*n,0);
      add(i,i+n,k);
      add(i+n,i,0);
      add(i+3*n,i+2*n,k);
      add(i+2*n,i+3*n,0);
    end;
    for i:=1 to n do
      for j:=1 to n do
        if a[i,j] then
        begin
          add(i,j+2*n,1);
          add(j+2*n,i,0);
        end
        else begin
          add(i+n,j+3*n,1);
          add(j+3*n,i+n,0);
        end;
    fillchar(numh,sizeof(numh),0);
    fillchar(h,sizeof(h),0);
    numh[0]:=t+1;
    u:=0;
    s:=0;
    while h[0]<t+1 do
    begin
      if u=t then
      begin
        i:=0;
        while i<>t do
        begin
          j:=cur[i];
          dec(edge[j].flow);
          inc(edge[j xor 1].flow);
          i:=edge[j].point;
        end;
        u:=0;
        inc(s);
        if s=n*m then exit(true);
      end;
      q:=-1;
      i:=p[u];
      while i<>-1 do
      begin
        j:=edge[i].point;
        if (edge[i].flow>0) and (h[u]=h[j]+1) then
        begin
          q:=i;
          break;
        end;
        i:=edge[i].next;
      end;
      if q<>-1 then
      begin
        cur[u]:=q;
        pre[j]:=u;
        u:=j;
      end
      else begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then exit(false);
        tmp:=t+1;
        i:=p[u];
        while i<>-1 do
        begin
          j:=edge[i].point;
          if edge[i].flow>0 then tmp:=min(tmp,h[j]);
          i:=edge[i].next;
        end;
        h[u]:=tmp+1;
        inc(numh[h[u]]);
        if u<>0 then u:=pre[u];
      end;
    end;
    exit(false);
  end;

begin
  readln(n,k);
  for i:=1 to n do
  begin
    readln(c);
    for j:=1 to n do
    begin
      if c[j]='Y' then a[i,j]:=true
      else a[i,j]:=false;
    end;
  end;
  t:=n*4+1;
  l:=1;
  r:=n;
  ans:=0;
  while l<=r do
  begin
    m:=(l+r) shr 1;
    if sap(m) then
    begin
      ans:=m;
      l:=m+1;
    end
    else r:=m-1;
  end;
  writeln(ans);
end.