可综合的Task写法

1、网上有人说Muxplus不可以综合Task语句，Quartus II可以综合Task语句，在翻看了夏宇闻的《Verilog数字系统设计教程》关于书中提到的可综合的Task写法似乎都是一个类型的，在Task里面并没有定义任何的输入输出类型以及变量。

2、参考书中Task的写法，写了一个模拟陀螺仪的波形产生程序：

module WaveGenerate(clk,reset,gp_x_pos,gp_x_neg);
input clk;
input reset;
output reg gp_x_pos;
output reg gp_x_neg;

/* 产生模拟陀螺仪波形时钟 */
`define system_clk 50000000
`define wave_div 600000
reg wave_gen_clk;
reg [15:0]clk_cnt;
always @(posedge clk  or negedge reset)
begin
    if(~reset)
        begin
        wave_gen_clk<=0;
        clk_cnt<=0;
        end
    else if(clk_cnt==`system_clk/`wave_div/2/2-1)
        begin
        wave_gen_clk<=~wave_gen_clk;
        clk_cnt<=0;
        end
    else 
        begin
        clk_cnt<=clk_cnt+1;
        end
end
/* 模拟陀螺仪波形状态机 */
`define pos_first 2'b01
`define neg_first 2'b10

`define bit1 2'b00
`define bit2 2'b01
`define bit3 2'b10
`define bit4 2'b11

reg [1:0]work_state;
reg [1:0]data_state;
reg identifyer;
always @(posedge wave_gen_clk or negedge reset)
begin
    if(~reset)
        begin
        work_state<=`pos_first;
        data_state<=`bit1;
        gp_x_neg<=0;
        gp_x_pos<=0;
        identifyer<=0;
        end
    else 
        begin
        case (work_state)
        `pos_first:begin
                    if(~identifyer)
                        pos_first_cycle;
                    else 
                        begin
                        work_state<=`neg_first;
                        data_state<=`bit1;
                        identifyer<=0;
                        end
                    end
        `neg_first:begin
                    if(~identifyer)
                        begin
                        neg_first_cycle;
                        end
                    else 
                        begin
                        work_state<=`pos_first;
                        data_state<=`bit1;
                        identifyer<=0;
                        end
                    end
        default:begin
                work_state<=`pos_first;
                end
        endcase
        end
end
/* 正脉冲发送周期 */
task pos_first_cycle;
    begin
            case (data_state)
            `bit1:begin
                    gp_x_pos <=1;
                    data_state <=`bit2;
                    end
            `bit2:begin
                    gp_x_neg<=1;
                    data_state<=`bit3;
                    end
            `bit3:begin
                    gp_x_pos<=0;
                    data_state<=`bit4;
                    end
            `bit4:begin
                    gp_x_neg<=0;
                    data_state<=`bit1;
                    identifyer<=1;
                    end
            default:begin
                    data_state<=`bit1;
                    end
            endcase
    end
endtask
/* 负脉冲发送周期 */
task neg_first_cycle;
    begin
        case (data_state)
        `bit1:begin
                gp_x_neg<=1;
                data_state<=`bit2;
                end
        `bit2:begin
                gp_x_pos<=1;
                data_state<=`bit3;
                end
        `bit3:begin
                gp_x_neg<=0;
                data_state<=`bit4;
                end
        `bit4:begin
                gp_x_pos<=0;
                data_state<=`bit1;
                identifyer<=1;
                end
        default:begin
                data_state<=`bit1;
                end
        endcase
    end
endtask
endmodule 

 最后观察示波器的波形正确。

3、似乎这种Task写法就是将Task中的Case内容搬到相应的地方去。