bzoj3626

百度空间马上要下架的说，赶快把最后一点题解补完，然后搬家
这是一道不错的题，首先注意询问是满足区间减法的，我们把他变成前缀和表示
设我们询问[1,r]中的点和z的LCA深度和，假设我们确定一个根，不难发现一个有趣的事情
点z和点i的LCA深度=z和i到根公共路径（LCA到根的路径）上点的个数！
也就是说，当我们查询时，我们只要知道，[1,r]上的点到根路径上的点在z到根上出现的次数和
所以不难想到离线的做法，按照编号的顺序，每次做到点i，就把点i到根路径上点权值+1
询问的时候我们只要查询z到根路径上点权值和即可，显然我们可以用树链剖分+线段树维护

const mo=201314;
type node=record
       po,next:longint;
     end;
     que=record
       x,y,p,op:longint;
     end;

var p,c,top,ans,fa,size:array[0..50010] of longint;
    tree,lazy:array[0..50010*4] of longint;
    q:array[0..100010] of que;
    e:array[0..50010] of node;
    t,l,r,x,i,j,n,m:longint;

procedure swap(var a,b:que);
  var c:que;
  begin
    c:=a;
    a:=b;
    b:=c;
  end;

procedure add(x,y:longint);
  begin
    e[i].po:=y;
    e[i].next:=p[x];
    p[x]:=i;
  end;

procedure dfs1(x:longint);
  var i,y:longint;
  begin
    size[x]:=1;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      fa[y]:=x;
      dfs1(y);
      size[x]:=size[x]+size[y];
      i:=e[i].next;
    end;
  end;

procedure dfs2(x:longint);
  var i,y,q:longint;
  begin
    inc(t);
    c[x]:=t;
    q:=n+1;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if size[y]>size[q] then q:=y;
      i:=e[i].next;
    end;
    if q<>n+1 then
    begin
      top[q]:=top[x];
      dfs2(q);
    end;
    i:=p[x];
    while i<>0 do
    begin
      y:=e[i].po;
      if y<>q then
      begin
        top[y]:=y;
        dfs2(y);
      end;
      i:=e[i].next;
    end;
  end;

procedure sort(l,r:longint);
  var i,j,y:longint;
  begin
    i:=l;
    j:=r;
    y:=q[(l+r) shr 1].y;
    repeat
      while q[i].y<y do inc(i);
      while y<q[j].y do dec(j);
      if not(i>j) then
      begin
        swap(q[i],q[j]);
        inc(i);
        dec(j);
      end;
    until i>j;
    if l<j then sort(l,j);
    if i<r then sort(i,r);
  end;

procedure push(i,l,r:longint);
  var m:longint;
  begin
    m:=(l+r) shr 1;
    tree[i*2]:=tree[i*2]+lazy[i]*(m+1-l);
    tree[i*2+1]:=tree[i*2+1]+lazy[i]*(r-m);
    inc(lazy[i*2],lazy[i]);
    inc(lazy[i*2+1],lazy[i]);
    lazy[i]:=0;
  end;

procedure work(i,l,r,x,y:longint);
  var m:longint;
  begin
    if (x<=l) and (y>=r) then
    begin
      tree[i]:=tree[i]+r-l+1;
      lazy[i]:=lazy[i]+1;
    end
    else begin
      if lazy[i]>0 then push(i,l,r);
      m:=(l+r) shr 1;
      if x<=m then work(i*2,l,m,x,y);
      if y>m then work(i*2+1,m+1,r,x,y);
      tree[i]:=(tree[i*2]+tree[i*2+1]) mod mo;
    end;
  end;

function getans(i,l,r,x,y:longint):longint;
  var m,s:longint;
  begin
    if (x<=l) and (y>=r) then exit(tree[i])
    else begin
      if lazy[i]>0 then push(i,l,r);
      m:=(l+r) shr 1;
      s:=0;
      if x<=m then s:=s+getans(i*2,l,m,x,y);
      if y>m then s:=s+getans(i*2+1,m+1,r,x,y);
      exit(s);
    end;
  end;

procedure ins(x:longint);
  begin
    while top[x]<>-1 do
    begin
      work(1,1,n,c[top[x]],c[x]);
      x:=fa[top[x]];
    end;
    work(1,1,n,1,c[x]);
  end;

function ask(x:longint):longint;
  begin
    ask:=0;
    while top[x]<>-1 do
    begin
      ask:=ask+getans(1,1,n,c[top[x]],c[x]);
      x:=fa[top[x]];
    end;
    ask:=(ask+getans(1,1,n,1,c[x])) mod mo;
  end;

begin
  readln(n,m);
  for i:=1 to n-1 do
  begin
    read(x);
    add(x,i);
  end;
  dfs1(0);
  top[0]:=-1;
  dfs2(0);
  t:=0;
  for i:=1 to m do
  begin
    readln(l,r,x);
    inc(t);
    q[t].x:=x; q[t].y:=l-1;
    q[t].p:=i; q[t].op:=-1;
    inc(t);
    q[t].x:=x; q[t].y:=r;
    q[t].p:=i; q[t].op:=1;
  end;
  sort(1,t);
  j:=0;
  for i:=1 to t do
  begin
    while (j<n) and (j<=q[i].y) do
    begin
      ins(j);
      inc(j);
    end;
    ans[q[i].p]:=(ans[q[i].p]+q[i].op*ask(q[i].x)+mo) mod mo;
  end;
  for i:=1 to m do
    writeln(ans[i]);
end.