cf765F.Souvenirs

比赛的时候看错了C题于是不会做了……来搞F，听说有人莫队水过去了，于是也写了个莫队，TLE7……惨掉rating

editorial看得很烦躁啊……又回想起了被英语阅读支配的恐惧

离线，移动右端点，考虑维护左端点处的答案.设当前右端点移动到了i,数列为a[],则答案的更新一定是由a[i]与某些a[j](j<i)的差的绝对值引起的，下面只考虑a[j]≥a[i]的情况，a[j]≤a[i]同理（当然如果有a[j]=a[i]会被用来更新2次但是肯定不会影响答案正确性）

首先我们找出最大的一个j满足j<i,a[j]≥a[i],用它更新[1,j]的答案。设a[j]=y,那么在[1,j-1]中如果有a的值大于y，肯定不会对答案构成影响（因为它与a[i]的差大于a[j]-a[i]），实际上，我们发现对于a数列中任何一个位于[1,j-1]的数，当且仅当它处于[a[i],(a[i]+a[j])/2]时，才可能与a[i]成对，对前面的答案造成影响，如果一个元素的值位于((a[i]+a[j])/2,a[j]],那么它肯定会与a[j]成对。这样一来，我们就把需要考虑的值域从[a[i],1e9]缩短到了[a[i],(a[i]+a[j])/2],重复这个过程，每次都至少会把这个区间折半，于是更新答案的次数是O(log(1e9))的，更新答案的过程用一个区间取min的线段树维护，寻找某一值域中最右元素可用一个动态开点的权值线段树维护，于是总时间复杂度为O(nlog²MaxV+mlogn),如果把a[]离散化之后开权值线段树可以做到O(nlognlogMaxV+mlogn),其中MaxV=1e9.

program cf765F;
uses math;
const maxn=100000+10;
      maxm=300000+10;
      maxv=1000000000;
type query=record next,l,r:longint;end;
var a,last:array[0..maxn] of longint;
    ques:array[0..maxm] of query;
    ans:array[0..maxm] of longint;
    mark:array[0..maxn*4] of longint;
    segv:array[0..maxn*40] of record l,r,right:longint;end;
    n,m,root,tot,i,j,l,r,id:longint;
procedure build(x,l,r:longint);
var mid:longint;
begin
  mark[x]:=maxv+1;
  if l<r then
  begin
    mid:=(l+r)shr 1;
    build(x+x,l,mid);
    build(x+x+1,mid+1,r);
  end;
end;
procedure update(x,l,r,nowl,nowr,v:longint);
var mid:longint;
begin
  if(nowl<=l)and(r<=nowr) then
  begin
    mark[x]:=min(mark[x],v);
    exit;
  end;
  mid:=(l+r)shr 1;
  if nowl<=mid then update(x+x,l,mid,nowl,nowr,v);
  if nowr>mid then update(x+x+1,mid+1,r,nowl,nowr,v);
end;
function ask(x,l,r,p:longint):longint;
var mid:longint;
begin
  if l=r then exit(mark[x]);
  mid:=(l+r)shr 1;
  if p<=mid then exit(min(mark[x],ask(x+x,l,mid,p)))
    else exit(min(mark[x],ask(x+x+1,mid+1,r,p)));
end;
function findright(x,l,r,nowl,nowr:longint):longint;
var mid:longint;
begin
  if((nowl<=l)and(r<=nowr))or(x=0) then exit(segv[x].right);
  mid:=(l+r)shr 1;
  if nowr<=mid then exit(findright(segv[x].l,l,mid,nowl,nowr));
  if nowl>mid then exit(findright(segv[x].r,mid+1,r,nowl,nowr));
  exit(max(findright(segv[x].l,l,mid,nowl,nowr),findright(segv[x].r,mid+1,r,nowl,nowr)));
end;
procedure modify(var x:longint;l,r,p,v:longint);
var mid:longint;
begin
  if x=0 then
  begin
    inc(tot);
    x:=tot;
  end;
  segv[x].right:=max(segv[x].right,v);
  if l<r then
  begin
    mid:=(l+r)shr 1;
    if p<=mid then modify(segv[x].l,l,mid,p,v)
      else modify(segv[x].r,mid+1,r,p,v);
  end;
end;
begin
  readln(n);
  for i:=1 to n do read(a[i]);
  readln(m);
  for i:=1 to m do readln(ques[i].l,ques[i].r);
  fillchar(last,sizeof(last),0);
  for i:=1 to m do
  begin
    ques[i].next:=last[ques[i].r];
    last[ques[i].r]:=i;
  end;
  build(1,1,n);
  root:=0;
  tot:=0;
  segv[0].right:=0;
  for i:=1 to n do
  begin
    if i>1 then
    begin
      l:=a[i];
      r:=maxv;
      while true do
      begin
        id:=findright(root,0,maxv,l,r);
        if id=0 then break;
        update(1,1,n,1,id,a[id]-a[i]);
        if a[i]=a[id] then break;
        r:=(a[i]+a[id])shr 1;
      end;
      l:=0;
      r:=a[i];
      while true do
      begin
        id:=findright(root,0,maxv,l,r);
        if id=0 then break;
        update(1,1,n,1,id,a[i]-a[id]);
        if a[i]=a[id] then break;
        l:=(a[i]+a[id])shr 1+1;
      end;
    end;
    j:=last[i];
    while j>0 do
    begin
      ans[j]:=ask(1,1,n,ques[j].l);
      j:=ques[j].next;
    end;
    modify(root,0,maxv,a[i],i);
  end;
  for i:=1 to m do writeln(ans[i]);
end.