浅谈网络流的基本算法 [转]

　

引言

　　过去听起来高深莫测的网络流算法，现在已飞入寻常百姓家了，对于每一个OIER，网络流是一个神圣的东西（个人见解），但神圣的同时，它并不是那样抽象，最形象的模型就是水流，从长江源点无限的向外流水，而大海（汇点）则在不断地‘喝水’，当然，你也可以不把它想成水，或者是其他一切可以流动的东西。而事实上，有些东西的流动比较流畅，而某些东西可能相对而言比较粘稠，流速更慢，因此，就产生了一个问题，单位时间内的总流量最多多少，这里会根据流速给定单位时间内的流量，这就是最先开启网络流之门的最大流算法，它的解决方式将在后面谈到，再想一下，如果水管是另一个物流公司所有，那么你会根据从哪里运到哪里付出一定的代价， 为了你自己的利润，显然要找一个在运的东西最多的前提下有最小费用的方案，这就引出了下一个问题，最小费用最大流。再引用某牛一句话“当然也有有钱没处花的傻子，去求最大费用最大流”，而事实上，题目会出现这个模型，为了避免你成为傻瓜，现在你要给它一个新的定义：最大收益流，这时的你，变成了物流公司的经理，而客户的路线由你规划，为了你的钱包，最大收益必不可少。

 

正文

　第一部分.概念性问题(基本定理及定义)

        对于一些网络流新手来说，有必要知道一些基本定义和基本定理，这些虽然看起来理论价值不大，但是现在的许多网络流描述需要这些专业性的词语，所以还是　　有些了解为好。

       首先对于图G

       G 的流是一个实值函数 f， f (u, v) 表示顶点 u 到顶点 v 的流，它可以为正， 为零，也可以为负，且满足下列三个性质：

1.容量限制：对所有u, v ÎV ，要求 f (u, v) £ c(u, v) 。 反对称性：对所有u, v ÎV ，要求 f (u, v) =- f (v, u) 。

2.流守恒性：对所有u ÎV -{s, t} ，要求 å f (u, v) = 0 。

3.整个流网络 G 的流量 f = å f (s, v) 或 f= å f (u, t) 。

接下来定义各种算法中都要用到的一些东东：

1.残留网络

给定一个流网络G = (V , E) 和流 f，由 f 压得的 G 的残留网络Gf= (V , E f ) ，定义 c f (u, v) 为残留网络G f  中边 (u, v) 的容量。如果弧 (u, v) Î E 或弧 (v, u) Î E ，则 弧 (u, v) Î E f ，且 c f (u, v) = c(u, v) - f (u, v) 。

  残留网络又被称为剩余图。

2.点的高度和层次，这是两个相对的概念，高度的定义为到汇点的最短路径长度，而层次则是指到源点的最短路径长度（这里的路径长度按照各个边的长度都为1算），这两个量是在最大流算法中贯穿始末的利器。

接下来引入最大流最小割定理

 对了，可能有同学还不知道什么是最小割，在这里提一下

 流网络 G = (V , E) 的割 (S ,T ) 将V 划分成 S 和T = V - S 两部分，使得 s Î S ，t ÎT 。定义割 (S ,T ) 的容量为 c(S ,T ),

  对 于 最 小 的 c ， 它 是 最 小 割 。

3.  最 大 流 最 小 割 定 理

 　　 在 流 网  络 中，最 小 割 的 容 量 等 于 最 大 流 的 流 量 。（证 明 再 次 略 过 ）

 

   第二部分.最大流的算法

下面步入与实际问题更加接近的算法实现部分，首先给出问题，给定一个流网络，求源到汇在单位时间内的最大流量。

