Delphi图像处理之图像反色

----开发环境 D7

图像反色: 对24位的真彩图的三个分量（R,G,B）取反;

//内存映射处理图像反色//适用于大图片的操作

 ---Unit

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtDlgs, ExtCtrls, ComCtrls, Math, TypInfo;

type
  TForm1 = class(TForm)
    Image1: TImage;
    Image2: TImage;
    Label1: TLabel;
    OpenPictureDialog1: TOpenPictureDialog;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    Button7: TButton;
    procedure Button1Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button7Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
begin
  if OpenPictureDialog1.Execute then
  begin
    Image1.Picture.LoadFromFile(OpenPictureDialog1.FileName);
    Label1.Caption:='图片宽x高:'+inttostr(Image1.Picture.Width)+'x'+inttostr(Image1.Picture.Height);
    Image2.Picture.Assign(Image1.Picture);
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  OpenPictureDialog1.Filter:='Bitmaps (*.bmp)|*.bmp';
  Self.DoubleBuffered:=True;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  vDC, vDC1:HDC;
begin
  vDC:=GetDC(Form1.Handle);
  //直接按Image2的大小来操作，只是看上去有点小问题(图片比Image控件大时有点问题)
  if not PatBlt(vDC,Image2.Left,Image2.Top,Image2.Width,Image2.Height,DSTINVERT ) then
    ShowMessage('error:设置失败！');
  ReleaseDC(Form1.Handle,vDC);

end;

procedure TForm1.Button6Click(Sender: TObject);
var
  x,y,R,G,B:Integer;
  vBmp:TBitmap;
  gray:Integer;
  vC:TColor;
begin
  vBmp:=TBitmap.Create;
  vBmp.Assign(Image1.Picture.Bitmap);
  vBmp.PixelFormat:=pf24bit;//如果Image1.Picture.Bitmap不是24位的真彩BMP图片，请设置这个
  for y:=0 to vBmp.Height -1 do
  begin
    for x:=0 to vBmp.Width-1  do
    begin
      vC:= vbmp.Canvas.Pixels[x,y]; //这样效率超级低，好慢
      R:=vC and $FF;
      G:=(vC shr 8) and $FF;
      B:=(vC shr 16)and $FF;
      vbmp.Canvas.Pixels[x,y]:=RGB(not R,not G,not B);
    end;
  end;
  Image2.Picture.Bitmap:=vBmp;
  vBmp.Free;
end;

procedure TForm1.Button3Click(Sender: TObject);
var
  vP:PByteArray;
  x,y:Integer;
  vBmp:TBitmap;
  gray:Integer;
begin
  vBmp:=TBitmap.Create;
  vBmp.Assign(Image1.Picture.Bitmap);
  vBmp.PixelFormat:=pf24bit;//如果Image1.Picture.Bitmap不是24位的真彩BMP图片，请设置这个
  for y:=0 to vBmp.Height -1 do
  begin
    vp:=vbmp.ScanLine[y]; //获取每行的像素
    for x:=0 to vBmp.Width-1  do
    begin
      vp[3*x+2]:=not vp[3*x+2];//R
      vp[3*x+1]:=not vp[3*x+1];//G
      vp[3*x]:=not vp[3*x];//B
    end;
  end;
  Image2.Picture.Bitmap:=vBmp;
  vBmp.Free;
end;

procedure TForm1.Button4Click(Sender: TObject);
var
  vBmp:TBitmap;
begin
  vBmp:=TBitmap.Create;
  try
    vBmp.Width:=Image1.Picture.Width;
    vBmp.Height:=Image1.Picture.Height;
    BitBlt(vBmp.Canvas.Handle,0,0,vBmp.Width,vBmp.Height,Image1.Picture.Bitmap.Canvas.Handle,0,0,NOTSRCCOPY);
    Image2.Picture.Bitmap.Assign(vBmp);
  finally
    vBmp.Free;
  end;


end;

procedure TForm1.Button5Click(Sender: TObject);
var
  vMyRect:TRect;
begin
  vMyRect.Left:=0;
  vMyRect.Top:=0;
  vMyRect.Right:=Image2.Picture .Width;
  vMyRect.Bottom:=Image2.Picture .Height;
  InvertRect(Image2.Canvas.Handle,vMyRect);
  //InvertRect(Image2.Canvas.Handle,Image2.ClientRect); //图片大小和Image控件的大小一样时可以用
  Image2.Repaint;
