1061: [Noi2008]志愿者招募

Description

申奥成功后，布布经过不懈努力，终于成为奥组委下属公司人力资源部门的主管。布布刚上任就遇到了一个难题：为即将启动的奥运新项目招募一批短期志愿者。经过估算，这个项目需要N 天才能完成，其中第i 天至少需要Ai 个人。 布布通过了解得知，一共有M 类志愿者可以招募。其中第i 类可以从第Si 天工作到第Ti 天，招募费用是每人Ci 元。新官上任三把火，为了出色地完成自己的工作，布布希望用尽量少的费用招募足够的志愿者，但这并不是他的特长！于是布布找到了你，希望你帮他设计一种最优的招募方案。
Input

第一行包含两个整数N, M，表示完成项目的天数和可以招募的志愿者的种类。 接下来的一行中包含N 个非负整数，表示每天至少需要的志愿者人数。 接下来的M 行中每行包含三个整数Si, Ti, Ci，含义如上文所述。为了方便起见，我们可以认为每类志愿者的数量都是无限多的。
Output

仅包含一个整数，表示你所设计的最优方案的总费用。
Sample Input
3 3
2 3 4
1 2 2
2 3 5
3 3 2
Sample Output
14
HINT

招募第一类志愿者3名，第三类志愿者4名 30%的数据中，1 ≤ N, M ≤ 10，1 ≤ Ai ≤ 10； 100%的数据中，1 ≤ N ≤ 1000，1 ≤ M ≤ 10000，题目中其他所涉及的数据均 不超过2^31-1。

首先贴上别人的题解https://www.byvoid.com/blog/noi-2008-employee/

首先肯定都知道这个是线性规划，可以用单纯形法做，但是单纯形法好像很少用一样，反正我是不会

既然不会线性规划，我们只好转换成网络流了，因为网络流也是一种线性规划我就不说什么了，弱菜表示完全想不到.....，线性规划转化为网络流，完全不懂啊

const
        maxn=1010;
        maxm=40010;
        inf=100000000;
var
        a,flag,dis,f,first:array[0..maxn]of longint;
        next,last,w,liu:array[0..maxm]of longint;
        n,m,s,t,tot,time,ans,flow:longint;
 
procedure insert(u,v,f,l:longint);
begin
        inc(tot);
        last[tot]:=v;
        next[tot]:=first[u];
        w[tot]:=f;
        liu[tot]:=l;
        first[u]:=tot;
        inc(tot);
        last[tot]:=u;
        next[tot]:=first[v];
        w[tot]:=-f;
        first[v]:=tot;
end;
 
procedure init;
var
        i,j,x,y,z:longint;
begin
        read(n,m);
        tot:=1;
        for i:=1 to n do
          read(a[i]);
        for i:=1 to m do
          begin
            read(x,y,z);
            insert(x,y+1,z,inf);
          end;
        s:=0;
        t:=n+2;
        for i:=1 to n+1 do
          begin
            z:=a[i]-a[i-1];
            if z>0 then insert(s,i,0,z);
            if z<0 then insert(i,t,0,-z);
            if i>0 then insert(i,i-1,0,inf);
          end;
end;
 
function dfs(x,flow:longint):longint;
var
        i,d,min:longint;
begin
        if x=t then
        begin
          inc(ans,flow*dis[t]);
          exit(flow);
        end;
        i:=first[x];
        flag[x]:=time;
        dfs:=0;
        while i<>0 do
          begin
            d:=dis[x]+w[i]-dis[last[i]];
            min:=flow;
            if min>liu[i] then min:=liu[i];
            if (min>0) and (d<f[last[i]]) then f[last[i]]:=d;
            if (min>0) and (d=0) and (flag[last[i]]<>time) then
            begin
              d:=dfs(last[i],min);
              inc(dfs,d);
              dec(flow,d);
              dec(liu[i],d);
              inc(liu[i xor 1],d);
            end;
            if flow=0 then break;
            i:=next[i];
          end;
end;
 
procedure work;
var
        i,del:longint;
begin
        repeat
          inc(time);
          for i:=s to t do
            f[i]:=inf;
          inc(flow,dfs(s,inf));
          del:=inf;
          for i:=s to t do
            if (flag[i]<>time) and (del>f[i]) then del:=f[i];
          if del=inf then break;
          for i:=s to t do
            if flag[i]<>time then inc(dis[i],del);
        until false;
        write(ans);
end;
 
var
        q:array[0..maxn]of longint;
        head,tail:longint;
 
procedure spfa;
var
        i:longint;
begin
        inc(time);
        head:=1;
        tail:=2;
        fillchar(dis,sizeof(dis),1);
        q[1]:=s;
        dis[s]:=0;
        while head<>tail do
          begin
            i:=first[q[head]];
            while i<>0 do
              begin
                if (liu[i]>0) and (dis[last[i]]>dis[q[head]]+w[i]) then
                begin
                  if flag[last[i]]<>time then
                  begin
                    q[tail]:=last[i];
                    flag[last[i]]:=time;
                    tail:=tail mod maxn+1;
                  end;
                  dis[last[i]]:=dis[q[head]]+w[i];
                end;
                i:=next[i];
              end;
            flag[q[head]]:=time-1;
            head:=head mod maxn+1;
          end;
end;
 
begin
        init;
       spfa;
        work;
end.