一个flash鼠标特效

有点像“水果忍者”划过屏幕时的动画，在每次按住鼠标左键不放然后拖动鼠标并释放，会出现动画。动画我参考别人的代码，然后在显示特效的时候使用了不同的颜色。

代码并不复杂，主要用到了GlowFilter，然后让线条的粗细大小从指定的一个值，慢慢减小..

MouseEffectDemo.as

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.GlowFilter;
    /**
     * ...
     * @author Meteoric_cry
     */
    public class MouseEffectDemo extends Sprite
    {
        private var _scene:Sprite;

        private var _startX:int;
        private var _startY:int;

        private var _isDown:Boolean;

        private static const MIN_POINT_DISTANCE:int = 20;

        public function MouseEffectDemo()
        {
            initView();
        }

        private function initView():void
        {
            _scene = new Sprite();

            addChild(_scene);

            _scene.filters = [getGlowFilter(0x00CCFF)];

            stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUpHandler);
        }

        private function listenerEnterFrameHandler():void
        {
            unlistenerEnterFrameHandler();

            stage.addEventListener(Event.ENTER_FRAME, onEnterFrameHandler);
        }

        private function unlistenerEnterFrameHandler():void
        {
            stage.removeEventListener(Event.ENTER_FRAME, onEnterFrameHandler);
        }

        private function onEnterFrameHandler(e:Event):void
        {
            //LineArr的长度可能会动态变化，详情参见它的update方法
            for each (var line:Line in Line.lineArr)
            {
                line.update();
            }

            update();
        }

        private function update():void
        {
            if (_isDown == false)
            {
                if (Line.lineArr.length === 0)
                {
                    unlistenerEnterFrameHandler();
                }

                return ;
            }

            var endX:int = mouseX;
            var endY:int = mouseY;

            if (Math.abs(_startX - endX) < MIN_POINT_DISTANCE || Math.abs(_startY - endY) < MIN_POINT_DISTANCE)
            {
                return ;
            }

            var line:Line = new Line(_startX, _startY, endX, endY);

            _scene.addChild(line);

            _startX = endX;
            _startY = endY;
        }

        private function onMouseUpHandler(e:MouseEvent):void
        {
            _isDown = false;
        }

        private function onMouseDownHandler(e:MouseEvent):void
        {
            _isDown = true;

            changeColorHandler();

            _startX = mouseX;
            _startY = mouseY;

            listenerEnterFrameHandler();
        }

        private function getGlowFilter(color:Number):GlowFilter
        {
            return new GlowFilter(color, 1, 10, 10, 2, 1, false, false)
        }

        private function changeColorHandler():void
        {
            var colorArr:Array = [0x00CCFF, 0xF5001D, 0xBC0093, 0x00CE00, 0xFF7400];
            var color:Number = colorArr[Math.floor(Math.random() * colorArr.length)];

            _scene.filters = [getGlowFilter(color)];
        }

    }

}

Line.as

package
{
    import flash.display.Sprite;

    /**
     * ...
     * @author Meteoric_cry
     */
    public class Line extends Sprite
    {
        static public var lineArr:Array = [];

        public var startX:int;
        public var startY:int;
        public var endX:int;
        public var endY:int;
        public var lineSize:int;

        public function Line(x0:int, y0:int, x1:int, y1:int, size:int=8)
        {
            lineArr.push(this);

            startX = x0;
            startY = y0;
            endX = x1;
            endY = y1;
            lineSize = size;

            draw();
        }

        private function draw():void
        {
            graphics.clear();
            graphics.lineStyle(lineSize, 0xFFFFFF);
            graphics.moveTo(startX, startY);
            graphics.lineTo(endX, endY);
        }

        public function update():void
        {
            draw();

            lineSize -= 1;

            if (lineSize < 1)
            {
                clear();
            }
        }

        private function clear():void
        {
            graphics.clear();

            for (var i:int = 0, len:int = lineArr.length; i < len; i++)
            {
                var line:Line = lineArr[i] as Line;

                if (line == this)
                {
                    lineArr.splice(i, 1);
                    parent.removeChild(this);

                    break;
                }
            }
        }


    }

}