end;

procedure TForm1.Button7Click(Sender: TObject);
var
  vFileHandle, vMapHandle:THandle;//文件句柄，映射句柄
  vPData:PByte; //内存映射文件头指针
  i,vFileSize:Integer;//vFileSize文件大小
begin
  //这个直接操作图片，请注意///记得先备份原图////再执行一次这个也能把图片还原////
  
  

  //文件映射处理大图片
  // 位图格式介绍 https://www.cnblogs.com/CZM-/p/5388553.html
  if OpenPictureDialog1.Execute then
  begin
    vFileHandle:=FileOpen(OpenPictureDialog1.FileName,fmOpenReadWrite); //获取文件句柄
    vFileSize:=GetFileSize(vFileHandle,nil);//获取物理文件大小
    //获取映射文件句柄
    vMapHandle:=CreateFileMapping(vFileHandle,nil,PAGE_READWRITE,0,vFileSize,nil);
    CloseHandle(vFileHandle);
    vPData:=MapViewOfFile(vMapHandle,FILE_MAP_ALL_ACCESS,0,0,vFileSize);
    CloseHandle(vMapHandle);
    try
      i:=0;
      //从文件头开始位置到数据区域偏移54字节(文件信息头14字节，位图信息头40字节)；
      Inc(Integer(vPdata),53);
      while i<vFileSize do
      begin
        //像素取反操作
        vPData^:=not vPData^;
        inc(Integer(vPData),1);//下一个Byte  //指针递增
        Inc(i,1);
      end;
    finally
      UnmapViewOfFile(vPData);
    end;
  end;
end;

end.


//------PatBlt--Begin----
BOOL PatBlt(HDC hdc, int nXLeft, int nYLeft, int nWidth, int nHeight, DWORD dwRop);
hdc：设备环境句柄。
nXLeft：指定要填充的矩形左上角的X轴坐标，坐标按逻辑单位表示。
nYLeft：指定要填充的矩形左上角的Y轴坐标，坐标按逻辑单位表示。
nWidth：指定矩形的宽度，按逻辑单位表示宽度。
nHeight：指定矩形的高度，按逻辑单位表示高度。
dwRop：指定光栅操作码。该操作码可以取下列值，这些值的含义如下：
PATCOPY：将指定的模式拷贝到目标位图中。
PATINVERT：使用布尔XOR（异或）操作符将指定模式的颜色与目标矩形的颜色进行组合。
DSTINVERT：将目标矩形反向。
BLACKNESS：使用物理调色板中与索引0相关的颜色填充目标矩形。（对于缺省的物理调色板而言，该颜色为黑色）。
WHITENESS：使用物理调色板中与索引1有关的颜色来填充目标矩形。（对于缺省的物理调色板而言，该颜色为白色）。
返回值：如果函数执行成功，则返回值为非零；如果函数执行失败，则返回值为0。
Windows NT：若想获得更多错误信息，请调用GetLastError函数。

//------PatBlt---End------


