SQL Server解决孤立用户浅析

孤立用户概念

       所谓孤立用户即指在服务器实例上未定义或错误定义了其相应 SQL Server 登录名的数据库用户无法登录到实例。 这样的用户被称为此服务器实例上的数据库的“孤立用户”。 如果删除了对应的 SQL Server 登录名，则数据库用户可能会变为孤立用户。 另外，在数据库还原或附加到 SQL Server 的其他实例之后，数据库用户也可能变为孤立用户。 如果未在新服务器实例中提供数据库用户映射到的 SID，则该用户可能变为孤立用户

检测孤立用户

检测孤立用户相当简单，可以使用下面SQL语句

Code Snippet

1. USE DatabaseName;
2. GO
3.  
4. EXEC sp_change_users_login @Action = 'Report';
5. GO

当然如果你不想用系统自带的存储过程sp_change_users_login，其实检测孤立账号也很简单，一个简单的SQL语句即可搞定：

Code Snippet

1. SELECT   UserName = name ,
2.          UserSID = sid
3. FROM     sysusers
4. WHERE    issqluser = 1
5.          AND ( sid IS NOT NULL
6.                AND sid <> 0x0
7.              )
8.          AND ( LEN(sid) <= 16 )
9.          AND SUSER_SNAME(sid) IS NULL
10. ORDER BY name

从上面可以看出，

    1：孤立账号必须是SQL Server 用户（issqluser= 1）,:

    2：它必须是sys、guest、INFORMATION_SCHEMA账号以外的SQL Server用户

    SELECT * FROM sysusers WHERE SID IS NULL OR SID = 0x0;

3：它返回与安全标识号 (SID) 关联的登录名必须为空值

4：SID的长度小于16

解决孤立账号

方法1:

Step 1:  检测、查看对应的孤立账号


USE <DatabaseName>;

GO

EXEC sp_change_users_login  @Action='Report';

GO

Step 2: 新建对应的登录名，例如上面检测到Test账号为孤立账号

USE [master]

GO

CREATE LOGIN [Test] WITH PASSWORD=N'Pa@#456' MUST_CHANGE, DEFAULT_DATABASE=[xxxx], CHECK_EXPIRATION=ON, CHECK_POLICY=ON

GO

Step 3:

USE EASN_EAP;

GO

EXEC sp_change_users_login @Action='Update_one',@UserNamePattern='xxxx',@LoginName='xxxx';

Step 4: 重复执行Step 1、Step 2、Step 3解决其它孤立账号，直到所有孤立账号全部被Fix掉。

方法2：对于方法1，如果账号比较多，操作起来比较郁闷，重复干繁琐的体力活。于是我写了一个存储过程来解决

SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO



IF EXISTS ( SELECT  1
            FROM    dbo.sysobjects
            WHERE   id = OBJECT_ID(N'sp_fix_orphaned_users')
                    AND OBJECTPROPERTY(id, 'IsProcedure') = 1 )
    DROP PROCEDURE sp_fix_orphaned_users;
GO

--================================================================================
--        ProcedureName        :            sp_fix_orphaned_users
--        Author               :            Kerry
--        CreateDate           :            2013-12-08
--        Description          :            批量解决数据库孤立账号
--                                        http://www.cnblogs.com/kerrycode/
/**********************************************************************************************
        Parameters            :                                    参数说明
***********************************************************************************************
            @DefaultPwd       :            所有孤立账户使用同一个密码@DefaultPwd
            @LoginName        :            所有需要fix的孤立账户，eg 'test1|test2|test3' 表示孤立账户test1、test2、test3。
            @Password         :            对应@LoginName，eg '@341|Dbd123|D#25' 分别表示上面账号对应的密码
*************************************************************************************************
   Modified Date    Modified User     Version                 Modified Reason
**************************************************************************************************    2013-12-08             Kerry         V01.00.00                  创建该存储过程。

*************************************************************************************************/
--=================================================================================================

CREATE PROCEDURE [dbo].[sp_fix_orphaned_users]
(
    @IsUseSamePwd  INT    = 0              ,
    @DefaultPwd       VARCHAR(32) = NULL ,
    @LoginName       NVARCHAR(MAX) =NULL,
    @Password       NVARCHAR(MAX) =NULL
)
AS

DECLARE @UserName NVARCHAR(64);
DECLARE @tmpPwd      VARCHAR(20);
DECLARE @LoginRows INT;
DECLARE @PwdRows   INT;



IF @IsUseSamePwd =1 AND @DefaultPwd IS NULL
BEGIN
    RAISERROR('%s Invalid. Please check the paramter %s value',16,1, '@DefaultPwd');
    RETURN 1;
END

IF @IsUseSamePwd = 0 AND ( @LoginName IS NULL OR  @Password IS NULL)
BEGIN
    RAISERROR('%s Invalid. Please check the paramter %s value',16,1, '@Password');
    RETURN 1;
END