最简单而效率较好的算法 是基于增广路的算法，这类算法在王欣上大牛的论文中有详细介绍，但我仍然想谈谈我的想法，希望能起到抛砖引玉的作用。基于增广路的算法主要有两种:MPLA,Dinic,SAP.其中最简单的是MPLA,最实用最简洁也是最多人用的是Dinia,SAP的范围也很广，加上GAP优化后的效率也让人咋舌，这也是最近SAP大泛滥的原因吧！个人比较喜欢Dinic，数据变态就用最高标号预流推进，SAP用的比较少，当然，用什么算法还是看你自己的感觉吧。有些人认为增广路算法格式低效，于是想出了对于每个节点操作的算法，这类算法以预留推进为顶梁柱，MPM也勉强归入这一类吧。

 

1.MPLA算法

即最短路径增值算法，可以有一个简单的思想，每次都找一条从源到汇的路径来增广，直到不能增广为止，之中算法的正确性是可以保证的，但效率不尽如人意，有些时候，把事情格式化反而有益，这里的MPLA就是这样，它只在层次图中找增广路，构建出层次图之后，用BFS不断增广，直到当前层次图中不再有增广路，再重新构建层次图，如果汇点不在层次图内，则源汇不再连通，最大流已经求出，否则继续执行增广，如此反复，就可以求出最大流，在程序实现时层次图不用被构建出来，只需要BFS出各点的距离标号，找路径时判断对于f(u,v)是否有d[u]+1=d[v]即可。

如果每建一次层次图成为一个阶段，则在最短路径增值算法中，最多有N个阶段，证明再次略过。

因此在整个算法中，最多有N个阶段，每个阶段构建层次图的BFS时间复杂度为O(m),建N次，因此构建层次图的总时间为O(mn),而在增广过程中，每一次增广至少删除一条边，因此增广m次，加上修改流量的时间，每一阶段的增广时间为O(m*(m+n)),共有N个阶段，所以复杂度为O(n*m*(m+n))=O(nm^2),这也是该算法的时间复杂度。

 

2.Dinic算法

MPLA虽然简单，但经常会点超时，我们把增广过程中的BFS改成DFS，效率会有比较大的提高么？答案是肯定的，至此我们已经得到了Dinic的算法流程，只是将MPLA的增广改为DFS，就能写出那美妙的Dinic了，同样，分析一下时间，在DFS过程中，会有前进和后退两种情况，最多前进后退N次，而增广路最多找M次，再加上N个阶段，所以Dinic的复杂度就是O(mn^2)，事实上，它也确实比MPLA快很多，简洁而比较高效，这也是许多OIER选择Dinic的理由了吧，毕竟，写它可能会节省出较长时间来完成其他题目.

 2  program dinic(input,output);
 var
    f           : array[0..1000,0..1000] of longint;
    number      : array[0..1000] of longint;
    q           : array[0..10000] of longint;
    n,m,ans,s,t : longint;
 procedure init;
 var
    x,y,c : longint;
    i     : longint;
 begin
    readln(m,n);
    s:=1;
    t:=n;
    fillchar(f,sizeof(f),0);
    for i:=1 to m do
    begin
       readln(x,y,c);
       inc(f[x,y],c);
    end;
 end; { init }
 function min(aa,bb :longint ):longint;
 begin
    if aa<bb then
       exit(aa);
    exit(bb);
 end; { min }
 function bfs(): boolean;
 var
    head,tail : longint;
    now,i     : longint;
 begin
    fillchar(number,sizeof(number),0);
    head:=0;
    tail:=1;
    q[1]:=s;
    number[s]:=1;
    while head<tail do
    begin
       inc(head);
       now:=q[head];
       for i:=1 to n do
      if f[now,i]>0 then
         if number[i]=0 then
         begin
            number[i]:=number[now]+1;
            inc(tail);
            q[tail]:=i;
         end;
    end;
    if number[t]=0 then
       exit(false);
    exit(true);
 end; { bfs }
 function dfs(now,flow :longint ):longint;
 var
    tmp,i : longint;
 begin
    if now=t then
       exit(flow);
    for i:=1 to n do
       if number[i]=number[now]+1 then
      if f[now,i]>0 then
      begin
         tmp:=dfs(i,min(flow,f[now,i]));
         if tmp<>0 then
         begin
            inc(f[i,now],tmp);
            dec(f[now,i],tmp);
            exit(tmp);
         end;
      end;
    exit(0);
 end; { dfs }
 procedure main;
 var
    tmp : longint;
 begin
    ans:=0;
    while bfs() do
    begin
       tmp:=dfs(s,maxlongint>>2);
       while tmp<>0 do
       begin
      inc(ans,tmp);
      tmp:=dfs(s,maxlongint>>2);
       end;
    end;
    writeln(ans);
 end; { main }
 begin
    init;
    main;
 end.

