pku3615 Cow Hurdles

给一个n个顶点的图（怎么最近的随笔都拿这句话开头^_^），Q条询问，(x,y)，查询从x到y的路径上的最大边的最小值。(Q<=40000)

最大最小问题99%都是二分答案，这道题却偏偏是那1%.

用floyd，最后的关键语句变成f[i,j]=min(f[i,j],max(f[i,k],f[k,j]))即可。算法执行后f[i,j]就是问题(i,j)的答案。

program pku3615(input,output);
var
   f   : array[0..400,0..400] of longint;
   n,m : longint;
   q   : longint;
function min(aa,bb :longint ):longint;
begin
   if aa<bb then
      exit(aa);
   exit(bb);
end; { min }
function max(aa,bb :longint ):longint;
begin
   if aa>bb then
      exit(aa);
   exit(bb);
end; { max }
procedure init;
var
   i,j        : longint;
   xx,yy,ww : longint;
begin
   fillchar(f,sizeof(f),0);
   for i:=1 to 300 do
      for j:=1 to 300 do
     if i<>j then
        f[i,j]:=maxlongint>>1;
   readln(n,m,q);
   for i:=1 to m do
   begin
      readln(xx,yy,ww);
      f[xx,yy]:=min(f[xx,yy],ww);
   end;
end; { init }
procedure main;
var
   i,j,k : longint;
begin
   for k:=1 to n do
      for i:=1 to n do
     if (i<>k) then
        for j:=1 to n do
           if (i<>j)and(j<>k) then
           f[i,j]:=min(f[i,j],max(f[i,k],f[k,j]));
end; { main }
procedure print;
var
   i     : longint;
   xx,yy : longint;
begin
   for i:=1 to q do
   begin
      readln(xx,yy);
      if f[xx,yy]<maxlongint>>1 then
     writeln(f[xx,yy])
      else
     writeln(-1);
   end;
end; { print }
begin
   init;
   main;
   print;
end.