poj3270

终于把这个很久以前拖下来的问题解决了

回忆一下，最少相邻交换次数等于逆序对数

这里求的是最少交换代价（非相邻元素也可以交换）；

先考虑最少交换次数这个问题

首先把现在数列看成原数列{1,2,3……n}的一个置换

根据置换的理论，每一个置换都能拆成唯一的互不相交的循环

显然最小交换次数是在每个循环内部交换达成的

在一个包含元素数位x的循环内，交换成原数列的最小次数显然为x-1

最小交换次数就很明显了

而这里求的是最小交换代价，显然循环内部每个元素都要交换一次（除了只含一个元素的循环）

首先想到的是用每个循环内最小元素使循环内其他元素归位

注意还有一种情况，我们可以把整个序列里的最小元素a和这个循环里最小的b交换，然后用元素a与循环内其他元素交换，最后再把

a交换出循环（a和b交换）

最小代价就是取这两种方法较小的那一个

var a,b:array[0..10010] of longint;
    f:array[0..100010] of longint;
    v:array[0..100010] of boolean;
    t,x,max,i,n,s,ans:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure dfs(x:longint);   //找循环
  begin
    v[x]:=true;
    ans:=ans+a[x];
    inc(s);
    if not v[b[x]] then dfs(b[x]);
  end;

begin
  readln(n);
  for i:=1 to n do
  begin
    readln(x);
    if x>max then max:=x;
    f[x]:=i;
  end;
  for i:=1 to max do  
    if f[i]>0 then
    begin
      inc(t);
      b[f[i]]:=t;
      a[t]:=i;
    end;

  for i:=1 to n do
    if not v[i] then
    begin
      s:=0;
      dfs(i);
      ans:=ans+min((s-2)*a[i],(s+1)*a[1]+a[i]);
    end;

  writeln(ans);
end.