3.SAP算法

    SAP也是找最短路径来增广的算法，有这样一句话：SAP算法更易理解，实现更简单，效率更高，而也有测试表明，SAP加上重要的GAP优化后，效率仅次于最高标号预流推进算法，因此如果你想背一个模板，SAP是最佳选择。SAP在增光时充分的利用了以前的信息，当按照高度找不到增广路时，它会对节点重新标号，h[i]=min{h[j]}+1(c[i,j]>0)，这也是SAP比较核心的思想，而根据这个我们可以发现，当高度出现间隙时，一定不会存在增广路了，算法已经可以结束，因此，这里引入间隙优化(GAP),即出现间隙时结束算法。

    在算法实现中，初始标号可以全部置为0，在增广过程中在逐渐提升高度，时间上可能会有常数的增加，但不改变渐进时间复杂度。同时为了简洁，SAP实现时用递归，代码不过80行左右。

View Code 
 program sap(input,output);
 var
    c        : array[0..1000,0..1000] of longint;
    h,vh        : array[0..1000] of longint;
    flow,n,m,ans    : longint;
    tmpflow    : longint;
    can        : boolean;
 procedure init;
 var
    i,j        : longint;
    xx,yy,cc : longint;
 begin
    fillchar(c,sizeof(c),0);
    fillchar(h,sizeof(h),0);
    ans:=0;
    readln(m,n);
    for i:=1 to m do
    begin
       readln(xx,yy,cc);
       inc(c[xx,yy],cc);
    end;
 end; { init }
 procedure dfs(now : longint );
 var
    min,tmp : longint;
    i       : longint;
 begin
    min:=n-1;
    tmp:=tmpflow;
    if now=n then
    begin
       can:=true;
       inc(ans,tmpflow);
       exit;
    end;
    for i:=1 to n do
       if c[now,i]>0 then
       begin
      if h[i]+1=h[now] then
      begin
         if c[now,i]<tmpflow then
            tmpflow:=c[now,i];
         dfs(i);
         if h[1]>=n then
            exit;
         if can then
            break;
         tmpflow:=tmp;
      end;
      if h[i]<min then
         min:=h[i];
       end;
    if not can then
    begin
       dec(vh[h[now]]);
       if vh[h[now]]=0 then
      h[1]:=n;
       h[now]:=min+1;
       inc(vh[h[now]]);
    end
    else
    begin
       dec(c[now,i],tmpflow);
       inc(c[i,now],tmpflow);
    end;
 end; { dfs }
 begin
    init;
    fillchar(vh,sizeof(vh),0);
    vh[0]:=n;
    while h[1]<n do
    begin
       tmpflow:=maxlongint>>2;;
       can:=false;
       dfs(1);
    end;
    writeln(ans);
 end.

4.MPM算法

    这个算法我还没有实践过，因为它的实现过程比较繁琐，而且时间效率不高，是一个只具有理论价值的算法，这个算法每次都处理单独节点，记每个节点入流和与出流和的最小值作为thoughput(now)（定义在非源汇点），每次先从now向汇推大小为thoughput(now)的流量，在从点now向源点拉大小为thoughput(now)的流量，删除该节点，继续执行直到图中只剩下源汇。时间复杂度为O(n^3)，但时间常数较大，时间效率不高。

