bzoj2763

首先是稀疏图，不难想到dij+heap

观察题目可以知道，0<=k<=10;

所以比较裸的想法就是，d[i,j]表示已经免费了i条线路后到达j的最短路

容易得到

d[i,j]:=min(d[i,j],d[i-1,k]);

d[i,j]:=min(d[i,j],d[i,k]+w[k,j]);

然后在做dij在选择中间点的时候，我们穷举一下免费的线路数就可以了；

然后就要维护10个堆……

语言表述有点渣，具体还是看程序吧

const inf=2000000007;
type point=record
       num,dis:longint;
     end;
     node=record
       next,cost,point:longint;
     end;

var edge:array[0..200010] of node;
    heap:array[0..11,0..10010] of point;
    d,where:array[0..11,0..10010] of longint;
    h:array[0..11] of longint;
    p:array[0..10010] of longint;
    len,x,y,z,i,j,n,m,u,k,s,t:longint;

procedure swap(var a,b:point);
  var c:point;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,z:longint);
  begin
    inc(len);
    edge[len].point:=y;
    edge[len].cost:=z;
    edge[len].next:=p[x];
    p[x]:=len;
  end;

procedure sift(p,i:longint);
  var j,x,y:longint;
  begin
    j:=i shl 1;
    while j<=h[p] do
    begin
      if (j+1<=h[p]) and (heap[p,j].dis>heap[p,j+1].dis) then inc(j);
      if heap[p,i].dis>heap[p,j].dis then
      begin
        x:=heap[p,i].num;
        y:=heap[p,j].num;
        where[p,x]:=j;
        where[p,y]:=i;
        swap(heap[p,i],heap[p,j]);
        i:=j;
        j:=i shl 1;
      end
      else break;
    end;
  end;

procedure up(p,i:longint);
  var j,x,y:longint;
  begin
    j:=i shr 1;
    while j>0 do
    begin
      if heap[p,i].dis<heap[p,j].dis then
      begin
        x:=heap[p,i].num;
        y:=heap[p,j].num;
        where[p,x]:=j;
        where[p,y]:=i;
        swap(heap[p,i],heap[p,j]);
        i:=j;
        j:=j shr 1;
      end
      else break;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n,m,k);
  readln(s,t);
  inc(s);  //点序号都+1，习惯一点
  inc(t);
  for i:=1 to m do
  begin
    readln(x,y,z);
    inc(x);
    inc(y);
    add(x,y,z);
    add(y,x,z);
  end;
  for i:=1 to n do
    if i<>s then
    begin
      for j:=0 to k do
        d[j,i]:=inf;
    end
    else
      for j:=0 to k do
        d[j,i]:=0;
  for i:=0 to k do
  begin
    for j:=1 to n do
    begin
      heap[i,j].num:=j;
      heap[i,j].dis:=d[i,j];
      where[i,j]:=j;
    end;
    h[i]:=n;
  end;
  for i:=0 to k do
    up(i,s);  //起点不一定是0，要初始化堆，一开始这里被坑翻了
  for u:=1 to n do
  begin
    for j:=k downto 0 do 
    begin
      x:=heap[j,1].num;
      y:=heap[j,h[j]].num;  
      if (h[j]=0) or (d[j,x]=inf) then continue;
      where[j,y]:=1;  //dij+heap比较重要的细节
      swap(heap[j,1],heap[j,h[j]]);
      dec(h[j]); 
      sift(j,1);  //出堆，调整堆
      i:=p[x];
      while i<>-1 do
      begin
        y:=edge[i].point;
        if (j<>k) and (d[j+1,y]>d[j,x]) then   //两种情况
        begin
          d[j+1,y]:=d[j,x];
          heap[j+1,where[j+1,y]].dis:=d[j+1,y];
          up(j+1,where[j+1,y]);
        end;
        if (d[j,y]>d[j,x]+edge[i].cost) then
        begin
          d[j,y]:=d[j,x]+edge[i].cost;
          heap[j,where[j,y]].dis:=d[j,y];
          up(j,where[j,y]);
        end;
        i:=edge[i].next;
      end;
    end;
  end;
  writeln(d[k,t]); //肯定尽可能免费好啊
end.