前言
在学习、分析之前首先要弄明白一个问题：为什么要分析启动代码？
因为启动代码绝大部分都是用汇编语言写的，对于没学过或者不熟悉汇编语言的同学确实有一定难度，但是如果你想真正深入地学习Linux，那么读、分析某一个体系结构（比如ARM）的启动代码或者其他底层代码是必不可少的。当分析之后会发现这是有很多好处的：分析启动代码可以加深对汇编语言的理解；可以学习汇编语言的使用技巧；可以学习如何编写位置无关的代码，可以知道从启动到start_kernel()函数之前内核到底干了什么事情，从而为后续其他内核子系统的学习打下基础。
废话不多说，下面基于s3c6410，以Linux-2.6.36版本为基础进行分析。ARM Linux的启动代码有两处，一处是经过压缩的，一处是没有经过压缩的，压缩的最终还是会调用没有压缩的，没有压缩的入口在arch/arm/kernel/head.S文件中，如下所示：
00000077 __HEAD 00000078 ENTRY(stext) 00000079 setmode PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9 @ ensure svc mode 00000080 @ and irqs disabled 00000081 mrc p15, 0, r9, c0, c0 @ get processor id 00000082 bl __lookup_processor_type @ r5=procinfo r9=cpuid 00000083 movs r10, r5 @ invalid processor (r5=0)? 00000084 beq __error_p @ yes, error 'p' 00000085 bl __lookup_machine_type @ r5=machinfo 00000086 movs r8, r5 @ invalid machine (r5=0)? 00000087 beq __error_a @ yes, error 'a' 00000088 bl __vet_atags 00000089 bl __create_page_tables 00000090 00000091 /* 00000092 * The following calls CPU specific code in a position independent 00000093 * manner. See arch/arm/mm/proc-*.S for details. r10 = base of 00000094 * xxx_proc_info structure selected by __lookup_machine_type 00000095 * above. On return, the CPU will be ready for the MMU to be 00000096 * turned on, and r0 will hold the CPU control register value. 00000097 */ 00000098 ldr r13, __switch_data @ address to jump to after 00000099 @ mmu has been enabled 00000100 adr lr, BSYM(__enable_mmu) @ return (PIC) address 00000101 ARM( add pc, r10, #PROCINFO_INITFUNC ) 00000102 THUMB( add r12, r10, #PROCINFO_INITFUNC ) 00000103 THUMB( mov pc, r12 ) 00000104 ENDPROC(stext)
79行就是要分析的第一行代码，设置CPU为管理模式，这也是CPU一上电所处的模式，关闭CPU普通中断和CPU快速中断。
81行，读协处理器p15获取CPU ID，结果存在r9寄存器里，待会会用到。
82行，跳转到__lookup_processor_type标号处，在arch/arm/kernel/head-common.S文件里定义：
00000160 __lookup_processor_type: 00000161 adr r3, 3f 00000162 ldmia r3, {r5 - r7} 00000163 add r3, r3, #8 00000164 sub r3, r3, r7 @ get offset between virt&phys 00000165 add r5, r5, r3 @ convert virt addresses to 00000166 add r6, r6, r3 @ physical address space 00000167 1: ldmia r5, {r3, r4} @ value, mask 00000168 and r4, r4, r9 @ mask wanted bits 00000169 teq r3, r4 00000170 beq 2f 00000171 add r5, r5, #PROC_INFO_SZ @ sizeof(proc_info_list) 00000172 cmp r5, r6 00000173 blo 1b 00000174 mov r5, #0 @ unknown processor 00000175 2: mov pc, lr 00000176 ENDPROC(__lookup_processor_type) …… 00000193 .align 2 00000194 3: .long __proc_info_begin 00000195 .long __proc_info_end 00000196 4: .long . 00000197 .long __arch_info_begin 00000198 .long __arch_info_end
在汇编语言中，标号代表的是地址，准确来说是链接地址。adr和ldr都是伪指令，它们两者的作用都是将标号处所代表的地址存放到寄存器中。但是adr采用基于PC值的相对地址（PC+偏移值），而ldr采用的是绝对地址（直接采用标号的值），另外adr要求指令与标号位于同一个段中。
161行，因此当前PC值是存放的是一个物理地址，为什么是物理地址？为了搞清楚这个问题，下面简单说说上一个“年代”的bootloader是怎么引导、启动内核的，主要的流程如下：
（1）上电
（2）必要的设置
（3）关看门狗
（4）初始化SDRAM、初始化Nand Flash
（5）把bootloader拷贝到SDRAM的高处
（6）清BSS段
（7）跳到SDRAM继续执行
（8）把Nand Flash中的内核Image拷贝到SDRAM（0x50008000）
（9）设置启动参数，r0、r1等寄存器，关闭MMU、cache等
（10）跳到内核Image的起始处（0x50008000）执行，此后，bootloader时代一去不复返，进入Linux新时代。
现在应该知道执行到161行时，PC的值就为0x50000000~0x58000000之间的某一个值（假定内存为128MB，s3c6410物理内存的起始地址为0x50000000），即一物理地址，因此r3的值就为194行的标号3处的物理地址。
162行，分别将r3、r3+4、r3+8地址上的内容存放到r5、r6、r7寄存器中，即r5存放的是__proc_info_begin的值（是一个链接地址，或者说虚拟地址），r6存放的是__proc_info_end的值（是一个链接地址，或者说虚拟地址），因为 . 表示的是当前的链接地址，所以r7存放的是标号4的链接地址，这跟LD链接脚本里的 . 表示的意思是一样的。
163行，将r3的值加8，即现在r3的值为196行的标号4的物理地址。
164行，r3 = r3 – r7，即r3 = 标号4的物理地址 - 标号4的虚拟地址，这样就可以计算出物理地址和虚拟地址的偏移量，显然r3的值为一负数。
165行，结果为r5 = __proc_info_begin的物理地址。
166行，结果为r6 = __proc_info_end的物理地址。
167行，取出struct proc_info_list结构体的前两个成员的值分别放到r3、r4。struct proc_info_list结构体的定义如下：
struct proc_info_list { unsigned int cpu_val; unsigned int cpu_mask; unsigned long __cpu_mm_mmu_flags; /* used by head.S */ unsigned long __cpu_io_mmu_flags; /* used by head.S */ unsigned long __cpu_flush; /* used by head.S */ const char *arch_name; const char *elf_name; unsigned int elf_hwcap; const char *cpu_name; struct processor *proc; struct cpu_tlb_fns *tlb; struct cpu_user_fns *user; struct cpu_cache_fns *cache; };
每一种体系结构都有一个这样的结构体变量，对于s3c6410,来说，它属于ARMv6体系结构，它的struct proc_info_list变量在arch/arm/mm/proc-v6.S中定义，在链接的时候所有这些变量都被放在__proc_info_begin和__proc_info_end之间。因此，167行执行后，r3 = cpu_val，r4 = cpu_mask。
168行，将r4的值与r9的值相与，得到的CPU ID存在r4中。
169行，比较r4与r3的值。
170行，如果r4=r3，那么跳到175行处执行，即子程序返回。如果r4不等于r3，那么执行171行，将r5的值加上sizeof(struct proc_info_list)，即指向下一个struct proc_info_list变量。
172行，比较r5和r6。
173行，如果r5小于r6，则跳转到167行，重复上面的过程。如果所有struct proc_info_list变量都比较后都没有找到对应的CPU ID，那么执行174行，r5 = 0，然后返回。
至此，__lookup_processor_type分析完毕，回到head.S的83行，把r5的值赋给r10，并影响标志位。
84行，如果r5=0，那么跳转到__error_p标号。这里假设内核是支持当前CPU的，即r5不为0，因此不分析__error_p的内容。
85行，跳到__lookup_machine_type标号处，同样是在arch/arm/kernel/head-common.S中定义：
00000196 4: .long . 00000197 .long __arch_info_begin 00000198 .long __arch_info_end 00000211 __lookup_machine_type: 00000212 adr r3, 4b 00000213 ldmia r3, {r4, r5, r6} 00000214 sub r3, r3, r4 @ get offset between virt&phys 00000215 add r5, r5, r3 @ convert virt addresses to 00000216 add r6, r6, r3 @ physical address space 00000217 1: ldr r3, [r5, #MACHINFO_TYPE] @ get machine type 00000218 teq r3, r1 @ matches loader number? 00000219 beq 2f @ found 00000220 add r5, r5, #SIZEOF_MACHINE_DESC @ next machine_desc 00000221 cmp r5, r6 00000222 blo 1b 00000223 mov r5, #0 @ unknown machine 00000224 2: mov pc, lr 00000225 ENDPROC(__lookup_machine_type)
和前面的__lookup_processor_type非常类似，只不过这里查找的是struct machine_desc结构体变量，比较的是struct machine_desc的成员nr的值，因此不再分析。这里需要提一下的是，比如对于mini6410（tiny6410），struct machine_desc变量的定义在arch/arm/mach-s3c64xx/mach-mini6410.c文件中，如下所示：
00000512 MACHINE_START(MINI6410, "MINI6410") 00000513 /* Maintainer: Ben Dooks <ben-linux@fluff.org> */ 00000514 .phys_io = S3C_PA_UART & 0xfff00000, 00000515 .io_pg_offst = (((u32)S3C_VA_UART) >> 18) & 0xfffc, 00000516 .boot_params = S3C64XX_PA_SDRAM + 0x100, 00000517 00000518 .init_irq = s3c6410_init_irq, 00000519 .map_io = mini6410_map_io, 00000520 .init_machine = mini6410_machine_init, 00000521 .timer = &s3c24xx_timer, 00000522 MACHINE_END
回到head.S，86、87行判断是否支持当前的机器号，不支持就跳到__error_a标号处。
88行，跳到__vet_atags，同样是在arch/arm/kernel/head-common.S中定义：
00000250 __vet_atags: 00000251 tst r2, #0x3 @ aligned? 00000252 bne 1f 00000253 00000254 ldr r5, [r2, #0] @ is first tag ATAG_CORE? 00000255 cmp r5, #ATAG_CORE_SIZE 00000256 cmpne r5, #ATAG_CORE_SIZE_EMPTY 00000257 bne 1f 00000258 ldr r5, [r2, #4] 00000259 ldr r6, =ATAG_CORE 00000260 cmp r5, r6 00000261 bne 1f 00000262 00000263 mov pc, lr @ atag pointer is ok 00000264 00000265 1: mov r2, #0 00000266 mov pc, lr 00000267 ENDPROC(__vet_atags)
251行，测试r2的低2位是否为0，也即r2的值是否4字节对齐。
252行，如果r2的低2位不为0，则跳转到265行，将r2的值设为0，然后返回。
下面先看一下bootloader传递参数给内核的结构定义，在arch/arm/include/asm/setup.h文件中：
00000146 struct tag { 00000147 struct tag_header hdr; 00000148 union { 00000149 struct tag_core core; 00000150 struct tag_mem32 mem; 00000151 struct tag_videotext videotext; 00000152 struct tag_ramdisk ramdisk; 00000153 struct tag_initrd initrd; 00000154 struct tag_serialnr serialnr; 00000155 struct tag_revision revision; 00000156 struct tag_videolfb videolfb; 00000157 struct tag_cmdline cmdline; 00000158 00000159 /* 00000160 * Acorn specific 00000161 */ 00000162 struct tag_acorn acorn; 00000163 00000164 /* 00000165 * DC21285 specific 00000166 */ 00000167 struct tag_memclk memclk; 00000168 } u; 00000169 };
147行，struct tag_header的定义：
00000024 struct tag_header { 00000025 __u32 size; 00000026 __u32 tag; 00000027 };
从struct tag的定义可以知道，bootloader传递的参数有好几种类型的tag，但是内核规定第一个tag必须是ATAG_CORE类型，最后一个必须是ATAG_NONE类型，每一种类型的tag都有一个编号，例如ATAG_CORE为0x54410001，ATAG_NONE为0x00000000。struct tag_header的tag成员就是用来描述tag的类型，而size成员用来描述整个tag的大小。每个tag连续存放。
那么标号__vet_atags的254行的意思就是获取ATAG_CORE类型tag的size成员的值赋给r5。
255行，将r5的值与ATAG_CORE_SIZE比较，ATAG_CORE_SIZE的值为((2*4 + 3*4) >> 2)，即5。
256行，如果255行比较的结果不相等，那么将r5与ATAG_CORE_SIZE_EMPTY进行比较，ATAG_CORE_SIZE_EMPTY的值为((2*4) >> 2)，即2。
257行，如果还是不相等，那么跳转到265行执行，同样是将r2设为0，然后返回。
258行，获取struct tag_header的tag成员，将它的值赋给r5。
259行，r6 = ATAG_CORE，即0x54410001。
260行，比较r5和r6的值。
261行，如果r5和r6的值不相等则跳转到265行，如果相等则执行263行直接返回。
至此，__vet_atags标号的内容分析完毕。
回到head.S的89行，跳转到__create_page_tables标号处，在head.S里定义：
00000219 __create_page_tables: 00000220 pgtbl r4 @ page table address 00000221 00000222 /* 00000223 * Clear the 16K level 1 swapper page table 00000224 */ 00000225 mov r0, r4 00000226 mov r3, #0 00000227 add r6, r0, #0x4000 00000228 1: str r3, [r0], #4 00000229 str r3, [r0], #4 00000230 str r3, [r0], #4 00000231 str r3, [r0], #4 00000232 teq r0, r6 00000233 bne 1b 00000234 00000235 ldr r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags 00000236 00000237 /* 00000238 * Create identity mapping for first MB of kernel to 00000239 * cater for the MMU enable. This identity mapping 00000240 * will be removed by paging_init(). We use our current program 00000241 * counter to determine corresponding section base address. 00000242 */ 00000243 mov r6, pc 00000244 mov r6, r6, lsr #20 @ start of kernel section 00000245 orr r3, r7, r6, lsl #20 @ flags + kernel base 00000246 str r3, [r4, r6, lsl #2] @ identity mapping 00000247 00000248 /* 00000249 * Now setup the pagetables for our kernel direct 00000250 * mapped region. 00000251 */ 00000252 add r0, r4, #(KERNEL_START & 0xff000000) >> 18 00000253 str r3, [r0, #(KERNEL_START & 0x00f00000) >> 18]! 00000254 ldr r6, =(KERNEL_END - 1) 00000255 add r0, r0, #4 00000256 add r6, r4, r6, lsr #18 00000257 1: cmp r0, r6 00000258 add r3, r3, #1 << 20 00000259 strls r3, [r0], #4 00000260 bls 1b 00000261 00000262 #ifdef CONFIG_XIP_KERNEL 00000263 /* 00000264 * Map some ram to cover our .data and .bss areas. 00000265 */ 00000266 orr r3, r7, #(KERNEL_RAM_PADDR & 0xff000000) 00000267 .if (KERNEL_RAM_PADDR & 0x00f00000) 00000268 orr r3, r3, #(KERNEL_RAM_PADDR & 0x00f00000) 00000269 .endif 00000270 add r0, r4, #(KERNEL_RAM_VADDR & 0xff000000) >> 18 00000271 str r3, [r0, #(KERNEL_RAM_VADDR & 0x00f00000) >> 18]! 00000272 ldr r6, =(_end - 1) 00000273 add r0, r0, #4 00000274 add r6, r4, r6, lsr #18 00000275 1: cmp r0, r6 00000276 add r3, r3, #1 << 20 00000277 strls r3, [r0], #4 00000278 bls 1b 00000279 #endif 00000280 00000281 /* 00000282 * Then map first 1MB of ram in case it contains our boot params. 00000283 */ 00000284 add r0, r4, #PAGE_OFFSET >> 18 00000285 orr r6, r7, #(PHYS_OFFSET & 0xff000000) 00000286 .if (PHYS_OFFSET & 0x00f00000) 00000287 orr r6, r6, #(PHYS_OFFSET & 0x00f00000) 00000288 .endif 00000289 str r6, [r0] 00000290 00000291 #ifdef CONFIG_DEBUG_LL 00000292 ldr r7, [r10, #PROCINFO_IO_MMUFLAGS] @ io_mmuflags 00000293 /* 00000294 * Map in IO space for serial debugging. 00000295 * This allows debug messages to be output 00000296 * via a serial console before paging_init. 00000297 */ 00000298 ldr r3, [r8, #MACHINFO_PGOFFIO] 00000299 add r0, r4, r3 00000300 rsb r3, r3, #0x4000 @ PTRS_PER_PGD*sizeof(long) 00000301 cmp r3, #0x0800 @ limit to 512MB 00000302 movhi r3, #0x0800 00000303 add r6, r0, r3 00000304 ldr r3, [r8, #MACHINFO_PHYSIO] 00000305 orr r3, r3, r7 00000306 1: str r3, [r0], #4 00000307 add r3, r3, #1 << 20 00000308 teq r0, r6 00000309 bne 1b 00000310 #if defined(CONFIG_ARCH_NETWINDER) || defined(CONFIG_ARCH_CATS) 00000311 /* 00000312 * If we're using the NetWinder or CATS, we also need to map 00000313 * in the 16550-type serial port for the debug messages 00000314 */ 00000315 add r0, r4, #0xff000000 >> 18 00000316 orr r3, r7, #0x7c000000 00000317 str r3, [r0] 00000318 #endif 00000319 #ifdef CONFIG_ARCH_RPC 00000320 /* 00000321 * Map in screen at 0x02000000 & SCREEN2_BASE 00000322 * Similar reasons here - for debug. This is 00000323 * only for Acorn RiscPC architectures. 00000324 */ 00000325 add r0, r4, #0x02000000 >> 18 00000326 orr r3, r7, #0x02000000 00000327 str r3, [r0] 00000328 add r0, r4, #0xd8000000 >> 18 00000329 str r3, [r0] 00000330 #endif 00000331 #endif 00000332 mov pc, lr 00000333 ENDPROC(__create_page_tables)
别看这个定义这么长，其实需要关注的代码并不多。
220行，pgtbl是一个宏，定义如下：
00000047 .macro pgtbl, rd 00000048 ldr d, =(KERNEL_RAM_PADDR - 0x4000) 00000049 .endm
就是将KERNEL_RAM_PADDR - 0x4000的值赋给r4，现在关键是KERNEL_RAM_PADDR的定义：
#define KERNEL_RAM_PADDR (PHYS_OFFSET + TEXT_OFFSET)
其中PHYS_OFFSET就是SDRAM的起始地址，对于s3c6410，它的值为0x50000000，TEXT_OFFSET在arch/arm/Makefile中定义：
00000222 TEXT_OFFSET := $(textofs-y) 00000240 export TEXT_OFFSET GZFLAGS MMUEXT
而textofs-y的定义为：
00000118 textofs-y := 0x00008000
因此KERNEL_RAM_PADDR的值就为0x50008000，而r4的值就为0x50004000。
225行，r0 = r4。
226行，r3 = 0。
227行，r6 = r0 + 0x4000，即0x50008000。
228到233行，将0x50004000开始到0x50008000这段内存清零。
235行，别忘了r10存的是struct proc_info_list变量的起始地址。这里将其__cpu_mm_mmu_flags成员的值赋给r7。
在分析下面的代码之前，先了解点预备知识。我们知道MMU的主要作用是将虚拟地址转换为物理地址，但是虚拟地址与物理地址的转换关系需要我们预先设置好（就是设置页表项），而转换的过程需要通过页表来完成。对于ARM来说，映射大体分为段映射和二级映射，段映射只需要一级页表，段映射的大小为1MB，二级映射需要两级页表。下面分析的代码都只用到段映射，因此只介绍段映射。
如图1所示（以ARM9为例），根据上面的分析可知，寄存器r4里存放的是一级页表的基地址，当启动MMU后，CPU发出的是虚拟地址（正确来说是修正后的虚拟地址，即MVA），然后MMU利用该地址的最高12位（MVA[31:20]）做为索引值，以一级页表基地址作为起始地址索引对应的页表项，当索引到相应的页表项后，根据页表项的内容找到对应的大小为1MB的起始物理地址，然后利用MVA的低20位（MVA[19:0]）索引确切的物理地址（精确到1个字节）。
图1 段映射
具体过程如图2所示，关键看图中的虚线部分，由于页表项的大小为4字节，因此最低两位为0，也即4字节对齐，根据虚线里的值就可以找到相应页表项的起始地址。从图中也可以知道页表基地址是16KB对齐的（最低14位为0）。
图2 获取一级描述符
有了上面的基础知识后就可以继续分析代码了。
243行，r6 = pc，保存当前PC的值。
244行，r6 = r6 >> 20。
245行，r3 = r7 | (r6 << 20)。此时，r3的值就是一个页表项的内容，也即段描述符。从这就可以知道244行的作用是清零r6的低20位。
246行，mem[r4 + r6 << 2] = r3，刚好与图2中的虚线部分对应。将r3的值存到页表相应的位置里，这样就完成了一个页表项的构建，也即完成了内核前1MB的映射。因为这里直接使用物理地址作为索引，所以虚拟地址与物理地址是直接映射关系，比如说虚拟地址0x50008000对应的物理地址也是0x50008000。后面会看到，这样做是为了开启MMU之后不用考虑太多的事情。
252行，r0 = r4 + (KERNEL_START & 0xff000000) >> 18，KERNEL_START的定义如下：
00000055 #define KERNEL_START KERNEL_RAM_VADDR
而KERNEL_RAM_VADDR的定义为：
00000029 #define KERNEL_RAM_VADDR (PAGE_OFFSET + TEXT_OFFSET)
PAGE_OFFSET的值板子对应的config文件里定义，这里为0xC0000000，因此KERNEL_START = 0xC0000000 + 0x00008000。
253行，mem[r0 + (KERNEL_START & 0x00f00000) >> 18] = r3和r0 = r0 + (KERNEL_START & 0x00f00000) >> 18。其实252行253行的意思就是mem[r4 + (0xC0008000 & 0xfff00000) >> 18] = r3，即将内核的前1MB映射到以0xC0008000为起始的虚拟内存处。
254行，r6 = KERNEL_END – 1，KERNEL_END的定义为：
00000056 #define KERNEL_END _end
而_end在arch/arm/kernel/vmlinux.lds.S中定义，表示的是内核Image的结束链接地址。
255行，r0 = r0 + 4，即下一个页表项的起始地址。
256行，r6 = r4 + r6 >> 18。
257行，比较r0，r6的值，并根据结果影响标志位。
258行，r3 = r3 + 1 << 20，即将r3的值加1MB。
259行，如果257行r0 <= r6的值就执行次句，mem[r0] = r3，r0 = r0 + 4。
260行，如果257行r0 <= r6的值就执行此句，跳转到257行。
257到260行的作用就是将整个内核Image映射到以0xC0008000为起始地址的虚拟地址处，如图3所示。
图3 内核Image映射到虚拟地址
162行，XIP大概就是说在Flash里执行内核，而不必把内核拷贝到内存里再执行，具体没了解过，在此略过，直接到284行。
284行，r0 = r4 + PAGE_OFFSET >> 18。
285行，r6 = r7 |( PHYS_OFFSET & 0xff000000)。
289行，mem[r0] = r6，即将物理内存的前1MB映射到0xC0000000，因为这1MB里存放有bootloader传过来的启动参数，从这可以看到，映射的虚拟地址存在重叠，但并没有关系，一个虚拟地址肯定只对应一个物理地址，但一个物理地址可以对应多个虚拟地址。
291行，看名字就知道是与调试有关的，因此不分析，直接到332行，子程序返回，至此__create_page_tables分析完毕。
98行，r13 = __switch_data的地址，等会再分析__switch_data的内容。
100行，lr = __enable_mmu的物理地址。
101行，pc = r10 + PROCINFO_INITFUNC，跳到struct proc_info_list变量的__cpu_flush成员处，从arch/arm/mm/proc-v6.S文件中可以知道，那里放的是一条跳转指令：b __v6_setup。__v6_setup也是在proc-v6.S中文件中定义：
00000157 __v6_setup: 00000158 #ifdef CONFIG_SMP 00000159 mrc p15, 0, r0, c1, c0, 1 @ Enable SMP/nAMP mode 00000160 orr r0, r0, #0x20 00000161 mcr p15, 0, r0, c1, c0, 1 00000162 #endif 00000163 00000164 mov r0, #0 00000165 mcr p15, 0, r0, c7, c14, 0 @ clean+invalidate D cache 00000166 mcr p15, 0, r0, c7, c5, 0 @ invalidate I cache 00000167 mcr p15, 0, r0, c7, c15, 0 @ clean+invalidate cache 00000168 mcr p15, 0, r0, c7, c10, 4 @ drain write buffer 00000169 #ifdef CONFIG_MMU 00000170 mcr p15, 0, r0, c8, c7, 0 @ invalidate I + D TLBs 00000171 mcr p15, 0, r0, c2, c0, 2 @ TTB control register 00000172 orr r4, r4, #TTB_FLAGS 00000173 mcr p15, 0, r4, c2, c0, 1 @ load TTB1 00000174 #endif /* CONFIG_MMU */ 00000175 adr r5, v6_crval 00000176 ldmia r5, {r5, r6} 00000177 #ifdef CONFIG_CPU_ENDIAN_BE8 00000178 orr r6, r6, #1 << 25 @ big-endian page tables 00000179 #endif 00000180 mrc p15, 0, r0, c1, c0, 0 @ read control register 00000181 bic r0, r0, r5 @ clear bits them 00000182 orr r0, r0, r6 @ set them 00000183 mov pc, lr @ return to head.S:__ret
158到162行，如果CPU是双核以上的，那么就使能多核模式。
164到168行，失能数据Cache、指令cache和write buffer。
169到174行，如果支持MMU，那么失能数据和指令TLB，将r4或上TTB_FLAGS之后写入到TTB1寄存器。
175行，取得v6_crval标号的物理地址，v6_crval的定义：
00000191 .type v6_crval, #object 00000192 v6_crval: 00000193 crval clear=0x01e0fb7f, mmuset=0x00c0387d, ucset=0x00c0187c
其中crval是一个宏，定义如下：
.macro crval, clear, mmuset, ucset
#ifdef CONFIG_MMU
.word clear
.word mmuset
#else
.word clear
.word ucset
#endif
.endm
这里假设是支持MMU的，因此v6_crval标号的定义替换为：
v6_crval: .word 0x01e0fb7f .word 0x00c0387d
176行，r5 = 0x01e0fb7f，r6 = 0x00c0387d
177到179行，大端模式相关，现在大部分CPU都工作在小端模式。
180行，读控制寄存器的值。
181行，r0 = r0 & (~r5)。
182行，r0 = r0 | r6。
183行，返回，注意，这里lr的值为__enable_mmu标号的物理地址，因为返回到__enable_mmu标号处执行，至此__v6_setup分析完毕，下面看__enable_mmu。
00000160 __enable_mmu: 00000161 #ifdef CONFIG_ALIGNMENT_TRAP 00000162 orr r0, r0, #CR_A 00000163 #else 00000164 bic r0, r0, #CR_A 00000165 #endif 00000166 #ifdef CONFIG_CPU_DCACHE_DISABLE 00000167 bic r0, r0, #CR_C 00000168 #endif 00000169 #ifdef CONFIG_CPU_BPREDICT_DISABLE 00000170 bic r0, r0, #CR_Z 00000171 #endif 00000172 #ifdef CONFIG_CPU_ICACHE_DISABLE 00000173 bic r0, r0, #CR_I 00000174 #endif 00000175 mov r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | 00000176 domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | 00000177 domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | 00000178 domain_val(DOMAIN_IO, DOMAIN_CLIENT)) 00000179 mcr p15, 0, r5, c3, c0, 0 @ load domain access register 00000180 mcr p15, 0, r4, c2, c0, 0 @ load page table pointer 00000181 b __turn_mmu_on 00000182 ENDPROC(__enable_mmu)
161到174行，根据配置设置相应的位，不说了。
175到179行，设置域存取寄存器。
180行，设置TTB寄存器。
181行，跳到__turn_mmu_on标号处。
00000196 __turn_mmu_on: 00000197 mov r0, r0 00000198 mcr p15, 0, r0, c1, c0, 0 @ write control reg 00000199 mrc p15, 0, r3, c0, c0, 0 @ read id reg 00000200 mov r3, r3 00000201 mov r3, r13 00000202 mov pc, r3 00000203 ENDPROC(__turn_mmu_on)
需要注意的是在执行200行时，MMU已经开启，CPU以后发出的都是虚拟地址。201行，r3 = r13，而r13的值为__switch_data标号的绝对地址（虚拟地址），因此202行就跳到__switch_data标号处。
00000019 .type __switch_data, %object 00000020 __switch_data: 00000021 .long __mmap_switched 00000022 .long __data_loc @ r4 00000023 .long _data @ r5 00000024 .long __bss_start @ r6 00000025 .long _end @ r7 00000026 .long processor_id @ r4 00000027 .long __machine_arch_type @ r5 00000028 .long __atags_pointer @ r6 00000029 .long cr_alignment @ r7 00000030 .long init_thread_union + THREAD_START_SP @ sp
取出21行的代码执行，也即跳转到__mmap_switched标号处。
00000041 __mmap_switched: 00000042 adr r3, __switch_data + 4 00000043 00000044 ldmia r3!, {r4, r5, r6, r7} 00000045 cmp r4, r5 @ Copy data segment if needed 00000046 1: cmpne r5, r6 00000047 ldrne fp, [r4], #4 00000048 strne fp, [r5], #4 00000049 bne 1b 00000050 00000051 mov fp, #0 @ Clear BSS (and zero fp) 00000052 1: cmp r6, r7 00000053 strcc fp, [r6],#4 00000054 bcc 1b 00000055 00000056 ARM( ldmia r3, {r4, r5, r6, r7, sp}) 00000057 THUMB( ldmia r3, {r4, r5, r6, r7} ) 00000058 THUMB( ldr sp, [r3, #16] ) 00000059 str r9, [r4] @ Save processor ID 00000060 str r1, [r5] @ Save machine type 00000061 str r2, [r6] @ Save atags pointer 00000062 bic r4, r0, #CR_A @ Clear 'A' bit 00000063 stmia r7, {r0, r4} @ Save control register values 00000064 b start_kernel 00000065 ENDPROC(__mmap_switched)
42行，获得__switch_data + 4的地址。
44行，将__data_loc的地址存到r4，_data的地址存到r5，__bss_start的地址存到r6，_end的地址存到r7。
45行，比较r4和r5的值，对于XIP，它们是不相等，这里显然是相等的，因此46到49行都不执行。
51到54行，清BSS段。
56行，r4 = processor_id，r5 = __machine_arch_type，r6 = __atags_pointer，r7 = cr_alignment，sp = init_thread_union + THREAD_START_SP。
57、58行，是对于Thumb状态的，这里啥也没做。
59到61行，将值存到对应的地址上。
62行，清掉r0的’A’位然后存到r4，该位表示数据存取是否需要对齐。
63行，保存r0，r4的值。
64行，start_kernel，欢呼吧……