5.预留推进算法

    以上的算法中，基本上都需要从大体上来把握全局，而预留推进算法则是将每一个顶点看作了一个战场，分别对他们进行处理，在处理过程中，存在某些时间不满足流量收支平衡，所以对预先推出的流叫做预流，下面来看算法如何将预流变成最大流的。

    预留推进算法有两个主过程，push和relabel，即推进和重标号，它是在模拟水流的过程，一开始先让源的出弧全部饱和，之后随着时间的推移，不断改变顶点的高度，而又规定水流仅能从高处流向低处，所以在模拟过程中，最终会有水流入汇，而之前推出的多余的水则流回了源，那么我们每次处理的是什么节点呢？把当前节点内存有水的节点称为活跃节点，每次对活跃节点执行推流操作，直到该节点不再活跃，如果不能再推流而当前节点仍未活跃节点，就需要对它进行重新标号了，标号后再继续推流，如此重复，直到网络中不再存在活跃节点为止，这时源的流出量就是该网络的最大流。注意，对于活跃节点的定义，不包括源汇，否则你会死的很惨。

    朴素的预留推进的效率还过得去，最多进行nm次饱和推进和n^2m次不饱和推进，因此总的时间复杂度为O(mn^2)

    事实上，如同增广路算法引入层次图一样，定下一些规则，可以让预留推进算法有更好的时间效率，下面介绍相对而言比较好实现的FIFO预留推进算法，它用一个队列来保存活跃节点，每次从队首取出一个节点进行推进，对一个节点relabel之后把它加到队尾，如此执行，直到队列为空，这样一来，预留推进算法的时间复杂度降为O(n^3),实现的时候，可以加上同样的间隙优化，但注意，出现间隙时不要马上退出，将新标号的的高度置为n+1，继续执行程序，这样会让所有的剩水流回源，满足流量收支平衡，以便最后的统计工作。

View Code 
 program preflow(input,output);
 var
    f,c        : array[0..2000,0..2000] of longint;
    q,h,vh,e : array[0..2000] of longint;
    m,n,s,t  : longint;
    flow        : longint;
 procedure init;
 var
    i,j        : longint;
    xx,yy,cc : longint;
 begin
    readln(m,n);
    fillchar(f,sizeof(f),0);
    fillchar(c,sizeof(c),0);
    fillchar(e,sizeof(e),0);
    for i:=1 to m do
    begin
       readln(xx,yy,cc);
       inc(c[xx,yy],cc);
    end;
    s:=1;
    t:=n;
 end; { init }
 procedure main;
 var
    i,j        : longint;
    head,tail    : longint;
    now,tmp,tmph    : longint;
 begin
    flow:=0;
    h[s]:=n;
    head:=0;
    tail:=0;
    for i:=1 to n do
    begin
       e[i]:=c[s,i];
       f[s,i]:=c[s,i];
       f[i,s]:=-f[s,i];
       if (e[i]>0)and(i<>t) then
       begin
      inc(tail);
      q[tail]:=i;
      inc(vh[h[i]]);
       end;
    end;
    while head<tail do
    begin
       inc(head);
       now:=q[head];
       for i:=1 to n do
      if (c[now,i]>f[now,i])and(h[now]=h[i]+1)and(e[now]>0) then
      begin
         tmp:=c[now,i]-f[now,i];
         if tmp>e[now] then
            tmp:=e[now];
         inc(f[now,i],tmp);
         dec(f[i,now],tmp);
         dec(e[now],tmp);
         inc(e[i],tmp);
         if (e[i]=tmp)and(i<>s)and(i<>t) then
         begin
            inc(tail);
            q[tail]:=i;
         end;
      end;
       if (e[now]>0)and(now<>s)and(now<>t) then
       begin
      tmph:=h[now];
      dec(vh[tmph]);
      h[now]:=$FFFF;
      for i:=1 to n do
         if (c[now,i]>f[now,i])and(h[now]>h[i]+1) then
            h[now]:=h[i]+1;
      inc(tail);
      q[tail]:=now;
      inc(vh[h[now]]);
      if vh[tmph]=0 then
         for i:=1 to n do
            if (h[i]>tmph)and(h[i]<n) then
            begin
           dec(vh[h[i]]);
           h[i]:=n;
           inc(vh[n]);
            end;
       end;
    end;
    flow:=0;
    for i:=1 to n do
       inc(flow,f[s,i]);
 end; { main }
 begin
    init;
    main;
    writeln(flow);
 end.

    下面介绍最后一个，也是编程难度最大，时间表现不同凡响的算法，最高标号预流推进，它的思想是既然水是从高处向低处流的，那么如果从低处开始会做许多重复工作，不如从最高点开始流，留一次就解决问题。再直观一些，引用黑书上的话“让少数的节点聚集大量的盈余，然后通过对这些节点的检查把非饱和推进变成一串连续的饱和推进”。在程序现实现时，用一个表list来储存所有的活跃节点，其中list(h)存储高的为h的活跃节点，同时记录一个level,为最高标号，每次查找时依次从level,level-1……查找，直到找到节点为止，这时从表内删掉这个节点，对它进行Push,Relabel操作，直到该节点不再活跃，继续进行，直到表内不在存在活跃节点。

     它的复杂度为O(n^2*m^(1/2)),时间效率很优秀（当然，如果你刻意构造卡预留推进的数据，它比MPLA还慢也是有可能的）。

