bzoj1834

首先先跑裸的最大流，然后加边，在残余网络上跑费用流
比较水

const max=1000000007;
type node=record
       from,flow,cost,point,next:longint;
     end;

var edge:array[0..100010] of node;
    w:array[0..30010] of longint;
    d,p,pre,cur,h,numh:array[0..10010] of longint;
    q:array[0..2000010] of longint;
    v:array[0..2010] of boolean;
    j,x,y,f,t,ans1,ans2,len,n,m,k,i:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y,f,w:longint);
  begin
    inc(len);
    edge[len].from:=x;
    edge[len].point:=y;
    edge[len].next:=p[x];
    edge[len].flow:=f;
    edge[len].cost:=w;
    p[x]:=len;
  end;

function sap:longint;
  var tmp,x,q,u,i,j,f,neck:longint;
  begin
    sap:=0;
    fillchar(numh,sizeof(numh),0);
    fillchar(h,sizeof(h),0);
    numh[0]:=n;
    u:=1;
    while h[0]<n do
    begin
      if u=n then
      begin
        i:=1;
        j:=cur[i];
        neck:=i;
        f:=edge[j].flow;
        while i<>n do
        begin
          if edge[j].flow<f then
          begin
            f:=edge[j].flow;
            neck:=edge[j].from;
          end;
          i:=edge[j].point;
          j:=cur[i];
        end;
        i:=1;
        j:=cur[i];
        while i<>n do
        begin
          dec(edge[j].flow,f);
          inc(edge[j xor 1].flow,f);
          i:=edge[j].point;
          j:=cur[i];
        end;
        u:=neck;
        sap:=sap+f;
      end;
      q:=-1;
      i:=p[u];
      while i<>-1 do
      begin
        x:=edge[i].point;
        if (edge[i].flow>0) and (h[u]=h[x]+1) then
        begin
          q:=i;
          break;
        end;
        i:=edge[i].next;
      end;
      if q<>-1 then
      begin
        cur[u]:=i;
        x:=edge[i].point;
        pre[x]:=u;
        u:=x;
      end
      else begin
        dec(numh[h[u]]);
        if numh[h[u]]=0 then break;
        tmp:=n;
        i:=p[u];
        while i<>-1 do
        begin
          x:=edge[i].point;
          if edge[i].flow>0 then tmp:=min(tmp,h[x]);
          i:=edge[i].next;
        end;
        h[u]:=tmp+1;
        inc(numh[h[u]]);
        if u<>1 then u:=pre[u];
      end;
    end;
  end;

function spfa:boolean;
  var f,r,i,x,y:longint;
  begin
    for i:=1 to n do
      d[i]:=max;
    d[0]:=0;
    fillchar(v,sizeof(v),false);
    fillchar(pre,sizeof(pre),255);
    v[0]:=true;
    f:=1;
    r:=1;
    q[1]:=0;
    while f<=r do
    begin
      x:=q[f];
      v[x]:=false;
      i:=p[x];
      while i<>-1 do
      begin
        y:=edge[i].point;
        if edge[i].flow>0 then
          if d[x]+edge[i].cost<d[y] then
          begin
            d[y]:=d[x]+edge[i].cost;
            pre[y]:=i;
            if not v[y] then
            begin
              v[y]:=true;
              inc(r);
              q[r]:=y;
            end;
          end;
        i:=edge[i].next;
      end;
      inc(f);
    end;
    if d[n]>=max then exit(false) else exit(true);
  end;

procedure mincost;
  var x,y,i,j,neck:longint;
  begin
    while spfa do
    begin
      i:=n;
      neck:=max;
      while i<>0 do
      begin
        j:=pre[i];
        neck:=min(neck,edge[j].flow);
        i:=edge[j].from;
      end;
      i:=n;
      while i<>0 do
      begin
        j:=pre[i];
        dec(edge[j].flow,neck);
        inc(edge[j xor 1].flow,neck);
        i:=edge[j].from;
      end;
      ans2:=ans2+d[n]*neck;
    end;
  end;

begin
  readln(n,m,k);
  len:=-1;
  fillchar(p,sizeof(p),255);
  for i:=1 to m do
  begin
    readln(x,y,f,w[i]);
    add(x,y,f,0);
    add(y,x,0,0);
  end;
  ans1:=sap;
  t:=len;
  i:=0;
  while i<=t do
  begin
    x:=edge[i].from;
    y:=edge[i].point;
    f:=w[i div 2+1];
    add(x,y,max,f);
    add(y,x,0,-f);
    i:=i+2;
  end;
  add(0,1,k,0);
  add(1,0,0,0);
  mincost;
  writeln(ans1,' ',ans2);
end.