Unity shader学习之Alpha Test

可以在fragment中使用cg的函数--clip来进行透明度测试。

函数定义如下：

void clip(float4 x);

void clip(float3 x);

void clip(float2 x);

void clip(float1 x);

void clip(float x);

参数：裁剪时使用的标量或矢量条件。

描述：如果给定参数的任何一个分量是负数，就会舍弃当前像素的输出颜色。等同于：

            void clip(float4 x)
            {
                if (any(x < 0))
                    discard;
            }                

转载请注明出处：http://www.cnblogs.com/jietian331/p/7154001.html

shader如下：

// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Custom/Alpha Test"
{
    Properties
    {
        _MainTex("Main Texture", 2D) = "white" {}
        _Specular("Specular", Color) = (1,1,1,1)
        _Gloss("Gloss", Range(8, 256)) = 8
        _CutOff("Cut Off", Range(0, 1)) = 0
    }

    SubShader
    {
        Pass
        {
            Tags
            {
                "LightMode" = "ForwardBase"
            }

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCg.cginc"
            #include "Lighting.cginc"

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _Specular;
            float _Gloss;
            float _CutOff;

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                fixed4 color : COLOR;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR;
                float2 uv : TEXCOORD0;
                float3 worldNormal : TEXCOORD1;
                float3 worldLight : TEXCOORD2;
                float3 worldView : TEXCOORD3;
            };

            v2f vert(appdata v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color = v.color;
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldLight = normalize(WorldSpaceLightDir(v.vertex));
                o.worldView = normalize(WorldSpaceViewDir(v.vertex));
                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET
            {
                fixed4 albedo = tex2D(_MainTex, i.uv) * i.color;

                // alpha test
                clip(albedo.a - _CutOff);
                // equals to:
                //if(albedo.a - _CutOff < 0)
                //    discard;

                fixed3 ambient = albedo.rgb * UNITY_LIGHTMODEL_AMBIENT.rgb;
                fixed3 diff = albedo.rgb * _LightColor0.rgb * max(0, dot(i.worldNormal, i.worldLight));
                fixed3 halfDir = normalize(i.worldLight + i.worldView);
                fixed3 spec = albedo.rgb * _Specular.rgb * pow(max(0, dot(halfDir, i.worldNormal)), _Gloss);
                fixed3 col = ambient + diff + spec;
                return fixed4(col, 1);
            }

            ENDCG
        }
    }

    Fallback "Diffuse"
}

效果如下：

 资源如下：

http://files.cnblogs.com/files/jietian331/transparent_texture.rar

有2个问题：

1. 从效果图中可看出，alpha test 得到的透明效果很“极端”——要么完全透明，要么完全不透明，而且在边缘上参差不齐，有锯齿，这是因为在边界处纹理的透明度变化精度问题。

2. 在片元着色器中discard操作会造成性能的下降。为什么？

因为Unity采用了Early-Z技术来提高GPU的性能，即把深度测试提前，先进行深度测试，再进行片元着色器的着色，这样被舍弃的片元便不需要再进行片元着色器的处理了，这样有利于提升GPU的性能。

而这种技术与片元着色器的discard操作是冲突的，因此现代的GPU会判断片元着色器中的操作是否与提前测试冲突，如果有冲突就会禁用提前测试，也就造成了性能上的下降。