View Code 
 program hign_node_flow(input,output);
 var
    c       : array[0..1000,0..1000] of longint;  {保存原图}
    f       : array[0..1000,0..1000] of longint;  {保存当前的预流图}
    h       : array[0..1000] of longint;  {保存各个节点当前高度}
    vh       : array[0..1000] of longint;  {保存各个高度节点的数量}
    e       : array[0..1100] of longint;  {保存各个节点的盈余}
    level   : longint;  {当前所有活跃节点的最高高度}
    l       : array[0..1000,0..1000] of longint;  {保存活跃节点的表,l[i,0]表示高度为i的活跃节点数，这也是不能用vh数组的原因}
    n,m,s,t : longint;  {节点数，边数，源，汇}
    listsum : longint;  {记录当前在表内的元素个数}
    flow       : longint; {记录流量}
    inlist  : array[0..1000] of boolean;  {节点是否在表内}
    q       : array[0..10000] of longint;  {用于BFS扩展的队列}
 procedure init;
 var
    i,xx,yy,cc : longint;
 begin
    readln(m,n);
    fillchar(f,sizeof(f),0);
    fillchar(c,sizeof(c),0);
    fillchar(e,sizeof(e),0);
    fillchar(h,sizeof(h),0);
    fillchar(vh,sizeof(vh),0);
    for i:=1 to m do
    begin
       readln(xx,yy,cc);
       inc(c[xx,yy],cc);{注意某些情况下有重边，这样处理比较保险}
    end;
    s:=1;
    t:=n;
 end; { init }
 procedure insect(now :longint );  {在活跃节点表内插入节点now}
 begin
    inlist[now]:=true; {标记now节点在表内}
    inc(listsum); {表中元素增加1}
    inc(l[h[now],0]); {高度为h[now]的活跃节点数增加1}
    l[h[now],l[h[now],0]]:=now; {表中高度为h[now]的第l[h[now],0]个活跃节点为now}
    if h[now]>level then {更新活跃节点最高高度}
       level:=h[now];
 end; { insect }  
 procedure bfs(); {利用BFS(反向的)，求的各个节点的高度}
 var
    head,tail,i : longint;
 begin
    head:=0;
    tail:=1;
    q[1]:=t;
    h[t]:=1; {汇点的高度为1}
    while head<tail do
    begin
       inc(head);
       for i:=1 to n do
      if c[i,q[head]]>0 then  {存在边}
         if h[i]=0 then {i节点高度没有求出}
         begin
            h[i]:=h[q[head]]+1; {求的节点i的高度}
            inc(tail);
            q[tail]:=i;
         end;
    end;
 end; { bfs }
 procedure previous(); {预流推进的预处理}
 var
    i : longint;
 begin
    for i:=1 to n do
    begin
       e[i]:=c[s,i]; {让源点的出弧饱和，则弧的指向点的盈余要改变}
       f[s,i]:=c[s,i]; {源点出弧饱和}
       f[i,s]:=-f[s,i]; {反向弧的处理}
       if (e[i]>0)and(i<>t)and(not inlist[i]) then {节点i成为活跃节点,且不是汇点，没有在表内(其实也不可能在表内)}
      insect(i);
    end;
    h[1]:=n;
    for i:=1 to n-1 do
       inc(vh[h[i]]);
 end; { previous }
 function find(level :longint ):longint; {传入当前活跃节点集合的最高高度}
 var
    i : longint;
 begin
    for i:=level downto 1 do {枚举节点集合}
       if l[i,0]<>0 then {存在节点}
       begin
      find:=l[i,l[i,0]]; {返回表的尾元素}
      inlist[l[i,l[i,0]]]:=false; {返回节点不再表内}
      dec(l[i,0]);
      dec(listsum); {表中元素个数减一}
      while (l[level,0]=0)and(level>0) do {更新level的值}
         dec(level);
      exit;
       end;
    exit(0); {没有找到节点就返回0}
 end; { find }
 procedure push(now :longint ); {推流操作}
 var
    i   : longint;
    tmp : longint;
 begin
    for i:=1 to n do
       if (c[now,i]>f[now,i])and(h[now]=h[i]+1)and(e[now]>0) then {如果当前节点有盈余且有出弧不饱和}
       begin
      tmp:=c[now,i]-f[now,i]; {tmp记录对弧而言能增广的量}
      if tmp>e[now] then {这里能增广的量=min(tmp,盈余)}
         tmp:=e[now];
      inc(f[now,i],tmp); {增广操作}
      dec(f[i,now],tmp);
      inc(e[i],tmp); {修改节点盈余}
      dec(e[now],tmp);
      if (not inlist[i])and(e[i]=tmp)and(i<>t) then {接受流的节点一定成为活跃节点且不再表内，又不是汇点}
         insect(i);
       end;
 end; { push }
 procedure relable(now : longint ); {重新标号}
 var
    i    : longint;
    tmph    : longint;
 begin
    tmph:=h[now];  {tmph保存未重新标号前now节点的高度}
    dec(vh[tmph]);  {高度为h[now]的节点数减一}
    h[now]:=$ffff;  {高度要取min(j)c[now,j]>0,则先赋值最大}
    for i:=1 to n do
       if (c[now,i]>f[now,i])and(h[now]>h[i]+1) then 
      h[now]:=h[i]+1;   {更新标号的过程}
    inc(vh[h[now]]); {新产生节点的高度记录进去}
    if vh[tmph]=0 then  {GAP优化，如果存在间隙，则最大流已求出}
       for i:=1 to n do  
      if (h[i]>tmph)and(h[i]<n) then {让各个节点均抬高到n}
      begin
         dec(vh[h[i]]);
         h[i]:=n;
         inc(vh[n]);
      end;      {不能直接退出，否则会无限执行且不满足流量平衡}
    if (now<>s)and(now<>t) then
       insect(now);{now经过PUSH过程已经不再活跃节点内了，且一定有盈余,但一定要保证now不是源，汇}
 end; { ralable }
 procedure main;
 var
    tmp : longint;
 begin
    while listsum<>0 do {当表中存在活跃节点时}
    begin
       tmp:=find(level); {找到最高标号点}
       push(tmp); {推进}
       if e[tmp]>0 then {如果推进后该节点还有盈余}
      relable(tmp); {重新标号该节点}
    end;
 end; { main }
 procedure print;
 var
    i : longint;
 begin
    flow:=0;
    for i:=1 to n do {累加源的出流量}
       inc(flow,f[s,i]);
    writeln(flow);
 end; { print }
 begin
    init;
    bfs();
    previous;
    main;
    print;
 end.

