算法模板——线段树9（区间加+区间求和+区间方和）

如题，实现一个程序，输入N个数，进行如下维护：

1.1 x y 求[x,y]区间的和

2.2 x y 求[x,y]区间的平方和

3.3 x y z 将[x,y]区间全部加上z

4.4 x y 求[x,y]区间内两两数相乘的积之和（其实4是1、2的简单组合）

如下：

var
   i,j,k,l,m,n:longint;
   t:int64;
   a,b,c:array[0..100000] of int64;
type
    rec=record
              aa,bb:int64;
    end;

function max(x,y:longint):longint;
         begin
              if x>y then max:=x else max:=y;
         end;
function min(x,y:longint):longint;
         begin
              if x<y then min:=x else min:=y;
         end;
procedure built(z,x,y:longint);
          begin
               if x=y then
                  begin
                       read(a[z]);
                       b[z]:=a[z]*a[z];
                  end
               else
                   begin
                        built(z*2,x,(x+y) div 2);
                        built(z*2+1,(x+y) div 2+1,y);
                        a[z]:=a[z*2]+a[z*2+1];
                        b[z]:=b[z*2]+b[z*2+1];
                   end;
               c[z]:=0;
          end;
procedure ext(z,x,y:longint);
          begin
               if c[z]=0 then exit;
               b[z]:=b[z]+2*c[z]*a[z]+(y-x+1)*c[z]*c[z];
               a[z]:=a[z]+(y-x+1)*c[z];
               if x<>y then
                  begin
                       c[z*2]:=c[z*2]+c[z];
                       c[z*2+1]:=c[z*2+1]+c[z];
                  end;
               c[z]:=0;
          end;
function suma(z,x,y,l,r:longint):int64;
         begin
              if l>r then exit(0);
              ext(z,x,y);
              if (x=l) and (y=r) then exit(a[z]);
              exit(suma(z*2,x,(x+y) div 2,l,min(r,(x+y) div 2))+suma(z*2+1,(x+y) div 2+1,y,max((x+y) div 2+1,l),r));
         end;
function sumb(z,x,y,l,r:longint):int64;
         begin
              if l>r then exit(0);
              ext(z,x,y);
              if (x=l) and (y=r) then exit(b[z]);
              exit(sumb(z*2,x,(x+y) div 2,l,min(r,(x+y) div 2))+sumb(z*2+1,(x+y) div 2+1,y,max((x+y) div 2+1,l),r));
         end;
function add(z,x,y,l,r:longint;t:int64):rec;
         var tt,tt1,tt2:rec;
         begin
              tt.aa:=0;tt.bb:=0;
              if l>r then exit(tt);
              if (x=l) and (y=r) then
                 begin
                      tt.aa:=t*(r-l+1);
                      tt.bb:=2*t*(a[z]+c[z]*(r-l+1))+t*t*(r-l+1);
                      c[z]:=c[z]+t;
                      exit(tt);
                 end;
              ext(z,x,y);
              tt1:=add(z*2,x,(x+y) div 2,l,min(r,(x+y) div 2),t);
              tt2:=add(z*2+1,(x+y) div 2+1,y,max((x+y) div 2+1,l),r,t);
              tt.aa:=tt1.aa+tt2.aa;
              tt.bb:=tt1.bb+tt2.bb;
              a[z]:=a[z]+tt.aa;
              b[z]:=b[z]+tt.bb;
              exit(tt);
         end;
begin
     readln(n);
     built(1,1,n);
     while true do
         begin
              read(j,k,l);
              case j of
                   1:begin
                          writeln(suma(1,1,n,k,l));
                   end;
                   2:begin
                          writeln(sumb(1,1,n,k,l));
                   end;
                   3:begin
                          read(t);
                          add(1,1,n,k,l,t);
                   end;
                   4:begin
                          t:=suma(1,1,n,k,l);
                          writeln((t*t-sumb(1,1,n,k,l)) div 2);
                   end;
              end;
              readln;
         end;
end.