linux awk命令详细使用方法

简单介绍

awk是一个强大的文本分析工具，相对于grep的查找，sed的编辑，awk在其对数据分析并生成报告时，显得尤为强大。简单来说awk就是把文件逐行的读入，以空格为默认分隔符将每行切片，切开的部分再进行各种分析处理。

awk有3个不同版本号: awk、nawk和gawk，未作特别说明，一般指gawk，gawk 是 AWK 的 GNU 版本号。

awk其名称得自于它的创始人 Alfred Aho 、Peter Weinberger 和 Brian Kernighan 姓氏的首个字母。实际上 AWK 的确拥有自己的语言： AWK 程序设计语言 ， 三位创建者已将它正式定义为“样式扫描和处理语言”。它同意您创建简短的程序，这些程序读取输入文件、为数据排序、处理数据、对输入运行计算以及生成报表，还有无数其它的功能。

使用方法

awk '{pattern + action}' {filenames}

尽管操作可能会非常复杂，但语法总是这样，当中 pattern 表示 AWK 在数据中查找的内容，而 action 是在找到匹配内容时所运行的一系列命令。花括号（{}）不须要在程序中始终出现，但它们用于依据特定的模式对一系列指令进行分组。 pattern就是要表示的正則表達式，用斜杠括起来。

awk语言的最基本功能是在文件或者字符串中基于指定规则浏览和抽取信息，awk抽取信息后，才干进行其它文本操作。完整的awk脚本通常常使用来格式化文本文件里的信息。

通常，awk是以文件的一行为处理单位的。awk每接收文件的一行，然后运行相应的命令，来处理文本。

调用awk

有三种方式调用awk

1.命令行方式
awk [-F  field-separator]  'commands'  input-file(s)
当中，commands 是真正awk命令，[-F域分隔符]是可选的。 input-file(s) 是待处理的文件。
在awk中，文件的每一行中，由域分隔符分开的每一项称为一个域。通常，在不指名-F域分隔符的情况下，默认的域分隔符是空格。

2.shell脚本方式
将全部的awk命令插入一个文件，并使awk程序可运行，然后awk命令解释器作为脚本的首行，一遍通过键入脚本名称来调用。
相当于shell脚本首行的：#!/bin/sh
能够换成：#!/bin/awk

3.将全部的awk命令插入一个单独文件，然后调用：
awk -f awk-script-file input-file(s)
当中，-f选项载入awk-script-file中的awk脚本，input-file(s)跟上面的是一样的。

 本章重点介绍命令行方式。

入门实例

假设last -n 5的输出例如以下

[root@www ~]# last -n 5 <==仅取出前五行
root     pts/1   192.168.1.100  Tue Feb 10 11:21   still logged in
root     pts/1   192.168.1.100  Tue Feb 10 00:46 - 02:28  (01:41)
root     pts/1   192.168.1.100  Mon Feb  9 11:41 - 18:30  (06:48)
dmtsai   pts/1   192.168.1.100  Mon Feb  9 11:41 - 11:41  (00:00)
root     tty1                   Fri Sep  5 14:09 - 14:10  (00:01)

假设仅仅是显示近期登录的5个帐号

#last -n 5 | awk  '{print $1}'
root
root
root
dmtsai
root

awk工作流程是这种：读入有' '换行符切割的一条记录，然后将记录按指定的域分隔符划分域，填充域，$0则表示全部域,$1表示第一个域,$n表示第n个域。默认域分隔符是"空白键" 或 "[tab]键",所以$1表示登录用户，$3表示登录用户ip,以此类推。

假设仅仅是显示/etc/passwd的账户

#cat /etc/passwd |awk  -F ':'  '{print $1}'  
root
daemon
bin
sys

这种是awk+action的演示例子，每行都会运行action{print $1}。

-F指定域分隔符为':'。

假设仅仅是显示/etc/passwd的账户和账户相应的shell,而账户与shell之间以tab键切割

#cat /etc/passwd |awk  -F ':'  '{print $1"	"$7}'
root    /bin/bash
daemon  /bin/sh
bin     /bin/sh
sys     /bin/sh

假设仅仅是显示/etc/passwd的账户和账户相应的shell,而账户与shell之间以逗号切割,并且在全部行增加列名name,shell,在最后一行增加"blue,/bin/nosh"。

cat /etc/passwd |awk  -F ':'  'BEGIN {print "name,shell"}  {print $1","$7} END {print "blue,/bin/nosh"}'
name,shell
root,/bin/bash
daemon,/bin/sh
bin,/bin/sh
sys,/bin/sh
....
blue,/bin/nosh

awk工作流程是这种：先运行BEGING，然后读取文件，读入有/n换行符切割的一条记录，然后将记录按指定的域分隔符划分域，填充域，$0则表示全部域,$1表示第一个域,$n表示第n个域,随后開始运行模式所相应的动作action。接着開始读入第二条记录······直到全部的记录都读完，最后运行END操作。

搜索/etc/passwd有rootkeyword的全部行

#awk -F: '/root/' /etc/passwd
root:x:0:0:root:/root:/bin/bash

这种是pattern的使用演示例子，匹配了pattern(这里是root)的行才会运行action(沒有指定action，默认输出每行的内容)。

搜索支持正则，比如找root开头的: awk -F: '/^root/' /etc/passwd