IF @IsUseSamePwd = 0
BEGIN

    CREATE TABLE #TempLoginNams
    (
        ID                INT,
        UserName        VARCHAR(20),
    )

    INSERT INTO #TempLoginNams
            ( ID, UserName )
    SELECT * FROM dbo.SplitString(@LoginName,'|');

    CREATE TABLE #TempPassword
    (
        ID            INT,
        UserPassrd  VARCHAR(20)
    )

    INSERT INTO #TempPassword
    SELECT * FROM dbo.SplitString(@Password,'|');

    SELECT @LoginRows=COUNT(1) FROM #TempLoginNams;
    SELECT @PwdRows=COUNT(10) FROM #TempPassword;

IF @LoginRows != @PwdRows
    BEGIN
        RAISERROR('The paramter %s have different nums. Please check the paramter %s value',16,1, '@LoginName & @Password ');
        RETURN 1;
    END

END


CREATE TABLE #OrphanedUser
(
    UserName    sysname,
    UserId        INT
)


INSERT INTO #OrphanedUser EXEC sp_change_users_login @Action='Report';


DECLARE Cur_OrphanedUsers CURSOR FOR
    SELECT UserName FROM #OrphanedUser;


OPEN Cur_OrphanedUsers;

FETCH NEXT FROM Cur_OrphanedUsers INTO @UserName;
WHILE ( @@FETCH_STATUS = 0 )
    BEGIN
        IF @IsUseSamePwd = 1
            BEGIN

                EXEC sp_change_users_login 'Auto_Fix', @UserName, NULL,
                    @DefaultPwd;


                EXEC sp_change_users_login @Action = 'update_one',
                    @UserNamePattern = @UserName, @LoginName = @UserName;
            END
        ELSE
            BEGIN
                SELECT  @UserName = o.UserName ,
                        @tmpPwd = p.UserPassrd
                FROM    #OrphanedUser o
                        LEFT JOIN #TempLoginNams l ON o.UserName = l.UserName
                        LEFT JOIN #TempPassword p ON l.ID = p.ID
                WHERE   o.UserName = @UserName;

                EXEC sp_change_users_login 'Auto_Fix', @UserName, NULL,
                    @tmpPwd;
                EXEC sp_change_users_login @Action = 'update_one',
                    @UserNamePattern = @UserName, @LoginName = @UserName;
            END

        FETCH NEXT FROM Cur_OrphanedUsers INTO @UserName
    END
CLOSE Cur_OrphanedUsers
DEALLOCATE Cur_OrphanedUsers

DROP TABLE  #OrphanedUser;

IF @IsUseSamePwd = 0
BEGIN
    DROP TABLE #TempLoginNams;
    DROP TABLE #TempPassword;
END

GO

 

其中该存储过程调用了一个Function成为SplitString，该函数是我从网上搜索得来的，作者不详，本来想自己重写该函数，后来觉得没有必要重复造轮子。因为这个函数完全满足我的需求。

 

Code Snippet

1. CREATE FUNCTION SplitString
2.     (
3.       -- Add the parameters for the function here
4.       @myString VARCHAR(500) ,
5.       @deliminator VARCHAR(10)
6.     )
7. RETURNS @ReturnTable TABLE
8.     (
9.       -- Add the column definitions for the TABLE variable here
10.       [id] [int] IDENTITY(1, 1)
11.                  NOT NULL ,
12.       [part] [varchar](50) NULL
13.     )
14. AS
15.     BEGIN
16.         DECLARE @iSpaces INT
17.         DECLARE @part VARCHAR(50)
18.         --initialize spaces 
19.         SELECT  @iSpaces = CHARINDEX(@deliminator, @myString, 0)
20.         WHILE @iSpaces > 0
21.             BEGIN
22.                 SELECT  @part = SUBSTRING(@myString, 0,
23.                                           CHARINDEX(@deliminator, @myString, 0))
24.                 INSERT  INTO @ReturnTable
25.                         ( part )
26.                         SELECT  @part
27.                 SELECT  @myString = SUBSTRING(@mystring,
28.                                               CHARINDEX(@deliminator,
29.                                                         @myString, 0)
30.                                               + LEN(@deliminator),
31.                                               LEN(@myString) - CHARINDEX(' ',
32.                                                               @myString, 0))
33.                 SELECT  @iSpaces = CHARINDEX(@deliminator, @myString, 0)
34.             END
35.         IF LEN(@myString) > 0
36.             INSERT  INTO @ReturnTable
37.                     SELECT  @myString
38.         RETURN
39.     END
40.            GO

 

这个存储过程在执行时，有一个既可以说是小bug，也可以说没有验证的错误，就是登录名的密码设置如果过于简单，则执行

EXEC sp_change_users_login 'Auto_Fix', @UserName, NULL,   @tmpPwd; 则会报如下错误

消息 15118，级别 16，状态 1，第 1 行
密码有效性验证失败。该密码不够复杂，不符合 Windows 策略要求。
消息 15497，级别 16，状态 1，过程 sp_change_users_login，第 223 行
无法使用 sp_addlogin 添加登录名(用户 = easn)。即将终止此过程。

