【CF711D】Directed Roads（环，强连通分量）

题意：

　　给一张N个点N条有向边的图，边可以逆向。问任意逆向若干条边使得这张图无环的方案数(mod 1e9+7)。

n<=200000

思路：三个样例给的好 找规律方便很多

        易得有N点的环有(2^n)-2中改法，除了不改和都改

        剩下的都是链，设除环外还有K个点，他们的总贡献就是2^k，因为都是一条边相连接怎么改也没有环

        CF上快速幂要写在外面不然会出现奇奇怪怪的CE

const mo=1000000007;
var head,vet,next,stack,low,dfn,b,s,flag:array[1..500000]of longint;
    n,tot,i,id,time,top,x,m:longint;
    ans,f,tmp:int64;

procedure add(a,b:longint);
begin
 inc(tot);
 next[tot]:=head[a];
 vet[tot]:=b;
 head[a]:=tot;
end;

function min(x,y:longint):longint;
begin
 if x<y then exit(x);
 exit(y);
end;

procedure dfs(u:longint);
var e,v:longint;
begin
 flag[u]:=1;
 inc(top); stack[top]:=u;
 inc(time); dfn[u]:=time; low[u]:=time;
 e:=head[u];
 while e<>0 do
 begin
  v:=vet[e];
  if flag[v]=0 then
  begin
   dfs(v);
   low[u]:=min(low[u],low[v]);
  end
   else if s[v]=0 then low[u]:=min(low[u],low[v]);
  e:=next[e];
 end;
 if dfn[u]=low[u] then
 begin
  inc(id); s[u]:=id; inc(b[id]);
  while (top>0)and(stack[top]<>u) do
  begin
   s[stack[top]]:=id;
   inc(b[id]);
   stack[top]:=0;
   dec(top);
  end;
  stack[top]:=0; dec(top);
 end;
end;

begin

 readln(n);
 for i:=1 to n do
 begin
  read(x);
  add(i,x);
 end;
 for i:=1 to n do
  if flag[i]=0 then dfs(i);
 m:=0;
 for i:=1 to n do
  if b[s[i]]=1 then m:=m+1;
 ans:=1;
 for i:=1 to id do
  if b[i]>1 then
  begin
   f:=1; tmp:=2;
   while b[i]>0 do
   begin
    if b[i] mod 2=1 then f:=f*tmp mod mo;
    tmp:=tmp*tmp mod mo;
    b[i]:=b[i] div 2;
   end;
   ans:=(ans*(f-2)) mod mo;
  end;
  ans:=(ans+mo) mod mo;
  f:=1; tmp:=2;
  while m>0 do
  begin
   if m mod 2=1 then f:=f*tmp mod mo;
   tmp:=tmp*tmp mod mo;
   m:=m div 2;
  end;
  ans:=ans*f mod mo;
 writeln(ans);

end.