小结：

网络流的最大流算法种类繁多，时间效率编程复杂度也不尽相同，对于不同的流网络，选择相应的算法，需要在不断实践中摸索，这也是一个菜鸟到大牛的必经之路。在一般题目中，选用Dinic是一个不错的想法，但当我们发现网络特别稠密时，FIFO的预留推进算法就要派上用场了，而时间比较紧但题目数据弱，我们甚至可以采用搜索找增广路的算法。

提供最大流测试网址：http://hzoi.openjudge.cn/never/1003/

 

 

     第三部分  最小费用最大流问题

 学习了网络流的最大流算法，一定有一种十分兴奋的感觉，那么，就让你借着这股兴奋劲儿，来学习这一章的最小费用流吧。

最小费用流有两种经典的算法，一种是消圈算法，另一种则是最小费用路增广算法。

第一种，消圈算法。如果在一个流网络中求出了一个最大流，但对于一条增广路上的某两个点之间有负权路，那么这个流一定不是最小费用最大流，因为我们可以让一部分流从这条最小费用路流过以减少费用，所以根据这个思想，可以先求出一个最大初始流，然后不断地通过负圈分流以减少费用，直到流网络中不存在负圈为止。

消圈算法的时间复杂度上限为O(nm^2cw),其中c是最大流量，w为非用最大值，而按特定的顺序消圈的时间复杂度为O(nm^2logn)。这里的时间复杂度分析是按照用bellman-ford算法消圈得到的，用SPFA应该可以得到更优的实际运行时间。

