poj3373

其实这道题只告诉了一个事
当出现多个满足答案约束条件是，我们可以求一个再求一个，不要一下子全求完
前两个条件怎么弄之前已经做过类似的了
于是我们可以用记忆化搜索找出最小差异
然后配合最小差异来剪枝，搜索出最小答案

var a,b:array[0..110] of longint;
    f:array[0..110,0..10010] of longint;
    n,m,k,i:longint;
    can:boolean;
    s:string;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function differ(j,cur:longint):longint;  //f[j,cur]表示处理到第j位前面余数为cur的情况最小差异数
  var i,wh,s:longint;
  begin
    if (j=n+1) then
    begin
      if cur=0 then exit(0)
      else exit(1000);
    end;
    if f[j,cur]<>-1 then exit(f[j,cur]);
    if j<>1 then s:=0 else s:=1;
    f[j,cur]:=1000;
    for i:=s to 9 do
    begin
      wh:=differ(j+1,(cur*10+i) mod m);
      if i<>a[j] then inc(wh);
      f[j,cur]:=min(f[j,cur],wh);
    end;
    exit(f[j,cur]);
  end;

procedure dfs(j,wh,cur:longint);
  var i,s:longint;
  begin
    if (j=n+1) then
    begin
      if cur=0 then can:=true;
      exit;
    end;
    if can then exit;
    if f[j,cur]+wh>k then exit;  //剪枝
    if j<>1 then s:=0 else s:=1;
    for i:=s to 9 do
    begin
      b[j]:=i;
      if (i=a[j]) then
        dfs(j+1,wh,(cur*10+i) mod m)
      else
        dfs(j+1,wh+1,(cur*10+i) mod m);
      if can then exit;
    end;
  end;

begin
  while not eof do
  begin
    readln(s);
    n:=length(s);
    for i:=1 to n do
      a[i]:=ord(s[i])-48;
    readln(m);
    if s='0' then
    begin
      writeln(0);
      continue;
    end;
    fillchar(f,sizeof(f),255);
    k:=differ(1,0);
//    writeln(k);
    can:=false;
    dfs(1,0,0);
    for i:=1 to n do
      write(b[i]);
    writeln;
  end;
end.