bzoj1040

论环形dp的重要！

其实这个环比较简单，稍微分析一下就知道，

这是一个简单环，并且每个联通块里只含有一个。

我觉得把处理环的关键，就是要找出环形和线形（树形）有什么区别。

如果我们从某处断开的做dp的话，转移的结果只对根节点有影响（不确定）；

然后我猜测应该只要找到环上相邻两点然后断开分别以他们为根做treedp就可以了

结果真的是这样……

总感觉缺点什么……

有待进一步思考……

type node=record
       point,next:longint;
     end;

var edge:array[0..2000010] of node;
    can:array[0..2000010] of boolean;
    v:array[0..1000010] of boolean;
    p,w:array[0..1000010] of longint;
    f:array[0..1000010,0..1] of int64;
    len,find,n,u,z,i:longint;
    ans,res:int64;

function max(a,b:int64):int64;
  begin
    if a>b then exit(a) else exit(b);
  end;

procedure add(x,y:longint);
  begin
    inc(len);
    edge[len].point:=y;
    edge[len].next:=p[x];
    can[len]:=true;
    p[x]:=len;
  end;

procedure dfs(x:longint);   //找环
  var i,y:longint;
  begin
    v[x]:=true;
    i:=p[x];
    while i<>-1 do
    begin
      y:=edge[i].point;
      if can[i] and not v[y] then   
      begin
        can[i xor 1]:=false;   //注意防止因为同一条边而回头
        dfs(y);
        can[i xor 1]:=true;    //解除标记
      end
      else if can[i] and v[y] then
      begin
        u:=x;
        z:=y;
        find:=i;
      end;
      i:=edge[i].next;
    end;
  end;

procedure treedp(x:longint);
  var i,y:longint;
  begin
    i:=p[x];
    f[x,0]:=0;
    f[x,1]:=w[x];
    while i<>-1 do
    begin
      y:=edge[i].point;
      if can[i] then   
      begin
        can[i xor 1]:=false;
        treedp(y);
        can[i xor 1]:=true;
        f[x,0]:=f[x,0]+max(f[y,0],f[y,1]);  //基本的treedp
        f[x,1]:=f[x,1]+f[y,0];
      end;
      i:=edge[i].next;
    end;
  end;

procedure dp(i:longint);
  begin
    dfs(i);
    can[find]:=false;    //断开
    can[find xor 1]:=false;
    treedp(u);
    res:=f[u,0];
    treedp(z);
    ans:=ans+max(f[z,0],res);  //都是不取根，这里是凭感觉写的，欢迎指教
  end;

begin
  len:=-1;
  readln(n);
  fillchar(p,sizeof(p),255);
  for i:=1 to n do
  begin
    readln(w[i],z);
    add(z,i);
    add(i,z);
  end;
  for i:=1 to n do
    if not v[i] then dp(i);
  writeln(ans);
end.