poj3177

边双连通有一个非常简单的做法就是先找出所有桥，然后再dfs一次不走桥即可
答案是（叶子节点的个数+1)/2

type node=record
       next,po:longint;
     end;

var e:array[0..20010] of node;
    p,dfn,low,d,be,fa:array[0..5000] of longint;
    hash:array[0..5000,0..5000] of boolean;
    b:array[0..20010] of boolean;
    len,n,m,x,y,i,ans,t,s,j,h,r:longint;

function min(a,b:longint):longint;
  begin
    if a>b then exit(b) else exit(a);
  end;

procedure add(x,y:longint);
  begin
    hash[x,y]:=true;
    inc(len);
    e[len].po:=y;
    e[len].next:=p[x];
    p[x]:=len;
  end;

procedure tarjan(x:longint);
  var i,y:longint;
  begin
    inc(h);
    dfn[x]:=h;
    low[x]:=h;
    i:=p[x];
    while i<>-1 do
    begin
      y:=e[i].po;
      if y<>fa[x] then
      begin
        if dfn[y]=0 then
        begin
          fa[y]:=x;
          tarjan(y);
        end;
        low[x]:=min(low[x],low[y]);
        if low[y]>dfn[x] then
        begin
          b[i]:=true;
          b[i xor 1]:=true;
        end;
      end;
      i:=e[i].next;
    end;
  end;

procedure dfs(x:longint);
  var i,y:longint;
  begin
    be[x]:=s;
    i:=p[x];
    while i<>-1 do
    begin
      y:=e[i].po;
      if (be[y]=0) and not b[i] then dfs(y);
      if b[i] and (be[x]<>be[y]) then inc(d[be[x]]);
      i:=e[i].next;
    end;
  end;

begin
  len:=-1;
  fillchar(p,sizeof(p),255);
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x,y);
    if not hash[x,y] then
    begin
      add(x,y);
      add(y,x);
    end;
  end;
  tarjan(1);
  for i:=1 to n do
    if be[i]=0 then
    begin
      inc(s);
      dfs(i);
    end;

  for i:=1 to s do
    if d[i]=1 then inc(ans);
  writeln((ans+1) shr 1);
end.