第二种，最小费用路增广算法。这里运用了贪心的思想，每次就直接去找s到t的最小费用路来增广，这样得到的结果一定是最小费用，实现较简单，时间复杂度O(mnv)，v为最大流量。用SPFA效果极好，但鉴于SPFA的不确定性，有时为了保险，往往运用重新加权技术，具体实践请通过网络或其他途径获得。

最小费用流的东西并不多，事实上是使用最短路径这种特殊的网络流解决了普遍的网络流问题，只要掌握好基础，程序不难写出。

View Code 
 program minflow(input,output);
 var
    f         : array[0..501,0..501] of longint;
    c         : array[0..501,0..501] of longint;
    min,pre,d : array[0..1000] of longint;
    q         : array[0..2000] of longint;
    v         : array[0..501] of boolean;
    m,n,s,t   : longint;
 procedure init;
 var
    xx,yy,cc,dd : longint;
    i           : longint;
 begin
    readln(n,m);
    fillchar(f,sizeof(f),63);
    fillchar(c,sizeof(c),0);
    for i:=1 to n do
       f[i,i]:=0;
    for i:=1 to m do
    begin
       readln(xx,yy,cc,dd);
       f[xx,yy]:=dd;
       c[xx,yy]:=cc;
       f[yy,xx]:=-dd;
    end;
    s:=1;
    t:=n;
 end; { init }
 function argument():boolean;
 var
    head,tail : longint;
    i,now     : longint;
 begin
    for i:=1 to n do
       d[i]:=maxlongint>>2;
    fillchar(v,sizeof(v),false);
    fillchar(min,sizeof(min),63);
    head:=0;
    tail:=1;
    q[1]:=s;
    v[1]:=true;
    d[1]:=0;
    while head<tail do
    begin
       inc(head);
       v[q[head]]:=false;
       now:=q[head];
       for i:=1 to n do
      if c[now,i]<>0 then
      begin
         if d[now]+f[now,i]<d[i] then
         begin
            d[i]:=d[now]+f[now,i];
            pre[i]:=now;
            if c[now,i]<min[now] then
           min[i]:=c[now,i]
            else
           min[i]:=min[now];
            if not v[i] then
            begin
           inc(tail);
           q[tail]:=i;
           v[i]:=true;
            end;
         end;
      end;
    end;
    if d[t]=maxlongint>>2 then
       exit(false);
    now:=t;
    while now<>s do
    begin
       dec(c[pre[now],now],min[t]);
       inc(c[now,pre[now]],min[t]);
       now:=pre[now];
    end;
 end; { argument }
 procedure main;
 var
    ans : longint;
 begin
    ans:=0;
    while argument() do
       inc(ans,min[t]*d[t]);
    writeln(ans);
 end; { main }
 begin
    init;
    main;
 end.

 

           第四部分  网络流算法的应用

