最简单的 Url 映射是使用 TIWAppForm 的 class 方法: SetURL;
THandlers 是 IntraWeb XIV 新增的内容处理器, 它能完成的不仅仅是 Url 映射(转发?).
THandlers 通过虚拟路径、虚拟文件名, 可以转到或处理任何文件.
这个过程中会用到一个 TContentBase 类型的参数, TContentForm、TContentRedirect 是它的子类; 有时会需要从 TContentBase 继承出解决更多问题的子类.
THandlers 所在单元及继承链:
IW.Content.Handlers.THandlers < TObject
主要成员:
{添加到内容处理器: aPath: 虚拟路径; aDocument: 虚拟文件夹名; aHandler: 要添加的内容}
class function Add(const aPath: string; const aDocument: string; aHandler: TContentBase): TContentBase
class function Add(const aDocument: string; aHandler: TContentBase): TContentBase
{添加为首页}
class function AddStartHandler(const aPath: string; const aDocument: string; aHandler: TContentBase): TContentBase
class function GetStartHandler(aSession: TIWApplication): TContentBase
{添加对指定扩展名的统一处理}
class function AddForExtension(const aExt: string; aHandler: TContentBase): TContentBase
class function FindMatch(aFullPath: string): TContentBase
class procedure RegisterGetStartHandlerProc(aProc: TGetStartHandlerProc = procedure(aSession: TIWApplication; var aHandler: TContentBase) of object)
TIWAppForm.SetURL 方法应该用在 initialization 部分, 如:
{假如有三个窗体, 这是 Unit1 的部分代码:}
//...
procedure TIWForm1.IWButton1Click(Sender: TObject);
begin
WebApplication.GoToURL('bbb.aspx');
// WebApplication.GoToURL('abc/ccc.xxx');
end;
initialization
TIWForm1.SetAsMainForm;
TIWForm1.SetURL('', 'aaa.html'); //参数 1 是虚拟路径, '' 或 '/' 表示根路径; 参数 2 是虚拟文件名
end.
{这是 Unit2 的部分代码: -------------------------------------------}
//...
initialization
TIWForm2.SetURL('/', 'bbb.php'); //名字是虚拟的, 不是真的 php 文件
end.
{这是 Unit3 的部分代码: -------------------------------------------}
//...
initialization
TIWForm3.SetURL('/abc/', 'ccc.xxx');
end.
{通过如上设置, 上面三个窗体就对应了下面三个网址(假定测试地址是: 127.0.0.1:8888)}
http://127.0.0.1:8888/aaa.html
http://127.0.0.1:8888/bbb.php
http://127.0.0.1:8888/abc/ccc.xxx
THandlers 测试一:
{代码主要写在 IWServerController 的 OnConfig 事件中, 下面是部分代码:}
uses
IWInit, IWGlobal, Unit1, Unit2, Unit3, {Unit1-3 分别对应三个窗体}
IW.Content.Handlers, IW.Content.Base, IW.Content.Form, IW.Content.Redirect; {THandlers、TContentBase、TContentForm、TContentRedirect 分别需要的单元}
{IWServerControllerBase.OnConfig 事件; 之前我是在 OnCreate 中测试的, 官方建议这些代码应该在 OnConfig 事件中}
procedure TIWServerController.IWServerControllerBaseConfig(Sender: TObject);
begin
THandlers.Add('', 'aaa.htm', TContentForm.Create(TIWForm1));
THandlers.AddStartHandler('', 'bbb.htm', TContentForm.Create(TIWForm2)); //纯属实验, 把 TIWForm2 设为首页
THandlers.AddForExtension('.php', TContentForm.Create(TIWForm3)); //只要访问 *.php 的页面, 就转到 TIWForm3
THandlers.Add('', 'ccc.htm', TContentRedirect.Create('xxx.html')); //假如在 wwwroot 下有 xxx.html, 那么访问 ccc.htm 就可以转到 xxx.html
end;
THandlers 测试二: 关于自定义的 TContentBase, 官方给出了这样的例子:
{自定义 TContentXML 的单元: -----------------------------------------------------------}
unit MyXml;
interface
uses Classes, IW.Content.Base, HTTPApp, IWApplication, IW.HTTP.Request, IW.HTTP.Reply;
type
TContentXML = class(TContentBase)
protected
function Execute(aRequest: THttpRequest; aReply: THttpReply; const aPathname: string; aSession: TIWApplication; aParams: TStrings): Boolean; override;
public
constructor Create; override;
end;
implementation
uses IW.Content.Handlers, IWMimeTypes;
constructor TContentXML.Create;
begin
inherited;
mFileMustExist := False;
end;
function TContentXML.Execute(aRequest: THttpRequest; aReply: THttpReply; const aPathname: string; aSession: TIWApplication; aParams: TStrings): Boolean;
begin
Result := True;
if Assigned(aReply) then
begin
aReply.ContentType := MIME_XML;
aReply.WriteString('<xml>My xml content here</xml>');
end;
end;
end.
{ServerController 单元的部分相关代码: --------------------------------------------------}
uses
IWInit, IWGlobal, IW.Content.Handlers, MyXml;
{IWServerControllerBase.OnConfig 事件}
procedure TIWServerController.IWServerControllerBaseConfig(Sender: TObject);
begin
THandlers.Add('', 'XmlTest', TContentXML.Create);
end;
{Unit1 单元的部分相关代码: -------------------------------------------------------------}
procedure TIWForm1.IWButton1Click(Sender: TObject);
begin
WebApplication.GoToURL('XmlTest');
end;