【CF733F】Drivers Dissatisfaction（最小瓶颈生成树，倍增）

题意：给出一个图，每条边有权值和花费c，每次花费ｃ能使的权值-1。给出一个预算，求减完权值后的一个最小生成树。

思路：感谢CC大神

        有这样一个结论：最佳方案里必定存在一种，预算全部花费全部分配在一条边上。证明显然，对于任意一组解，都可以在内部再分配预算使总费用更小或不变。

        于是先求出原图的最小生成树，枚举每条边。

        对于在生成树中的，判断使这条边减费是否更优。

        不在生成树上的，找出树上从x[i]到y[i]的路径（唯一）上a[i]最大的边，判断删除那条边并加入减费后的(x[i],y[i])是否更优。

type yjs=record
          a:longint;
          s:int64;
         end;
var f,q,g:array[1..210000,0..19]of longint;
    head,vet,next,len,num,a,b,c,x,y,dep,fa,inq,ya,yb:array[1..500000]of longint;
    hth,mst,s:int64;
    tot,n,m,i,del,k,tx,ty:longint;
    t:yjs;

procedure swap(var x,y:longint);
var t:longint;
begin
 t:=x; x:=y; y:=t;
end;

procedure qsort(l,r:longint);
var i,j,mid:longint;
begin
 i:=l; j:=r; mid:=a[(l+r)>>1];
 repeat
  while mid>a[i] do inc(i);
  while mid<a[j] do dec(j);
  if i<=j then
  begin
   swap(a[i],a[j]); swap(b[i],b[j]); swap(c[i],c[j]);
   swap(x[i],x[j]); swap(y[i],y[j]);
   inc(i); dec(j);
  end;
 until i>j;
 if l<j then qsort(l,j);
 if i<r then qsort(i,r);
end;

procedure add(a,b,c,d:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 len[tot]:=c;
 num[tot]:=d;
 head[a]:=tot;
end;

function lca(x,y:longint):longint;
var i,d:longint;
begin
 if dep[x]<dep[y] then swap(x,y);
 d:=dep[x]-dep[y];
 for i:=0 to 19 do
  if d and (1<<i)>0 then x:=q[x,i];
 for i:=19 downto 0 do
  if q[x,i]<>q[y,i] then
  begin
   x:=q[x,i]; y:=q[y,i];
  end;
 if x=y then exit(x);
 exit(q[x,0]);
end;

function clac(x,y:longint):yjs;
var i,d:longint;
    cc:yjs;
begin
 if dep[x]<dep[y] then swap(x,y);
 d:=dep[x]-dep[y];
 cc.a:=0; cc.s:=-maxlongint;
 for i:=19 downto 0 do
  if d and (1<<i)>0 then
  begin
   if f[x,i]>cc.s then
   begin
    cc.a:=g[x,i];
    cc.s:=f[x,i];
   end;
   x:=q[x,i];
  end;
 exit(cc);
end;

function ask(x,y:longint):yjs;
var t:longint;
    t1,t2:yjs;
begin
 t:=lca(x,y);
 t1:=clac(x,t);
 t2:=clac(y,t);
 if t1.s>t2.s then exit(t1);
 exit(t2);
end;

function find(k:longint):longint;
begin
 if fa[k]<>k then fa[k]:=find(fa[k]);
 find:=fa[k];
end;

procedure dfs(u,pre:longint);
var e,v,i:longint;
begin
 for i:=1 to 19 do
 begin
  if dep[u]<(1<<i) then break;
  q[u,i]:=q[q[u,i-1],i-1];
  if f[u,i-1]<f[q[u,i-1],i-1] then
  begin
   f[u,i]:=f[q[u,i-1],i-1];
   g[u,i]:=g[q[u,i-1],i-1];
  end
   else
   begin
    f[u,i]:=f[u,i-1];
    g[u,i]:=g[u,i-1];
   end;
 end;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if v<>pre then
  begin
   dep[v]:=dep[u]+1;
   f[v,0]:=len[e];
   q[v,0]:=u;
   g[v,0]:=num[e];
   dfs(v,u);
  end;
  e:=next[e];
 end;
end;

begin

 readln(n,m);
 for i:=1 to m do read(a[i]);
 for i:=1 to m do read(b[i]);
 for i:=1 to m do c[i]:=i;
 for i:=1 to m do readln(x[i],y[i]);
 readln(s);
 ya:=a; yb:=b;
 qsort(1,m);
 for i:=1 to n do fa[i]:=i;
 for i:=1 to m do
 begin
  tx:=find(x[i]); ty:=find(y[i]);
  if tx<>ty then
  begin
   fa[ty]:=tx;
   hth:=hth+a[i];
   inq[c[i]]:=1;
   add(x[i],y[i],a[i],c[i]);
   add(y[i],x[i],a[i],c[i]);
  end;
 end;
 dfs(1,-1);
 mst:=hth;
 for i:=1 to m do
  if inq[c[i]]=1 then
  begin
   if mst-s div b[i]<hth then
   begin
    hth:=mst-s div b[i];
    k:=c[i];
   end;
  end
   else
   begin
    t:=ask(x[i],y[i]);
    if mst-ya[t.a]+a[i]-s div b[i]<hth then
    begin
     hth:=mst-ya[t.a]+a[i]-s div b[i];
     k:=c[i];
     del:=t.a;
    end;
   end;
 writeln(hth);
 for i:=1 to m do
 begin
  if i=del then continue;
  if i=k then begin writeln(i,' ',ya[i]-s div yb[i]); continue; end;
  if inq[i]=1 then writeln(i,' ',ya[i]);
 end;

end.