bzoj1486

这里学了一个新知识叫分数规划
这道题目是求∑w[i]/S最小
首先二分答案k，然后
如果某个环∑w[i]/S<=k即
∑w[i]<=k*S-->∑w[i]-k*S<=0--->∑(w[i]-k)<=0
所以对于原图每条边变为w[i]-k，如果存在负圈，那么k还可以更小，否则反之
判负环可以用spfa，而这里由于我们只要找到一个负圈即可
所以我们用dfs类型的spfa而不用bfs型
这里有关于spfa的dfs和bfs比较
http://wenku.baidu.com/link?url=D8kKnPDyfVfUbp7FlkM6PV484bd_ikEPvZnHkgwquiqapU4rlbgxUzsF1M9ck3pu7sBpQlwrERWsMoyWTRE7PacJ_zsAPliqlt07wKY-olO

const eps=1e-9;
type node=record
       po,next:longint;
       len:extended;
     end;

var w:array[0..20010] of node;
    p:array[0..3010] of longint;
    d:array[0..3010] of extended;
    v:array[0..3010] of boolean;
    x,y,n,m,i,len:longint;
    z,l,r,mid:extended;

procedure add(x,y:longint;z:extended);
  begin
    inc(len);
    w[len].po:=y;
    w[len].len:=z;
    w[len].next:=p[x];
    p[x]:=len;
  end;

function dfs(x:longint):boolean;
  var i,y:longint;
  begin
    v[x]:=true;
    i:=p[x];
    while i<>0 do
    begin
      y:=w[i].po;
      if d[y]>d[x]+w[i].len-mid then
      begin
        if not v[y] then
        begin
          d[y]:=d[x]+w[i].len-mid;
          if dfs(y) then exit(true)
        end
        else exit(true);
      end;
      i:=w[i].next;
    end;
    v[x]:=false;
    exit(false);
  end;

function check:boolean;
  var i:longint;
  begin
    for i:=1 to n do
      d[i]:=0;
    fillchar(v,sizeof(v),false);
    for i:=1 to n do
      if dfs(i) then exit(true);
    exit(false);
  end;

begin
  readln(n,m);
  l:=10000007;
  r:=-10000007;
  for i:=1 to m do
  begin
    readln(x,y,z);
    add(x,y,z);
    if z>r then r:=z;
    if z<l then l:=z;
  end;
  while l+eps<r do
  begin
    mid:=(l+r)/2;
    if check then r:=mid
    else l:=mid;
  end;
  writeln(l:0:8);
end.