1084: [SCOI2005]最大子矩阵

Description

这里有一个n*m的矩阵，请你选出其中k个子矩阵，使得这个k个子矩阵分值之和最大。注意：选出的k个子矩阵不能相互重叠。

Input

第一行为n,m,k（1≤n≤100,1≤m≤2,1≤k≤10），接下来n行描述矩阵每行中的每个元素的分值(每个元素的分值的绝对值不超过32767)。

Output

只有一行为k个子矩阵分值之和最大为多少。

Sample Input

3 2 2

1 -3

2 3

-2 3

Sample Output

9

因为m≤2，所以就成了sbDP题，分情况DP即可

var
    f1:array[0..100,0..10]of longint;
    s1:array[0..100]of longint;
    f2:array[0..100,0..100,0..10]of longint;
    s2:array[0..100,1..2]of longint;
    n,m,k:longint;

procedure up(var x:longint;y:longint);
begin
    if x<y then x:=y;
end;

procedure work1;
var
    i,j,l:longint;
begin
    fillchar(f1,sizeof(f1),200);
    for i:=1 to n do
      begin
        read(s1[i]);
        inc(s1[i],s1[i-1]);
      end;
    for i:=0 to n do
      f1[i,0]:=0;
    for l:=1 to k do
      for i:=1 to n do
        begin
          up(f1[i,l],f1[i-1,l]);
          for j:=1 to i do
            up(f1[i,l],f1[j-1,l-1]+s1[i]-s1[j-1]);
        end;
    writeln(f1[n,k]);
end;

procedure work2;
var
    i,j,l,r:longint;
begin
    for i:=1 to n do
      for j:=1 to m do
        begin
          read(s2[i,j]);
          inc(s2[i,j],s2[i-1,j]);
        end;
    fillchar(f2,sizeof(f2),200);
    for i:=0 to n do
      for j:=0 to n do
        f2[i,j,0]:=0;
    for l:=1 to k do
      for i:=1 to n do
        for j:=1 to n do
          begin
            up(f2[i,j,l],f2[i-1,j,l]);
            up(f2[i,j,l],f2[i,j-1,l]);
            for r:=1 to i do
              up(f2[i,j,l],f2[r-1,j,l-1]+s2[i,1]-s2[r-1,1]);
            for r:=1 to j do
              up(f2[i,j,l],f2[i,r-1,l-1]+s2[j,2]-s2[r-1,2]);
            if i=j then
            for r:=1 to i do
              up(f2[i,j,l],f2[r-1,r-1,l-1]+s2[j,2]-s2[r-1,2]+s2[i,1]-s2[r-1,1]);
          end;
    writeln(f2[n,n,k]);
end;

begin
    read(n,m,k);
    if m=1 then work1
    else work2;
end.