【HDOJ4322】Candy（费用流）

题意：给N个孩子分配M个糖果。

有一个N*M的矩阵表示孩子和糖果的关系，若第i行第j列的数是1则表示第i个孩子喜欢第j个糖果，反之不喜欢。

已知，若一个孩子被分配到他喜欢的糖果那么他将获得K的快乐值，反之只能获取1的快乐值。

现在给你这N个孩子需要满足的快乐值，问你能不能满足所有孩子的需求。

1<=N<=13, 1<=M<=13, 2<=K<=10

0<=B[i]<=1000

思路：RYZ作业

费用流（经典？）模型之一

这题的建模是使用最大费用最大流将各人喜欢的糖果作用最大化

From：http://blog.csdn.net/chenzhenyu123456/article/details/48130365

建图：设置超级源点source，超级汇点sink，用a表示当前孩子需要满足的快乐值

1，source向每个糖果建边，容量1，费用0；

2，只考虑有特殊的糖，那么对于第i个人喜欢j糖果，则j糖果向第i个人建边，容量为1，费用为0；

3，每个孩子向汇点建边。这时需要分类讨论 

     (1) a % K == 0，表示该孩子选择(a / K)个他喜欢的糖果就可以满足，而且该孩子选择1个他喜欢的糖果，会获取K的快乐值。 建边信息——容量为(a / K)，费用为K；

     (2) a % K != 0，表示该孩子选择(a / K + 1)个他喜欢的糖果才能满足，这时我们不能只建一条容量为(a / K + 1)，费用为K的边，如果这样处理我们就放大了最大流时费用的最大效益。

                             因此我们要建一条容量为(a / K)，费用为K的边，再建一条容量为1，费用为a % K的边。这样的话在用特殊糖果满足该孩子的需求时，才不会使最后流入汇点的费用增加

建好图，跑一次最大费用最大流。

最终结果：（用sumflow记录所有孩子需要满足的快乐值之和）

最大费用cost——特殊的糖被充分利用后所分配的快乐值之和。若cost >= sumflow 则表示已经满足条件。

最大流flow——为了达到这样的程度使用的糖的数量。

这样就还剩M - flow数目的糖被我们当做普通的糖使用，只要M - flow >= sumflow - cost，就可以满足条件。

var head,vet,next,len1,len2,fan,dis:array[1..2000]of longint;
    inq:array[1..2000]of boolean;
    q,b:array[0..2000]of longint;
    a:array[1..20,1..20]of longint;
    pre:array[1..2000,1..2]of longint;
    n,m,sum,ans1,ans2,tot,source,src,s,cas,v,i,j,k:longint;

procedure add(a,b,c,d:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len1[tot]:=c;
 len2[tot]:=d;
 head[a]:=tot;

 inc(tot);
 next[tot]:=head[b];
 vet[tot]:=a;
 len1[tot]:=0;
 len2[tot]:=-d;
 head[b]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

function spfa:boolean;
var u,e,v,t,w,i:longint;
begin
 for i:=1 to s do
 begin
  dis[i]:=-(maxlongint>>1);
  inq[i]:=false;
 end;
 t:=0; w:=1; q[1]:=source; dis[source]:=0; inq[source]:=true;
 while t<w do
 begin
  inc(t); u:=q[t mod 100]; inq[u]:=false;
  e:=head[u];
  while e<>0 do
  begin
   v:=vet[e];
   if (len1[e]>0)and(dis[u]+len2[e]>dis[v]) then
   begin
    dis[v]:=dis[u]+len2[e];
    pre[v,1]:=u;
    pre[v,2]:=e;
    if not inq[v] then
    begin
     inc(w); q[w mod 100]:=v; inq[v]:=true;
    end;
   end;
   e:=next[e];
  end;
 end;
 if dis[src]=-(maxlongint>>1) then exit(false);
 exit(true);
end;

procedure mcf;
var k,e,t:longint;
begin
 k:=src; t:=maxlongint;
 while k<>source do
 begin
  t:=min(t,len1[pre[k,2]]);
  k:=pre[k,1];
 end;
 k:=src;
 while k<>source do
 begin
  e:=pre[k,2];
  len1[e]:=len1[e]-t;
  len1[fan[e]]:=len1[fan[e]]+t;
  ans2:=ans2+t*len2[e];
  k:=pre[k,1];
 end;
 ans1:=ans1+t;
end;

begin
 assign(input,'hdoj4322.in'); reset(input);
 assign(output,'hdoj4322.out'); rewrite(output);
 readln(cas);
 for i:=1 to 2000 do
  if i and 1=1 then fan[i]:=i+1
   else fan[i]:=i-1;
 for v:=1 to cas do
 begin
  readln(n,m,k);
  for i:=1 to s do head[i]:=0;
  tot:=0; s:=0; ans1:=0; ans2:=0; sum:=0;
  for i:=1 to m do
  begin
   read(b[i]);
   sum:=sum+b[i];
  end;
  for i:=1 to m do
   for j:=1 to n do read(a[i,j]);
  source:=n+m+1; src:=n+m+2; s:=n+m+2;
  for i:=1 to n do add(source,i,1,0);
  for i:=1 to m do
   for j:=1 to n do
    if a[i,j]=1 then add(j,i+n,1,0);
  for i:=1 to m do
  begin
   add(i+n,src,b[i] div k,k);
   if b[i] mod k>0 then add(i+n,src,1,b[i] mod k);
  end;
  while spfa do mcf;
  if n-ans1>=sum-ans2 then writeln('Case #',v,': YES')
   else writeln('Case #',v,': NO');
 end;
 close(input);
 close(output);
end.