bzoj3172

这里学习AC自动机
其实对KMP和trie掌握好了之后很容易扩展成AC自动机的
这里运用了一个性质
由失配指针反向可以建成一棵fail树
x串在y串中的出现的次数即为在fail树上以x结尾节点为根的子树中有多少个节点属于y串，这很好理解
而推广到这题，在文章中出现的次数即为单词结尾节点为根的子树的规模
注意这道题有相同的单词
当初这题我是用后缀数组做的O(LlogL)
而自动机复杂度为O(L),快了很多

type node=record
       po,next:longint;
     end;

var e:array[0..1000010] of node;
    trie:array[0..1000010,'a'..'z'] of longint;
    q,f,p,w:array[0..1000010] of longint;
    v:array[0..210] of longint;
    t,i,j,k,n,l,len:longint;
    s:ansistring;

procedure add(x,y:longint);
  begin
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure bfs;
  var x,y,h,r,j:longint;
      c:char;
  begin
    h:=1;
    r:=0;
    for c:='a' to 'z' do
      if trie[0,c]>0 then
      begin
        add(0,trie[0,c]);
        inc(r);
        q[r]:=trie[0,c];
      end;

    while h<=r do
    begin
      x:=q[h];
      for c:='a' to 'z' do
        if trie[x,c]>0 then
        begin
          y:=trie[x,c];
          inc(r);
          q[r]:=y;
          j:=f[x];
          while (j>0) and (trie[j,c]=0) do j:=f[j];
          f[y]:=trie[j,c];
          add(trie[j,c],y);
        end;
      inc(h);
    end;
  end;

procedure dfs(x:longint);
  var i,y:longint;
  begin
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      dfs(y);
      w[x]:=w[y]+w[x];
      i:=e[i].next;
    end;
  end;

begin
  readln(n);
  for i:=1 to n do
  begin
    readln(s);
    j:=0;
    l:=length(s);
    for k:=1 to l do
    begin
      if trie[j,s[k]]=0 then
      begin
        inc(t);
        trie[j,s[k]]:=t;
      end;
      j:=trie[j,s[k]];
      inc(w[j]);
    end;
    v[i]:=j;
  end;
  bfs;
  dfs(0);
  for i:=1 to n do
    writeln(w[v[i]]);
end.

var h,rank,x,y,sum,sa:array[0..1010000] of longint;
    f:array[0..1010000,0..30] of longint;
    where,len,d:array[0..500] of longint;
    now, k,ans,i,j,p,n,m,t,l,r:longint;
    s,cc:ansistring;
function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

function lcp(a,b:longint):longint;
  var k:longint;
  begin
    k:=trunc(ln(b-a+1)/ln(2));
    exit(min(f[a,k],f[b-d[k]+1,k]));
  end;

begin
  readln(t);
  for i:=1 to t do
  begin
    readln(cc);
    where[i]:=length(s)+1;
    len[i]:=length(cc);
    s:=s+cc;
    if i<>t then s:=s+' ';
  end;
{  for i:=1 to t do
     writeln(where[i],' ',len[i]);}
  n:=length(s);
  for i:=1 to n do
  begin
    y[i]:=ord(s[i]);
    inc(sum[y[i]]);
  end;
  m:=130;
  for i:=2 to 130 do
    inc(sum[i],sum[i-1]);
  for i:=1 to n do
  begin
    sa[sum[y[i]]]:=i;
    dec(sum[y[i]]);
  end;
  p:=1;
  rank[sa[1]]:=1;
  for i:=2 to n do
  begin
    if y[sa[i]]<>y[sa[i-1]] then inc(p);
    rank[sa[i]]:=p;
  end;
  m:=p;
  j:=1;
  while m<n do
  begin
    y:=rank;
    fillchar(sum,sizeof(sum),0);
    p:=0;
    for i:=n-j+1 to n do
    begin
      inc(p);
      x[p]:=i;
    end;
    for i:=1 to n do
      if sa[i]>j then
      begin
        inc(p);
        x[p]:=sa[i]-j;
      end;
    for i:=1 to n do
    begin
      rank[i]:=y[x[i]];
      inc(sum[rank[i]]);
    end;
    for i:=2 to m do
      inc(sum[i],sum[i-1]);
    for i:=n downto 1 do
    begin
      sa[sum[rank[i]]]:=x[i];
      dec(sum[rank[i]]);
    end;
    p:=1;
    rank[sa[1]]:=1;
    for i:=2 to n do
    begin
      if (y[sa[i]]<>y[sa[i-1]]) or (y[sa[i]+j]<>y[sa[i-1]+j]) then inc(p);
      rank[sa[i]]:=p;
    end;
    j:=j shl 1;
    m:=p;
  end;
  h[1]:=0;
  p:=0;
  for i:=1 to n do
  begin
    if rank[i]=1 then continue;
    j:=sa[rank[i]-1];
    while s[i+p]=s[j+p] do inc(p);
    h[rank[i]]:=p;
    if p>0 then dec(p);
  end;
  k:=trunc(ln(n)/ln(2));
  d[0]:=1;
  for i:=1 to k do
    d[i]:=d[i-1]*2;
  for i:=1 to n do
    f[i,0]:=h[i];
  for j:=1 to k do
    for i:=1 to n do
      if i+d[j]-1<=n then
      begin
        f[i,j]:=min(f[i,j-1],f[i+d[j-1],j-1]);
      end
      else break;
  for i:=1 to t do
  begin
    ans:=1;
    k:=-1;
    l:=1;
    now:=rank[where[i]];
    r:=now-1;
    while l<=r do
    begin
      m:=(l+r) shr 1;
      if lcp(m+1,now)>=len[i] then
      begin
        k:=m;
        r:=m-1
      end
      else l:=m+1;
    end;
    if k<>-1 then ans:=ans+now-k;
    l:=now+1;
    k:=-1;
    r:=n;
    while l<=r do
    begin
      m:=(l+r) shr 1;
      if lcp(now+1,m)>=len[i] then
      begin
        k:=m;
        l:=m+1;
      end
      else r:=m-1;
    end;
    if k<>-1 then ans:=ans+k-now;
    writeln(ans);
  end;
end.