【NOIP2015】运输计划（树上差分，二分答案）

题意：一棵有边权的树上有m条路径，要求选择一条边使其边权变为0，使得最大路径长度最小

n,m<=300000

思路：直接求最优方案不可做，但检验对于某一个ans是否能有方案是可行的

取出所有总长度>ans的路径，求它们的交，取交集中长度最大的一条，设值为c[i]，总长度最长的设为max

比较max-c[i]与ans的关系即可

路径求交因为是离线的，可以暴力树剖，也可以分类讨论维护路径交

但对于这个离线的问题，可以差分来做

对于路径(a[i],b[i])，设c[i]=lca

分为a[i]到lca，b[i]到lca两条路径 

f[a[i]]++ f[b[i]]++ f[c[i]]=f[c[i]]-2

最后自底向下dfs一遍即可

贴个两年前写的代码

var f:array[1..300000,0..19]of longint;
    head,vet,next,dep,fa,val,x,y,z,a,b,r,cnt,size,len,c,dis:array[1..700000]of longint;
    n,m,i,left,right,mid,last,tot,tmp,maxw,maxans:longint;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;
end;

procedure dfs(u,father:longint);
var e,v,i:longint;
begin
 for i:=1 to 19 do
 begin
  if dep[u]<1<<i then break;
  f[u,i]:=f[f[u,i-1],i-1];
 end;
 size[u]:=1;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if v<>fa[u] then
  begin
   f[v,0]:=u;
   fa[v]:=u;
   dep[v]:=dep[u]+1;
   dis[v]:=dis[u]+len[e];
   dfs(v,u);
   size[u]:=size[u]+size[v];
  end;
  e:=next[e];
 end;
end;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

function lca(x,y:longint):longint;
var i,d:longint;
begin
 if dep[x]<dep[y] then swap(x,y);
 d:=dep[x]-dep[y];
 for i:=0 to 19 do
  if d and (1<<i)>0 then x:=f[x,i];
 for i:=19 downto 0 do
  if f[x,i]<>f[y,i] then
  begin
   x:=f[x,i]; y:=f[y,i];
  end;
 if x=y then exit(x);
 exit(f[x,0]);
end;

function max(x,y:longint):longint;
begin
 if x>y then exit(x);
 exit(y);
end;

function dfs2(u:longint):longint;
var e,v:longint;
begin
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if v<>fa[u] then cnt[u]:=cnt[u]+dfs2(v);
  e:=next[e];
 end;
 if cnt[u]=tmp then maxw:=max(maxw,val[u]);
 exit(cnt[u]);
end;

function isok(k:longint):boolean;
var i:longint;
begin
 maxans:=0; maxw:=0; tmp:=0;
 fillchar(cnt,sizeof(cnt),0);
 for i:=1 to n do
  if c[i]>k then
  begin
   maxans:=max(maxans,c[i]);
   inc(cnt[a[i]]);
   inc(cnt[b[i]]);
   cnt[r[i]]:=cnt[r[i]]-2;
   inc(tmp);
  end;

 dfs2(1);
 if maxans-maxw<=k then exit(true);
 exit(false);
end;

begin

 readln(n,m);
 for i:=1 to n-1 do
 begin
  readln(x[i],y[i],z[i]);
  add(x[i],y[i],z[i]);
  add(y[i],x[i],z[i]);
 end;
 dfs(1,0);
 for i:=1 to m do
 begin
  readln(a[i],b[i]);
  r[i]:=lca(a[i],b[i]);
  c[i]:=dis[a[i]]+dis[b[i]]-dis[r[i]]*2;
 end;

 for i:=1 to n-1 do
  if dep[x[i]]>dep[y[i]] then val[x[i]]:=z[i]
   else val[y[i]]:=z[i];

 left:=0; right:=50000000;
 while left<=right do
 begin
  mid:=(left+right)>>1;
  if isok(mid) then begin last:=mid; right:=mid-1; end
   else left:=mid+1;
 end;
 writeln(last);


end.