CodeChef GRAPHCNT

题目大意：

　　一张n个点m条边的有向图，问有多少对（x,y）存在有一条从1到x的路径，有一条1到y的路径，他们俩不相交。

题解：

　　……于是为了这题我去学习了一下支配树，感觉很妙啊。

　　设定了一个起点之后，u支配点就是从起点到u的必经点。支配树就是每个点都向自己最近的支配点连边，这有一个线性算法……这篇博客 还不错。

　　求出支配树之后就是一个问树上多少点对lca是1……嗯也挺难的对吧……

　　贴个代码吧。

program j01;
const maxn=1000086;maxm=20000086;
var q,next:array[0..maxm]of longint;
    head,pre,dom:array[0..maxn]of longint;
    semi,idom:array[0..maxn]of longint;
    f,fa,best:array[0..maxn]of longint;
    dfn,id:array[0..maxn]of longint;
    ans:int64;
    size:array[0..maxn]of longint;
    tt,n,m,i,u,v,tot:longint;

procedure addd(var h:longint;v:longint);
begin
    inc(tt);q[tt]:=v;next[tt]:=h;h:=tt;
end;

procedure dfs(i:longint);
var j:longint;
begin
    inc(tot);dfn[i]:=tot;id[tot]:=i;j:=head[i];
    while j>0 do
    begin
        if dfn[q[j]]=0 then begin fa[q[j]]:=i;dfs(q[j]);end;j:=next[j];
    end;
end;

function find(i:longint):longint;
var v:longint;
begin
    if f[i]=i then exit(i);
    v:=find(f[i]);
    if dfn[semi[best[f[i]]]]<dfn[semi[best[i]]] then best[i]:=best[f[i]];
    f[i]:=v;exit(v);
end;

procedure tarjan;
var u,j:longint;
begin
    for i:=tot downto 2 do
    begin
        u:=id[i];j:=pre[u];
        while j>0 do
        begin 
            if dfn[q[j]]=0 then begin j:=next[j];continue;end;
            find(q[j]);
            if dfn[semi[best[q[j]]]]<dfn[semi[u]] then semi[u]:=semi[best[q[j]]];
            j:=next[j];
        end;
        addd(dom[semi[u]],u);
        f[u]:=fa[u];u:=id[i-1];j:=dom[u];
        while j>0 do
        begin
            find(q[j]);
            if semi[best[q[j]]]=u then idom[q[j]]:=u
                else idom[q[j]]:=best[q[j]];
            j:=next[j];
        end;
    end;
    for i:=2 to tot do
    begin
        u:=id[i];if idom[u]<>semi[u] then idom[u]:=idom[idom[u]];
    end;
end;

begin
    readln(n,m);
    for i:=1 to m do
    begin
        readln(u,v);addd(head[u],v);addd(pre[v],u);
    end;
    dfs(1);
    for i:=1 to n do
    begin
        f[i]:=i;semi[i]:=i;best[i]:=i;
    end;
    tarjan;
    ans:=int64(tot)*(tot-1)div 2;
    for i:=tot downto 2 do
    begin
        u:=id[i];inc(size[u]);
        if idom[u]=1 then ans:=ans-(int64(size[u])*(size[u]-1)div 2);
        inc(size[idom[u]],size[u]);
    end;
    writeln(ans);
    //for i:=1 to n do writeln(i,':',idom[i]);
end.