搜索/etc/passwd有rootkeyword的全部行，并显示相应的shell

# awk -F: '/root/{print $7}' /etc/passwd             
/bin/bash

 这里指定了action{print $7}

awk内置变量

awk有很多内置变量用来设置环境信息，这些变量能够被改变，以下给出了最常常使用的一些变量。

ARGC               命令行參数个数
ARGV               命令行參数排列
ENVIRON            支持队列中系统环境变量的使用
FILENAME           awk浏览的文件名称
FNR                浏览文件的记录数
FS                 设置输入域分隔符，等效于命令行 -F选项
NF                 浏览记录的域的个数
NR                 已读的记录数
OFS                输出域分隔符
ORS                输出记录分隔符
RS                 控制记录分隔符

 此外,$0变量是指整条记录。$1表示当前行的第一个域,$2表示当前行的第二个域,......以此类推。

统计/etc/passwd:文件名称，每行的行号，每行的列数，相应的完整行内容:

#awk  -F ':'  '{print "filename:" FILENAME ",linenumber:" NR ",columns:" NF ",linecontent:"$0}' /etc/passwd
filename:/etc/passwd,linenumber:1,columns:7,linecontent:root:x:0:0:root:/root:/bin/bash
filename:/etc/passwd,linenumber:2,columns:7,linecontent:daemon:x:1:1:daemon:/usr/sbin:/bin/sh
filename:/etc/passwd,linenumber:3,columns:7,linecontent:bin:x:2:2:bin:/bin:/bin/sh
filename:/etc/passwd,linenumber:4,columns:7,linecontent:sys:x:3:3:sys:/dev:/bin/sh

使用printf替代print,能够让代码更加简洁，易读

 awk  -F ':'  '{printf("filename:%10s,linenumber:%s,columns:%s,linecontent:%s
",FILENAME,NR,NF,$0)}' /etc/passwd

print和printf

awk中同一时候提供了print和printf两种打印输出的函数。

当中print函数的參数能够是变量、数值或者字符串。字符串必须用双引號引用，參数用逗号分隔。假设沒有逗号，參数就串联在一起而无法区分。这里，逗号的作用与输出文件的分隔符的作用是一样的，仅仅是后者是空格而已。

printf函数，其使用方法和c语言中printf基本类似,能够格式化字符串,输出复杂时，printf更加好用，代码更易懂。

 awk编程

 变量和赋值

除了awk的内置变量，awk还能够自己定义变量。

以下统计/etc/passwd的账户人数

awk '{count++;print $0;} END{print "user count is ", count}' /etc/passwd
root:x:0:0:root:/root:/bin/bash
......
user count is  40

count是自己定义变量。之前的action{}里都是唯独一个print,事实上print仅仅是一个语句，而action{}能够有多个语句，以;号隔开。

这里沒有初始化count，尽管默认是0，可是妥当的做法还是初始化为0:

awk 'BEGIN {count=0;print "[start]user count is ", count} {count=count+1;print $0;} END{print "[end]user count is ", count}' /etc/passwd
[start]user count is  0
root:x:0:0:root:/root:/bin/bash
...
[end]user count is  40

统计某个目录下的文件占用的字节数

ls -l |awk 'BEGIN {size=0;} {size=size+$5;} END{print "[end]size is ", size}'
[end]size is  8657198

假设以M为单位显示:

ls -l |awk 'BEGIN {size=0;} {size=size+$5;} END{print "[end]size is ", size/1024/1024,"M"}' 
[end]size is  8.25889 M

注意，统计不包含目录的子目录。

条件语句

 awk中的条件语句是从C语言中借鉴来的，见例如以下声明方式：

if (expression) {
    statement;
    statement;
    ... ...
}

if (expression) {
    statement;
} else {
    statement2;
}

if (expression) {
    statement1;
} else if (expression1) {
    statement2;
} else {
    statement3;
}

统计某个目录下的文件占用的字节数,过滤4096大小的文件(一般都是目录):

ls -l |awk 'BEGIN {size=0;print "[start]size is ", size} {if($5!=4096){size=size+$5;}} END{print "[end]size is ", size/1024/1024,"M"}' 
[end]size is  8.22339 M

循环语句

awk中的循环语句相同借鉴于C语言，支持while、do/while、for、break、continue，这些keyword的语义和C语言中的语义全然相同。

数组

  因为awk中数组的下标能够是数字和字母，数组的下标通常被称为keyword(key)。值和keyword都存储在内部的一张针对key/value应用hash的表格里。因为hash不是顺序存储，因此在显示数组内容时会发现，它们并非依照你预料的顺序显示出来的。数组和变量一样，都是在使用时自己主动创建的，awk也相同会自己主动推断其存储的是数字还是字符串。一般而言，awk中的数组用来从记录中收集信息，能够用于计算总和、统计单词以及跟踪模板被匹配的次数等等。

显示/etc/passwd的账户

awk -F ':' 'BEGIN {count=0;} {name[count] = $1;count++;}; END{for (i = 0; i < NR; i++) print i, name[i]}' /etc/passwd
0 root
1 daemon
2 bin
3 sys
4 sync
5 games
......

这里使用for循环遍历数组

awk编程的内容极多，这里仅仅罗列简单常常使用的使用方法，许多其他请參考 http://www.gnu.org/software/gawk/manual/gawk.html