一．  最大流问题。

一般情况下，比较裸的最大流几乎不存在，网络流这种东西考得就是你的构图能力，要不然大家背一背基本算法就都满分了，下面介绍一道比较典型的最大流问题。

   问题一：最小路径覆盖问题。

   题目链接：http://hzoi.openjudge.cn/never/1004/

   最小路径覆盖=|P|－最大匹配数

   而最大匹配数可以用匈牙利，也可以用最大流，而两者在这特殊的图中，效率是相同的，而一旦题目有一些变化，网络流可以改改继续用，而匈牙利的局限性较大。

   问题二：奶牛航班。

   Usaco的赛题，以飞机上的座位作为流量限制，通过实际模型的构建，最终运用最大流算法解决，详解可参考国家集训队论文，具体哪年的忘记了，囧。

  最大流实在难已以找到比较有意思的题目，下面进入应用最广泛的最小费用流吧！

 

二.最小费用流问题（最大收益流问题）

这个问题的模型很多下面就此解析几道例题。

   问题一：N方格取数

   在一个有m*n 个方格的棋盘中，每个方格中有一个正整数。现要从方格中取数，使任意2 个数所在方格没有公共边，且取出的数的总和最大。

   解析：这是一个二分图最大点权独立集问题，就是找出图中一些点，使得这些点之间没有边相连，这些点的权值之和最大。独立集与覆盖集是互补的，求最大点权独立集可以转化为求最小点权覆盖集（最小点权支配集）。最小点权覆盖集问题可以转化为最小割问题解决。

   结论:最大点权独立集 = 所有点权 - 最小点权覆盖集 = 所有点权 - 最小割集 = 所有点权 - 网络最大流。

   问题还有许多，可以参考网上的网络流与线性规划24题，里面题目比较全面（虽然好多根本用不到网络流）。

最后再提一道题目，说一下最小割的转化建模。

The last问题：黑手党

题目大意：要用最少的人数来切断从A到B的所有路径，每个人只能切断一条边。

分析：显然是一个从A到B的最小割问题，由最大流最小割定理，求A到B 的最大流即可。

结论：网络流问题博大精深，难点在构图，这是一种能力，需要逐渐培养。

 

总结：关于网络流的介绍到这里也就结束了，但是网络流绝不是仅仅这点东西的，由于个人水平问题，出错或片面的地方还请大牛指正。

 

参考资料：

[1].国家集训队论文2007 王欣上，浅谈基于分层思想的网络流算法。

[2].国家集训队论文2002，江鹏，从一道题目的解法试坛网络流的构造与算法。

[3].算法艺术与信息学竞赛，刘汝佳，黄亮。

 

[转] http://www.cnblogs.com/neverforget/archive/2011/10/20/2210785.html

 

-----------

注：预留推进算法Gap优化：

若发现存在某个高度t<|V|，使得没有任何点的高

  度为t，则可以把所有高度在( t, |V| ]之间的点的高度

  全部提升到|V|+1