【Codevs1907】方格取数3（最小割）

题意：在一个有m*n 个方格的棋盘中，每个方格中有一个正整数。现要从方格中取数，使任
意2 个数所在方格没有公共边，且取出的数的总和最大。试设计一个满足要求的取数算法。

n,m<=30

思路：如果将棋盘黑白点染色，可以发现相邻的黑白点不能同时取

将源点到黑点连一条容量为黑点数字的边，黑点到相邻白点连容量为∞的边，白点到汇点连容量为白点数字的边，可以发现如果不让相邻黑白点同时取到，三条边中必定要切断一条

题意就是让切断的总和最小，所以显然不会切∞，只会切另外两条

跑最小割即可

const dx:array[1..4]of longint=(-1,1,0,0);
      dy:array[1..4]of longint=(0,0,-1,1);
var fan:array[1..200000]of longint;
    head,vet,next,len,gap,dis:array[0..20000]of longint;
    a,b,num:array[1..50,1..50]of longint;
    n,m,i,j,tot,source,src,s,sum,k,x,y:longint;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

procedure add(a,b,c:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 head[a]:=tot;

 inc(tot);
 next[tot]:=head[b];
 vet[tot]:=a;
 len[tot]:=0;
 head[b]:=tot;
end;

function dfs(u,aug:longint):longint;
var e,v,t,val,flow:longint;
begin
 if u=src then exit(aug);
 e:=head[u]; val:=s-1; flow:=0;
 while e<>0 do
 begin
  v:=vet[e];
  if len[e]>0 then
  begin
   if dis[u]=dis[v]+1 then
   begin
    t:=dfs(v,min(len[e],aug-flow));
    len[e]:=len[e]-t;
    len[fan[e]]:=len[fan[e]]+t;
    flow:=flow+t;
    if dis[source]>=s then exit(flow);
    if aug=flow then break;
   end;
   val:=min(val,dis[v]);
  end;
  e:=next[e];
 end;
 if flow=0 then
 begin
  dec(gap[dis[u]]);
  if gap[dis[u]]=0 then dis[source]:=s;
  dis[u]:=val+1;
  inc(gap[dis[u]]);
 end;
 exit(flow);
end;


function maxflow:longint;
var ans:longint;
begin
 fillchar(gap,sizeof(gap),0);
 fillchar(dis,sizeof(dis),0);
 gap[0]:=s; ans:=0;
 while dis[source]<s do ans:=ans+dfs(source,maxlongint);
 exit(ans);
end;

begin
 assign(input,'Codevs1907.in'); reset(input);
 assign(output,'Codevs1907.out'); rewrite(output);
 readln(n,m);
 for i:=1 to 200000 do
  if i mod 2=1 then fan[i]:=i+1
   else fan[i]:=i-1;
 for i:=1 to n do
  for j:=1 to m do
  begin
   read(a[i,j]); sum:=sum+a[i,j];
   inc(s); num[i,j]:=s; b[i,j]:=(i+j+1) mod 2;
  end;
 for i:=1 to n do
  for j:=1 to m do
   if b[i,j]=1 then
    for k:=1 to 4 do
    begin
     x:=i+dx[k]; y:=j+dy[k];
     if (x>0)and(x<=n)and(y>0)and(y<=m) then
     begin
      add(num[i,j],num[x,y],maxlongint);
      //writeln(i,' ',j,' ',x,' ',y);
     end;
    end;
 source:=s+1; src:=s+2; s:=s+2;
 for i:=1 to n do
  for j:=1 to m do
   if b[i,j]=1 then
   begin
    //writeln(source,' ',i,' ',j);
    add(source,num[i,j],a[i,j]);
   end
    else
    begin
     //writeln(i,' ',j,' ',src);
     add(num[i,j],src,a[i,j]);
    end;
 writeln(sum-maxflow);

 close(input);
 close(output);
end.