1833: [ZJOI2010]count 数字计数

Description
给定两个正整数a和b，求在[a,b]中的所有整数中，每个数码(digit)各出现了多少次。
Input
输入文件中仅包含一行两个整数a、b，含义如上所述。
Output
输出文件中包含一行10个整数，分别表示0-9在[a,b]中出现了多少次。
Sample Input
1 99
Sample Output
9 20 20 20 20 20 20 20 20 20
HINT

30%的数据中，a<=b<=10^6；
100%的数据中，a<=b<=10^12。

首先把这个问题变成f（b）-f（a-1）

然后就是比较简单的数位dp

f[i,j]表示长度为i以j开头0到9各个数字的出现次数

先算出全部的，再减去不合法的

不合法的就是枚举，减去从第i位开始超出n的情况，注意减去比第i位更高的数字（一开始就这样WA的）

type
        node=array[0..9]of int64;
var
        f:array[0..15,0..9]of node;
        ten:array[0..15]of int64;
        a,b:int64;

operator +(a,b:node)c:node;
var
        i:longint;
begin
        for i:=0 to 9 do
          c[i]:=a[i]+b[i];
end;

operator -(a,b:node)c:node;
var
        i:longint;
begin
        for i:=0 to 9 do
          c[i]:=a[i]-b[i];
end;

operator *(a:node;b:int64)c:node;
var
        i:longint;
begin
        for i:=0 to 9 do
          c[i]:=a[i]*b;
end;

function ff(x:int64):node;
var
        s:array[0..15]of longint;
        i,j,len:longint;
        fff:node;
begin
        fillchar(ff,sizeof(ff),0);
        fillchar(fff,sizeof(fff),0);
        for i:=1 to 13 do
          begin
            s[i]:=x mod 10;
            x:=x div 10;
          end;
        for i:=13 downto 1 do
          if s[i]<>0 then break;
        len:=i;
        for i:=1 to len do
          for j:=1 to 9 do
            ff:=ff+f[i,j];
        for i:=len downto 1 do
          begin
            for j:=s[i]+1 to 9 do
              ff:=ff-f[i,j]-fff*ten[i];
            inc(fff[s[i]]);
          end;
end;

procedure print(a:node);
var
        i:longint;
begin
        for i:=0 to 8 do
          write(a[i],' ');
        write(a[9]);
end;

procedure main;
var
        i,j,k:longint;
begin
        read(a,b);
        ten[1]:=1;
        for i:=2 to 13 do
          ten[i]:=ten[i-1]*10;
        for i:=1 to 13 do
          for j:=0 to 9 do
            begin
              for k:=0 to 9 do
                f[i,j]:=f[i,j]+f[i-1,k];
              inc(f[i,j,j],ten[i]);
            end;
        print(ff(b)-ff(a-1));
end;

begin
        main;
end.