一时还没有找到如何去验证密码是否符合复杂度的方法，留待以后进一步完善。

 

假如迁移数据库后，发现有user1、user2、user3三个孤立账号，如果我想着三个孤立账号使用同一密码，那么执行SQL 1 ，如果我想给user1、user2、user3三个账号设置各自密码，那么使用SQL 2解决孤立账号问题。

--SQL 1
EXEC [dbo].[sp_fix_orphaned_users] @IsuseSamePwd =1,@DefaultPwd='Qwe!@423'

--SQL 2
EXEC [dbo].[sp_fix_orphaned_users] @IsuseSamePwd =0, @loginName='user1|user2|user3', @Password='Qwe!@423|QweD2@#4|Oi87^%'

看到桦仔的回复（修改后的存储过程后），那个确实是个不错的方法，我测试了一下后发现还是这个问题：

Code Snippet

1. CREATE PROCEDURE [dbo].[sp_fix_orphaned_users]
2. AS
3.     BEGIN
4.         DECLARE @UserName NVARCHAR(64)
6.         CREATE TABLE #SqlLoginUser
7.         (
8.             UserName SYSNAME ,
9.             UserId INT IDENTITY(1, 1)
10.         )
11.          
12.         INSERT  INTO #SqlLoginUser( UserName ) SELECT  [name]  FROM  SYS.[sql_logins]
15.         CREATE TABLE #OrphanedUser
16.             (
17.               UserName SYSNAME ,
18.               UserId INT
19.             )
21.         INSERT  INTO #OrphanedUser EXEC sp_change_users_login @Action = 'Report';
23.         DECLARE Cur_OrphanedUsers CURSOR
24.         FOR
25.             SELECT  UserName
26.             FROM    #OrphanedUser;
27.         OPEN Cur_OrphanedUsers;
28.         FETCH NEXT FROM Cur_OrphanedUsers INTO @UserName;
29.         WHILE ( @@FETCH_STATUS = 0 )
30.             BEGIN
31.                 IF ( @UserName IN ( SELECT  [UserName]
32.                                     FROM    [#SqlLoginUser] ) )
33.                     BEGIN
34.                         EXEC sp_change_users_login @Action = 'update_one',
35.                             @UserNamePattern = @UserName,
36.                             @LoginName = @UserName;
37.                     END
38.                 ELSE
39.                     BEGIN
40.                         DECLARE @SQL NVARCHAR(200)
41.                         SET @SQL = 'CREATE LOGIN ' + @UserName + ' WITH PASSWORD='''''
42.                         EXEC(@SQL)
43.                         EXEC sp_change_users_login @Action = 'update_one',
44.                             @UserNamePattern = @UserName,
45.                             @LoginName = @UserName;
46.                     END
47.    
48.                 FETCH NEXT FROM Cur_OrphanedUsers INTO @UserName
49.             END
50.         CLOSE Cur_OrphanedUsers
51.         DEALLOCATE Cur_OrphanedUsers
52.      
53.         DROP TABLE   #OrphanedUser
54.         DROP TABLE  #SqlLoginUser
55.     END
57. EXEC sp_fix_orphaned_users

消息 15116，级别 16，状态 1，第 1 行
密码有效性验证失败。该密码太短，不符合 Windows 策略要求。
消息 15291，级别 16，状态 1，过程 sp_change_users_login，第 137 行
正在终止此过程。缺少 Login 名称 'xxx' 或该名称无效。

不过对于这个错误倒是很好解决，创建登录名是将CHECK_POLICY设置为OFF，就可避免上面错误。

Code Snippet

1. USE [master]
2. GO
3. CREATE LOGIN [test] WITH PASSWORD=N'', DEFAULT_DATABASE=[master], CHECK_EXPIRATION=OFF, CHECK_POLICY=OFF
4. GO

给登录名密码设置为空，这个做法相当不安全，我还是觉得有所不妥，其实，我现在在的需求是这样（很多时候，由于表达能力不足，没有阐述清楚）： 数据库从一台服务器迁移到另外一台服务器后，这个数据库对应的账号变成了孤立账号，假设其孤立账号为U1、U2……UN在迁移整理过程我发现，其实我只需要账号U1、U2、 U4、U6，其它账号没有必要也迁移过去。所以我才为存储过程sp_fix_orphaned_users设置了参数@LoginName和@Password， 用于解决这种需求。@LoginName=‘U1|U2|U4|U6’， @Password=‘Pwd1|Pwd2|Pwd4|Pwd6’，而有时候在测试数据库环境，为了图方便、省事，就所有孤立账号使用同一个秘密，这就是加入参数@IsUseSamePwd的缘故。当然这些是我自己的特殊需求。至于如果不用验证密码复杂性，可以结合桦仔的方法，先新建登录名，然后使用sp_change_users_login来Fix掉。