//------BitBlt----Begin-------
BOOL BitBlt(_In HDC hdcDest,  _In_  int nXDest,  _In_  int nYDest,  _In_  int nWidth,  _In_  int nHeight,  _In_  HDC hdcSrc,  _In_  int nXSrc,  _In_  int nYSrc,  _In_  DWORD dwRop);
hDestDC：指向目标设备环境的句柄。
x：指定目标矩形区域左上角的X轴逻辑坐标。
y：指定目标矩形区域左上角的Y轴逻辑坐标。
nWidth：指定源在目标矩形区域的逻辑宽度。
nHeight：指定源在目标矩形区域的逻辑高度。
hSrcDC：指向源设备环境的句柄。
xSrc：指定源矩形区域左上角的X轴逻辑坐标。
ySrc：指定源矩形区域左上角的Y轴逻辑坐标。
dwRop：指定光栅操作代码。这些代码将定义源矩形区域的颜色数据，如何与目标矩形区域的颜色数据组合以完成最后的颜色。
下面列出了一些常见的光栅操作代码：
BLACKNESS：表示使用与物理调色板的索引0相关的色彩来填充目标矩形区域，（对缺省的物理调色板而言，该颜色为黑色）。
DSTINVERT：表示使目标矩形区域颜色取反。
MERGECOPY：表示使用布尔型的AND（与）操作符将源矩形区域的颜色与特定模式组合一起。
MERGEPAINT：通过使用布尔型的OR（或）操作符将反向的源矩形区域的颜色与目标矩形区域的颜色合并。
NOTSRCCOPY：将源矩形区域颜色取反，于拷贝到目标矩形区域。
NOTSRCERASE：使用布尔类型的OR（或）操作符组合源和目标矩形区域的颜色值，然后将合成的颜色取反。
PATCOPY：将特定的模式拷贝到目标位图上。
PATPAINT：通过使用布尔OR（或）操作符将源矩形区域取反后的颜色值与特定模式的颜色合并。然后使用OR（或）操作符将该操作的结果与目标矩形区域内的颜色合并。
PATINVERT：通过使用XOR（异或）操作符将源和目标矩形区域内的颜色合并。
SRCAND：通过使用AND（与）操作符来将源和目标矩形区域内的颜色合并。
SRCCOPY：将源矩形区域直接拷贝到目标矩形区域。
SRCERASE：通过使用AND（与）操作符将目标矩形区域颜色取反后与源矩形区域的颜色值合并。
SRCINVERT：通过使用布尔型的XOR（异或）操作符将源和目标矩形区域的颜色合并。
SRCPAINT：通过使用布尔型的OR（或）操作符将源和目标矩形区域的颜色合并。
WHITENESS：使用与物理调色板中索引1有关的颜色填充目标矩形区域。（对于缺省物理调色板来说，这个颜色就是白色）。

//-------BitBlt----End----

------Form

object Form1: TForm1
  Left = 269
  Top = 245
  BorderStyle = bsDialog
  Caption = 'Form1'
  ClientHeight = 485
  ClientWidth = 886
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'MS Sans Serif'
  Font.Style = []
  OldCreateOrder = False
  OnCreate = FormCreate
  PixelsPerInch = 96
  TextHeight = 13
  object Image1: TImage
    Left = 8
    Top = 16
    Width = 425
    Height = 337
    Center = True
    Proportional = True
    Stretch = True
  end
  object Image2: TImage
    Left = 448
    Top = 16
    Width = 425
    Height = 337
    Center = True
    Proportional = True
    Stretch = True
  end
  object Label1: TLabel
    Left = 16
    Top = 360
    Width = 385
    Height = 25
    AutoSize = False
    Caption = '图片宽x高:'
  end
  object Button1: TButton
    Left = 16
    Top = 416
    Width = 161
    Height = 25
    Caption = 'Button1_加载图片'
    TabOrder = 0
    OnClick = Button1Click
  end
  object Button2: TButton
    Left = 248
    Top = 400
    Width = 179
    Height = 25
    Caption = 'Button2_PatBlt'
    TabOrder = 1
    OnClick = Button2Click
  end
  object Button3: TButton
    Left = 448
    Top = 400
    Width = 179
    Height = 25
    Caption = 'Button3_ScanLine'
    TabOrder = 2
    OnClick = Button3Click
  end
  object Button4: TButton
    Left = 640
    Top = 400
    Width = 179
    Height = 25
    Caption = 'Button4_BitBlt'
    TabOrder = 3
    OnClick = Button4Click
  end
  object Button5: TButton
    Left = 248
    Top = 440
    Width = 179
    Height = 25
    Caption = 'Button5_InvertRect'
    TabOrder = 4
    OnClick = Button5Click
  end
  object Button6: TButton
    Left = 448
    Top = 440
    Width = 179
    Height = 25
    Caption = 'Button6_像素点取反_好慢'
    TabOrder = 5
    OnClick = Button6Click
  end
  object Button7: TButton
    Left = 640
    Top = 440
    Width = 185
    Height = 25
    Caption = 'Button7_文件映射处理大图片'
    TabOrder = 6
    OnClick = Button7Click
  end
  object OpenPictureDialog1: TOpenPictureDialog
    Filter = 'Bitmaps (*.bmp)|*.bmp'
    Left = 72
    Top = 368
  end
end