超小超轻便——100多行代码实现的简易缓动类

　　平时做as3游戏少不了要用到缓动效果，一般都是用greensock的tweenlite库，但引用tweenlite库是有代价的，整个swc库的大小是93kb。对于大型的页游，游戏本身体量就大，且需要用到大量缓动效果，那这100kb左右的文件大小当然是微不足道。但如果是普通的几mb的小游戏，只需要用到to方法实现一个最简单的缓动效果，那专门引入tweenlite库则显得小题大做。缓动效果并不难实现，针对这种简单应用，完全可以用100多行的代码自己实现。代码大小小于1kb。思路是通用的，像cocos，unity等手游开发，也会有开源的第三方缓动库。开发一些几mb的手机小游戏，如果只需要简单的缓动效果，完全可以自己实现，养成好习惯，为游戏安装包瘦身。毕竟安装包越小，玩家越喜欢。

package
{
    import__global;
    
    import flash.display.DisplayObject;
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.utils.Dictionary;

    public class Tween
    {
        public function Tween()
        {
            
        }
        private static var root:DisplayObject;
        
        private static var list:Dictionary=new Dictionary();
        private static var len:int;
        /**
         *缓动类 
         * @param target 目标
         * @param duration 缓动时间 秒
         * @param targetVars 参数 {目标对象属性：值}
         * @param callBack 变化完成后回调
         */        
        public static function to(target:Object, duration:Number, targetVars:Object,fromVars:Object=null,callBack:Function=null):void
        {
            //假如该对象已经有缓动则直接完成上一次的缓动
            if(list[target]!=null)
            {
                for(var key:String in targetVars)
                {
                    setValue(target,key,targetVars[key]);
                }
                len--;
            }
            if(fromVars==null)
            {
                fromVars={};
                for(key in targetVars)
                {
                    fromVars[key]=target[key];
                }
            }
            var perVars:Object={};
            var count:int=duration*24;
            for(key in targetVars)
            {
                perVars[key]=(targetVars[key]-target[key])/count;
//                trace("per ["+key+"]:"+perVars[key]+" count:"+count);
            }
            list[target]={count:count,fromVars:fromVars,target:target,targetVars:targetVars,perVars:perVars,callBack:callBack};
            len++;
            startMotion();
        }
        
        private static function startMotion():void
        {
            if(root==null)
            {
                root=__global.stage;
            }
            
            if(len>0)
            {
                root.removeEventListener(Event.ENTER_FRAME,enterFrame);
                root.addEventListener(Event.ENTER_FRAME,enterFrame);
            }
            else
            {
                root.removeEventListener(Event.ENTER_FRAME,enterFrame);
            }
        }
        
        private static function enterFrame(e:Event=null):void
        {
            for(var key2:* in list)
            {
                var task:Object=list[key2];
                task.count--;
                //缓动结束
                if(task.count<=0)
                {
                    for(var key:String in task.targetVars)
                    {
                        setValue(task.target,key,task.targetVars[key]);
                    }
                    if(task.callBack)task.callBack();
                    delete list[key2];
                    len--;
                    startMotion();
                }
                else
                {
                    for( key in task.targetVars)
                    {
                        task.fromVars[key]+=task.perVars[key];
                        setValue(task.target,key,task.fromVars[key]);
                    }
                }
            }
        }
        
        /**
         *设置值，可以通过属性名过滤处理方法 
         * @param target
         * @param key
         * @param value
         * 
         */        
        private static function setValue(target:Object,key:String,value:Number):void
        {
            switch(key)
            {
                case "currentFrame":
                    var mc:MovieClip=target as MovieClip;
                    if(mc)
                    {
//                        trace("set currentFrame:"+int(value));
                        mc.gotoAndStop(int(value))
                    }
                    else
                    {
                        target[key]=value;
                    }
                    break;
                default:
                    target[key]=value;
                    break;
            }
        }
        
    }
}