【ZJOI2017 Round1练习&BZOJ5350】D5T1 masodik（DP，斜率优化）

题意：你要从(0,0)点走到(n,m)， 每次只能往 x 轴或者 y 轴正方向移动一个单位距离。
从(i,j)移动到(i,j+1)的代价为 ri,从(i,j)移动到(i+1,j)的代价为 cj。

求最小代价。

对于 20%的数据， n， m<=5000。
对于 100%的数据， n， m<=10^5,0<ri,ci<=10^8。

思路：杜教原题

• 建出r和c的下凸壳，每次走斜率大的那个。
• 证明？

• P q
• | |
• a--|-----|---
• b--|-----|---
• ra(q-p)+cp(a-b)<=rb(q-p)+cq(a-b)
• (ra-rb)(q-p)<=(cq-cp)(a-b)
• (ra-rb)/(a-b)<=(cq-cp)/(q-p)<=.......(more columns and
rows.
• 斜率?
• 每次走过路径斜率递增--->下凸
• 如何证明在下凸壳上?

下凸壳显然 假设当前是第x1行第y1列，下一个行和列是x2和y2，那么考虑是先沿行走还是先沿列走

先沿行走：r[x1]*(y2-y1)+c[y2]*(x2-x1)

先沿列走：r[x2]*(y2-y1)+c[y1]*(x2-x1)

r[x1]*(y2-y1)+c[y2]*(x2-x1)<r[x2]*(y2-y1)+c[y1]*(x2-x1)

(r[x2]-r[x1])/(x2-x1)>(c[y2]-c[y1])/(y2-y1)

于是先沿斜率大的走

var x,y:array[0..200000,1..2]of longint;
    q1,q2:array[0..200000]of longint;
    r,c:array[0..200000]of int64;
    n,m,i,j,l1,l2:longint;
    k1,k2:double;
    ans:int64;

function slope(i,j,k:longint):double;
begin
 exit((y[i,k]-y[j,k])/(x[i,k]-x[j,k]));
end;

function clac(x1,y1,x2,y2,k:longint):int64;
begin
 if k=1 then exit(r[x1]*(y2-y1)+c[y2]*(x2-x1))
        else exit(c[y1]*(x2-x1)+r[x2]*(y2-y1));
end;

begin
 assign(input,'masodik.in'); reset(input);
 assign(output,'masodik.out'); rewrite(output);
 readln(n,m);
 for i:=0 to n do
 begin
  read(y[i,1]); x[i,1]:=i; r[i]:=y[i,1];
 end;
 for i:=0 to m do
 begin
  read(y[i,2]); x[i,2]:=i; c[i]:=y[i,2];
 end;
 for i:=0 to n do
 begin
  while (l1>1)and(slope(i,q1[l1],1)<=slope(q1[l1-1],q1[l1],1)) do dec(l1);
  inc(l1); q1[l1]:=i;
 end;
 for i:=0 to m do
 begin
  while (l2>1)and(slope(i,q2[l2],2)<=slope(q2[l2-1],q2[l2],2)) do dec(l2);
  inc(l2); q2[l2]:=i;
 end;
 i:=1; j:=1;
 while (i<l1)and(j<l2) do
 begin
  k1:=slope(q1[i],q1[i+1],1);
  k2:=slope(q2[j],q2[j+1],2);
  if k1>k2 then
  begin
   ans:=ans+clac(q1[i],q2[j],q1[i],q2[j+1],1);
   inc(j);
  end
  else
  begin
   ans:=ans+clac(q1[i],q2[j],q1[i+1],q2[j],2);
   inc(i);
  end;
 end;
 while i<l1 do
 begin
  ans:=ans+clac(q1[i],q2[l2],q1[i+1],q2[l2],1);
  inc(i);
 end;
 while j<l2 do
 begin
  ans:=ans+clac(q1[l1],q2[j],q1[l1],q2[j+1],2);
  inc(j);
 end;
 writeln(ans);


 close(input);
 close(output);
end.