bzoj1875

我们知道，邻接矩阵自乘t次就是经过t条边的路径数
但这道题显然不能这样，因为不能走回头路
于是我们可以构造边的邻接矩阵矩乘即可

const mo=45989;
type way=record
       po,fr:longint;
     end;
     node=array[0..122,0..122] of longint;

var c,a,w:node;
    ed:array[0..200] of way;
    x,y,n,m,s,t,e,i,j,ans,len:longint;

procedure add(x,y:longint);
  begin
    inc(len);
    ed[len].po:=y;
    ed[len].fr:=x;
  end;

procedure mul(var c:node;a,b:node);
  var i,j,k:longint;
  begin
    for i:=1 to len do
      for j:=1 to len do
      begin
        c[i,j]:=0;
        for k:=1 to len do
          c[i,j]:=(c[i,j]+a[i,k]*b[k,j]) mod mo;
      end;
  end;

procedure quick(n:longint);
  begin
    while n>0 do
    begin
      if n mod 2=1 then mul(a,a,w);
      mul(w,w,w);
      n:=n shr 1;
    end;
  end;

begin
  len:=1;
  readln(n,m,t,s,e);
  inc(s);
  inc(e);
  for i:=1 to m do
  begin
    readln(x,y);
    inc(x); inc(y);
    add(x,y);
    add(y,x);
  end;
  for i:=2 to len do
  begin
    for j:=2 to len do
      if (i xor 1<>j) then
        if ed[i].po=ed[j].fr then w[i,j]:=1;
    a[i,i]:=1;
    if ed[i].fr=s then c[1,i]:=1;
  end;
  quick(t-1);
  mul(c,c,a);
  for i:=2 to len do
    if ed[i].po=e then ans:=(ans+c[1,i]) mod mo;
  writeln(ans mod mo);
end.