【BZOJ2874】训练士兵（主席树）

题意：有一个N*M的矩阵，给出一些形如(x1,y1,x2,y2,s)的操作，代表(x1,y1)到(x2,y2)都被加上了s这个数

现在有一些强制在线的询问，询问(x1,y1)到(x2,y2)的和

对于100%的数据 n,m<=10^8,k<=40000,q<=100000； 

思路：将操作(x1,y1,x2,y2,s)差分成

(x1,y1)+s

(x1,y2+1)-s

(x2+1,y1)-s

(x2+1,y2+1)+s 

四个点

询问(x,y)等价于

[sum_{i=1}^x  sum_{j=1}^y   a[i,j]*(x+1)*(y+1)-a[i,j]*i*(y+1)-a[i,j]*j*(x+1)+a[i,j]*i*j ]

证明如下：

可以看出只需维护a[i,j],a[i,j]*i,a[i,j]*j,a[i,j]*i*j四个值的二维前缀和

从左到右，从上到下排序并离散化，对每一行建立一棵主席树表示左上角的前缀和，

询问时在主席树中查找一段从头开始的前缀和即可

var t:array[0..6000000,1..6]of int64;
    root:array[0..600000]of int64;
    c:array[1..300000,1..3]of int64;
    cx,cy:array[1..300000]of int64;
    n,m,i,j,u,k,cnt,u1,u2,k1,q1,tmp,x,y:longint;
    ans,x1,y1,x2,y2:int64;

procedure swap(var x,y:int64);
var t:int64;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsortx(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=cx[(l+r)>>1];
 repeat
  while mid>cx[i] do inc(i);
  while mid<cx[j] do dec(j);
  if i<=j then
  begin
   swap(cx[i],cx[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsortx(l,j);
 if i<r then qsortx(i,r);
end;

procedure qsorty(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=cy[(l+r)>>1];
 repeat
  while mid>cy[i] do inc(i);
  while mid<cy[j] do dec(j);
  if i<=j then
  begin
   swap(cy[i],cy[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsorty(l,j);
 if i<r then qsorty(i,r);
end;

function hashx(x:longint):longint;
var l,r,mid,last:longint;
begin
 l:=1; r:=u1; last:=0;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  if x>=cx[mid] then begin last:=mid; l:=mid+1; end
   else r:=mid-1;
 end;
 exit(last);
end;

function hashy(x:longint):longint;
var l,r,mid,last:longint;
begin
 l:=1; r:=u2; last:=0;
 while l<=r do
 begin
  mid:=(l+r)>>1;
  if x>=cy[mid] then begin last:=mid; l:=mid+1; end
   else r:=mid-1;
 end;
 exit(last);
end;

procedure qsort(l,r:longint);
var i,j,mid1,mid2:longint;
begin
 i:=l; j:=r; mid1:=c[(l+r)>>1,1]; mid2:=c[(l+r)>>1,2];
 repeat
  while (mid1>c[i,1])or((mid1=c[i,1])and(mid2>c[i,2])) do inc(i);
  while (mid1<c[j,1])or((mid1=c[j,1])and(mid2<c[j,2])) do dec(j);
  if i<=j then
  begin
   swap(c[i,1],c[j,1]);
   swap(c[i,2],c[j,2]);
   swap(c[i,3],c[j,3]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

function query(p,l,r,x,y:longint):int64;
var mid:longint;
begin
 if x=0 then exit(0);
 if p=0 then exit(0);
 if x>=r then exit(t[p,y]);
 mid:=(l+r)>>1;
 if x<=mid then exit(query(t[p,5],l,mid,x,y))
  else exit(t[t[p,5],y]+query(t[p,6],mid+1,r,x,y));
end;

function ask(x,y:longint):int64;
var x1,y1:longint;
begin
 x1:=hashx(x); y1:=hashy(y);
 ask:=0;
 ask:=ask+query(root[x1],1,u2,y1,1)*(x+1)*(y+1);
 ask:=ask-query(root[x1],1,u2,y1,2)*(y+1);
 ask:=ask-query(root[x1],1,u2,y1,3)*(x+1);
 ask:=ask+query(root[x1],1,u2,y1,4);
end;

procedure update(var p:int64;l,r,x:longint;v:int64;x1,y1:longint);
var mid:longint;
begin
 inc(cnt); t[cnt]:=t[p];
 p:=cnt;
 t[cnt,1]:=t[cnt,1]+v;
 t[cnt,2]:=t[cnt,2]+v*x1;
 t[cnt,3]:=t[cnt,3]+v*y1;
 t[cnt,4]:=t[cnt,4]+v*x1*y1;
 if l=r then exit;
 mid:=(l+r)>>1;
 if x<=mid then update(t[p,5],l,mid,x,v,x1,y1)
  else update(t[p,6],mid+1,r,x,v,x1,y1);
end;

begin
 assign(input,'bzoj2874.in'); reset(input);
 assign(output,'bzoj2874.out'); rewrite(output);
 readln(n,m,k1,q1);
 k:=0;
 for i:=1 to k1 do
 begin
  read(x1); read(x2); read(y1); read(y2); read(tmp);
  inc(k); c[k,1]:=x1; c[k,2]:=y1; c[k,3]:=tmp;
  inc(k); c[k,1]:=x1; c[k,2]:=y2+1; c[k,3]:=-tmp;
  inc(k); c[k,1]:=x2+1; c[k,2]:=y1; c[k,3]:=-tmp;
  inc(k); c[k,1]:=x2+1; c[k,2]:=y2+1; c[k,3]:=tmp;
  inc(u); cx[u]:=x1; cy[u]:=y1;
  inc(u); cx[u]:=x2+1; cy[u]:=y2+1;
 end;
 qsortx(1,u); qsorty(1,u);
 u1:=1;
 for i:=2 to u do
  if cx[i]<>cx[u1] then begin inc(u1); cx[u1]:=cx[i]; end;
 u2:=1;
 for i:=2 to u do
  if cy[i]<>cy[u2] then begin inc(u2); cy[u2]:=cy[i]; end;

 qsort(1,k);
 j:=1;
 for i:=1 to u1 do
 begin
  root[i]:=root[i-1];
  while (j<=k)and(hashx(c[j,1])=i) do
  begin
   update(root[i],1,u2,hashy(c[j,2]),c[j,3],c[j,1],c[j,2]);
   inc(j);
  end;
 end;
 for i:=1 to q1 do
 begin
  readln(x,y);
  x1:=ans mod n+1; x2:=(ans+x) mod n+1; if x1>x2 then swap(x1,x2);
  y1:=ans mod m+1; y2:=(ans+y) mod m+1; if y1>y2 then swap(y1,y2);
  ans:=ask(x2,y2)-ask(x1-1,y2)-ask(x2,y1-1)+ask(x1-1,y1-1);
  writeln(ans);
 end;
 close(input);
 close(output);
end.