VB6之多维数组中元素在内存中的排列情况

Private Declare Sub RtlMoveMemory Lib "kernel32" (Destination As Any, Source As Any, ByVal Length As Long)


'code by lichmama from cnblogs.com
Private Sub Form_Load()
    Dim a(2) As Byte
    Dim b(2, 2) As Byte
    Dim c(2, 2, 2) As Byte
    
    Debug.Print "一维数组："
    Debug.Print VarPtr(a(0)), VarPtr(a(1)), VarPtr(a(2))
    '数组元素在内存中的排列情况：
    'a[0]|a[1]|a[2]
    
    Debug.Print "二维数组："
    Debug.Print VarPtr(b(0, 0)), VarPtr(b(1, 0)), VarPtr(b(2, 0))
    Debug.Print VarPtr(b(0, 1)), VarPtr(b(1, 1)), VarPtr(b(2, 1))
    Debug.Print VarPtr(b(0, 2)), VarPtr(b(1, 2)), VarPtr(b(2, 2))
    '数组元素在内存中的排列情况：
    'b[0,0]|b[1,0]|b[2,0]-->b[0,1]|b[1,1]|b[2,1]-->b[0,2]|b[1,2]|b[2,2]
    
    Debug.Print "三维数组："
    Debug.Print VarPtr(c(0, 0, 0)), VarPtr(c(1, 0, 0)), VarPtr(c(2, 0, 0))
    Debug.Print VarPtr(c(0, 1, 0)), VarPtr(c(1, 1, 0)), VarPtr(c(2, 1, 0))
    Debug.Print VarPtr(c(0, 2, 0)), VarPtr(c(1, 2, 0)), VarPtr(c(2, 2, 0))
    Debug.Print VarPtr(c(0, 0, 1)), VarPtr(c(1, 0, 1)), VarPtr(c(2, 0, 1))
    Debug.Print VarPtr(c(0, 1, 1)), VarPtr(c(1, 1, 1)), VarPtr(c(2, 1, 1))
    Debug.Print VarPtr(c(0, 2, 1)), VarPtr(c(1, 2, 1)), VarPtr(c(2, 2, 1))
    Debug.Print VarPtr(c(0, 0, 2)), VarPtr(c(1, 0, 2)), VarPtr(c(2, 0, 2))
    Debug.Print VarPtr(c(0, 1, 2)), VarPtr(c(1, 1, 2)), VarPtr(c(2, 1, 2))
    Debug.Print VarPtr(c(0, 2, 2)), VarPtr(c(1, 2, 2)), VarPtr(c(2, 2, 2))
    '数组元素在内存中的排列情况：
    'c[0,0,0]|c[1,0,0]|c[2,0,0]-->c[0,1,0]|c[1,1,0]|c[2,1,0]-->c[0,2,0]|c[1,2,0]|c[2,2,0]
    '-->c[0,0,1]|c[1,0,1]|c[2,0,1]-->c[0,1,1]|c[1,1,1]|c[2,1,1]-->c[0,2,1]|c[1,2,1]|c[2,2,1]
    '-->c[0,0,2]|c[1,0,2]|c[2,0,2]-->c[0,1,2]|c[1,1,2]|c[2,1,2]-->c[0,2,2]|c[1,2,2]|c[2,2,2]
    
    '我们习惯逻辑上这么给数组赋值，字面上像是b()="lhmimaca!"
    b(0, 0) = &H6C: b(0, 1) = &H68: b(0, 2) = &H6D
    b(1, 0) = &H69: b(1, 1) = &H6D: b(1, 2) = &H61
    b(2, 0) = &H63: b(2, 1) = &H61: b(2, 2) = &H21
    
    Dim text As String
    text = String(9, " ")
    Call RtlMoveMemory(ByVal StrPtr(text), ByVal VarPtr(b(0, 0)), 9)
    Debug.Print "但，其实结果是这样的：";
    Debug.Print StrConv(text, vbUnicode)
End Sub

看结果说话（内存地址打印）：

一维数组：
 2031464       2031465       2031466 
二维数组：
 2048432       2048433       2048434 
 2048435       2048436       2048437 
 2048438       2048439       2048440 
三维数组：
 2059256       2059257       2059258 
 2059259       2059260       2059261 
 2059262       2059263       2059264 
 2059265       2059266       2059267 
 2059268       2059269       2059270 
 2059271       2059272       2059273 
 2059274       2059275       2059276 
 2059277       2059278       2059279 
 2059280       2059281       2059282 
但，其实结果是这样的：lichmama!