【NOIP2014】子矩阵

这题如果按暴力做只有一半分，最大时间复杂度为O(C(16,8)*C(16,8)); 很容易算出超时；

我们可以发现如果直接dp会很难想，但是知道选哪几行去dp就很好写状态转移方程：

     dp[i][j]=min(dp[i][j],dp[k][j-1]+a[i]+b[k][i]);

其中dp[i][j]表示 前i列里选j列的子矩阵最大分值

     a[i]表示 第i列选到的行的总差值

     b[k][i]表示选到的每一行第k列和第i列之间的差值

我们只要枚举 行 然后dp一次，取最小值即可 这样最大时间复杂度就成了O(C(8,16)*n³);

最后附上我弱弱的pascal代码： 

var
  i,j,k,n,m,n1,m1,ans:longint;
  dp,a,f:array[0..16,0..16] of longint;
  hc:array[0..16,1..16,1..16] of longint;
  b,lc:array[0..17] of longint;
function min(a,b:longint):longint;
 begin
  if a>b then min:=b
         else min:=a;
 end;
procedure ddp;
 var
  i,j,k,max:longint;
 begin
  fillchar(f,sizeof(f),0);
  fillchar(lc,sizeof(lc),0);
  fillchar(dp,sizeof(dp),0);
  for i:=1 to m do
   for j:=1 to n1-1 do
    lc[i]:=lc[i]+abs(a[b[j+1],i]-a[b[j],i]);
  for i:=1 to m do
   for j:=i+1 to m do
    for k:=1 to n1 do
     f[i,j]:=f[i,j]+hc[b[k],i,j];
  for i:=1 to m do
   dp[i,1]:=lc[i];
  for i:=2 to m do
   for j:=2 to m1 do
    if i>=j then
              begin
               dp[i,j]:=maxlongint;
               for k:=j-1 to i-1 do
                dp[i,j]:=min(dp[i,j],dp[k,j-1]+lc[i]+f[k,i]);
              end;
  for i:=m1 to m do
   if dp[i,m1]<ans then ans:=dp[i,m1];
 end;
procedure jw(ii:longint);
 begin
  inc(b[ii]);
  if ii>=0 then
   if b[ii]>(n-n1+ii) then
                         begin
                          jw(ii-1);
                          b[ii]:=b[ii-1]+1;
                         end;
 end;
begin
  read(n,m,n1,m1);
  for i:=1 to n do
   for j:=1 to m do
    begin
     read(a[i,j]);
     for k:=1 to j-1 do
      hc[i,k,j]:=abs(a[i,j]-a[i,k]);
    end;
  for i:=1 to n1 do
   b[i]:=i;
  ans:=100000000;
  while b[0]=0 do
   begin
    ddp;
    jw(n1);
   end;
  write(ans);
end.